cpm/HTTP.pm untested

filter: Statementstmt 0.0% 0 / 62 Branchbran 0.0% 0 / 22 Conditioncond 0.0% 0 / 15 MC/DCmcdc 0.0% 0 / 9 Subroutinesub 0.0% 0 / 14 Podpod 0.0% 0 / 7 totaltotal 0.0% 0 / 129 CC 12 SCAR 43.3
CC
12
Cov
0%
create
156.0
configure
2.0
supports
2.0
CRAP 75.9
1 package App::cpm::HTTP;
2 use v5.24;
3 use warnings;
4 use experimental qw(lexical_subs signatures);
5  
6 use App::cpm;
7 use HTTP::Tinyish;
8  
9 package App::cpm::HTTP::_HTTPTiny {
10 $INC{"App/cpm/HTTP/_HTTPTiny.pm"} = __FILE__;
11 use parent 'HTTP::Tinyish::Base';
12 use HTTP::Tiny;
13 my %supports = (http => 1);
14 sub configure ($class) {
15 my %meta = ("HTTP::Tiny" => $HTTP::Tiny::VERSION);
16 $supports{https} = HTTP::Tiny->can_ssl;
17 \%meta;
18 }
19 sub supports ($class, $scheme) { $supports{$scheme} }
20 sub new ($class, %argv) {
21 bless { _conns => {}, _new_argv => \%argv }, $class;
22 }
23 sub _tiny ($self, $url) {
24 my ($key) = $url =~ m{^(https?://[^/]+)};
25 $key ||= "_";
26 $self->{_conns}{$key} ||= HTTP::Tiny->new($self->{_new_argv}->%*);
27 }
28 sub request ($self, $method, $url, @argv) {
29 $self->_tiny($url)->request($method, $url, @argv);
30 }
31 sub mirror ($self, $url, @argv) {
32 $self->_tiny($url)->mirror($url, @argv);
33 }
34 }
35  
36 sub create ($class, %args) {
37 my $wantarray = wantarray;
38 my $report_perl_version = delete $args{report_perl_version};
39 my $agent = "App::cpm/$App::cpm::VERSION";
40 $agent .= " perl/$]" if $report_perl_version;
41  
42 my @try;
43 if (!defined $args{prefer} or lc $args{prefer} eq "auto") {
44 @try = qw(HTTPTiny LWP Curl Wget);
45 } elsif (lc $args{prefer} eq "httptiny") {
46 @try = qw(HTTPTiny);
47 } elsif (lc $args{prefer} eq "lwp") {
48 @try = qw(LWP);
49 } elsif (lc $args{prefer} eq "curl") {
50 @try = qw(Curl);
51 } elsif (lc $args{prefer} eq "wget") {
52 @try = qw(Wget);
53 } else {
54 die "unknown http backend: $args{prefer}\n";
55 }
56 my @try2 =
57 map { $_ eq "HTTP::Tinyish::HTTPTiny" ? "App::cpm::HTTP::_HTTPTiny" : $_ }
58 map { "HTTP::Tinyish::$_" }
59 @try;
60  
61 my ($backend, $tool, $desc);
62 for my $try (@try2) {
63 my $meta = HTTP::Tinyish->configure_backend($try) or next;
64 $try->supports("https") or next;
65 ($tool) = sort keys $meta->%*;
66 ($desc = $meta->{$tool}) =~ s/^(.*?)\n.*/$1/s;
67 $backend = $try, last;
68 }
69 die "Couldn't find HTTP Clients that support https, tried @try2" if !$backend;
70  
71 my $http = $backend->new(
72 agent => $agent,
73 timeout => 60,
74 verify_SSL => 1,
75 %args,
76 );
77 my $keep_alive = exists $args{keep_alive} ? $args{keep_alive} : 1;
78 if ($keep_alive and $backend =~ /LWP$/) {
79 $http->{ua}->conn_cache({ total_capacity => 3 });
80 }
81  
82 $wantarray ? ($http, "$tool $desc") : $http;
83 }
84  
85 1;