| 1 | package App::cpm::Resolver::MetaDB; | ||
| 2 | use v5.24; | ||
| 3 | use warnings; | ||
| 4 | use experimental qw(lexical_subs signatures); | ||
| 5 | |||
| 6 | use App::cpm::DistNotation; | ||
| 7 | use App::cpm::Util 'uniq'; | ||
| 8 | use App::cpm::version; | ||
| 9 | use CPAN::Meta::YAML; | ||
| 10 | |||
| 11 | sub new ($class, $ctx, %argv) { | ||
| 12 | my $uri = $argv{uri} || "https://cpanmetadb.plackperl.org/v1.0/"; | ||
| 13 | my $mirror = $argv{mirror} || "https://cpan.metacpan.org/"; | ||
| 14 | s{/*$}{/} for $uri, $mirror; | ||
| 15 | bless { | ||
| 16 | %argv, | ||
| 17 | uri => $uri, | ||
| 18 | mirror => $mirror, | ||
| 19 | }, $class; | ||
| 20 | } | ||
| 21 | |||
| 22 | sub _get ($self, $ctx, $uri) { | ||
| 23 | my $res; | ||
| 24 | for (1..2) { | ||
| 25 | $res = $ctx->{http}->get($uri); | ||
| 26 | last if $res->{success} or $res->{status} == 404; | ||
| 27 | } | ||
| 28 | $res; | ||
| 29 | } | ||
| 30 | |||
| 31 | sub resolve ($self, $ctx, $task) { | ||
| 32 | if (defined $task->{version_range} and $task->{version_range} =~ /(?:<|!=|==)/) { | ||
| 33 | my $uri = "$self->{uri}history/$task->{package}"; | ||
| 34 | my $res = $self->_get($ctx, $uri); | ||
| 35 | if (!$res->{success}) { | ||
| 36 | my $error = "$res->{status} $res->{reason}, $uri"; | ||
| 37 | $error .= ", $res->{content}" if $res->{status} == 599; | ||
| 38 | return { error => $error }; | ||
| 39 | } | ||
| 40 | |||
| 41 | my @found; | ||
| 42 | for my $line ( split /\r?\n/, $res->{content} ) { | ||
| 43 | if ($line =~ /^$task->{package}\s+(\S+)\s+(\S+)$/) { | ||
| 44 | push @found, { | ||
| 45 | version => $1, | ||
| 46 | version_o => App::cpm::version->parse($1), | ||
| 47 | distfile => $2, | ||
| 48 | }; | ||
| 49 | } | ||
| 50 | } | ||
| 51 | |||
| 52 | @found = reverse @found; | ||
| 53 | |||
| 54 | my $match; | ||
| 55 | for my $try (sort { $b->{version_o} <=> $a->{version_o} } @found) { | ||
| 56 | if ($try->{version_o}->satisfy($task->{version_range})) { | ||
| 57 | $match = $try, last; | ||
| 58 | } | ||
| 59 | } | ||
| 60 | |||
| 61 | if ($match) { | ||
| 62 | my $dist = App::cpm::DistNotation->new_from_dist($match->{distfile}); | ||
| 63 | return { | ||
| 64 | source => "cpan", | ||
| 65 | package => $task->{package}, | ||
| 66 | version => $match->{version}, | ||
| 67 | uri => $dist->cpan_uri($self->{mirror}), | ||
| 68 | distfile => $dist->distfile, | ||
| 69 | }; | ||
| 70 | } else { | ||
| 71 | return { error => "found versions @{[join ',', uniq map $_->{version}, @found]}, but they do not satisfy $task->{version_range}, $uri" }; | ||
| 72 | } | ||
| 73 | } else { | ||
| 74 | my $uri = "$self->{uri}package/$task->{package}"; | ||
| 75 | my $res = $self->_get($ctx, $uri); | ||
| 76 | if (!$res->{success}) { | ||
| 77 | my $error = "$res->{status} $res->{reason}, $uri"; | ||
| 78 | $error .= ", $res->{content}" if $res->{status} == 599; | ||
| 79 | return { error => $error }; | ||
| 80 | } | ||
| 81 | |||
| 82 | my $yaml = CPAN::Meta::YAML->read_string($res->{content}); | ||
| 83 | my $meta = $yaml->[0]; | ||
| 84 | if (!App::cpm::version->parse($meta->{version})->satisfy($task->{version_range})) { | ||
| 85 | return { error => "found version $meta->{version}, but it does not satisfy $task->{version_range}, $uri" }; | ||
| 86 | } | ||
| 87 | my @provides = map { | ||
| 88 | my $package = $_; | ||
| 89 | my $version = $meta->{provides}{$_}; | ||
| 90 | $version = undef if $version eq "undef"; | ||
| 91 | +{ package => $package, version => $version }; | ||
| 92 | } sort keys $meta->{provides}->%*; | ||
| 93 | |||
| 94 | my $dist = App::cpm::DistNotation->new_from_dist($meta->{distfile}); | ||
| 95 | return { | ||
| 96 | source => "cpan", | ||
| 97 | distfile => $dist->distfile, | ||
| 98 | uri => $dist->cpan_uri($self->{mirror}), | ||
| 99 | version => $meta->{version}, | ||
| 100 | provides => \@provides, | ||
| 101 | }; | ||
| 102 | } | ||
| 103 | return; | ||
| 104 | } | ||
| 105 | |||
| 106 | 1; |