File Coverage

blib/lib/Geo/UK/Postcode/CodePointOpen.pm

Criterion	Covered	Total	%
statement	94	100	94.0
branch	27	36	75.0
condition	13	20	65.0
subroutine	16	17	94.1
pod	5	5	100.0
total	155	178	87.0

package Geo::UK::Postcode::CodePointOpen;

our $VERSION = '0.007';

use Moo;
use Types::Path::Tiny qw/ Dir /;

use Geo::UK::Postcode::Regex;
use Geo::Coordinates::OSGB qw/ grid_to_ll /;
use List::MoreUtils qw/ uniq /;
use Text::CSV;

has path => ( is => 'ro', isa => Dir, coerce => Dir->coercion );
has pc_re          => ( is => 'lazy' );
has column_headers => ( is => 'lazy' );
has csv            => ( is => 'lazy' );
has metadata       => ( is => 'lazy' );

sub _build_pc_re {
    Geo::UK::Postcode::Regex->strict_regex;
}

sub _build_column_headers {
    my $self = shift;

    my $fh = $self->doc_dir->child('Code-Point_Open_Column_Headers.csv')
        ->filehandle('<');

    my $short = $self->csv->getline($fh)
        or die "Unable to read short column headers";
    my $long = $self->csv->getline($fh)
        or die "Unable to read long column headers";

    return {
        short => $short,
        long  => $long
    };
}

sub _build_csv {
    my $csv = Text::CSV->new( { binary => 1 } )
        or die Text::CSV->error_diag();
    return $csv;
}

#
# PRODUCT:
# DATASET VERSION NUMBER:
# COPYRIGHT DATE:
# RM UPDATE DATE:
#       XX\t123
sub _build_metadata {
    my $self = shift;

    my $metadata_file = $self->doc_dir->child('metadata.txt');

    my @lines = $metadata_file->lines( { chomp => 1 } );

    my $author = shift @lines;

    my @headers = grep {/:/} @lines;
    my @counts  = grep {/\t/} @lines;

    return {
        AUTHOR => $author,
        ( map { split /\s*:\s*/ } @headers ),
        counts =>
            { map { /\s+([A-Z]{1,2})\t(\d+)/ ? ( $1, $2 ) : () } @counts },
    };
}

sub doc_dir {
    shift->path->child('Doc');
}

sub data_dir {
    shift->path->child('Data/CSV');
}

sub data_files {
    my ( $self, @outcodes ) = @_;

    my $areas
        = join( '|', uniq grep {$_} map { /^([A-Z]+)/i && lc $1 } @outcodes );

    return sort $self->data_dir->children(
        $areas ? qr/^(?:$areas)\.csv$/    #
        :        qr/\.csv$/
    );
}

sub read_iterator {
    my ( $self, %args ) = @_;

    my ( @col_names, $lat_col, $lon_col, $out_col, $in_col );
    if ( $args{short_column_names} ) {
        @col_names = @{ $self->column_headers->{short} };
        ( $lat_col, $lon_col ) = ( 'LA', 'LO' );
        ( $out_col, $in_col )  = ( 'OC', 'IC' );
    } else {
        @col_names = @{ $self->column_headers->{long} };
        ( $lat_col, $lon_col ) = ( 'Latitude', 'Longitude' );
        ( $out_col, $in_col )  = ( 'Outcode',  'Incode' );
    }

    my @outcodes = @{ $args{outcodes} || [] };
    my @data_files = $self->data_files(@outcodes);

    my $match = @outcodes ? join( '|', map {uc} @outcodes ) : undef;
    $match = qr/^(?:$match)$/ if $match;

    # Create iterator coderef
    my $fh2;
    my $csv = $self->csv;

    my $iterator = sub {

        my %pc;
        while (1) {

            unless ( $fh2 && !eof $fh2 ) {
                my $file = shift @data_files or return;    # none left
                $fh2 = $file->filehandle('<');
            }

            # Expects:
            # Postcode,Positional_quality_indicator,Eastings,Northings,...
            my $row = $csv->getline($fh2);

            my $i = 0;
            %pc = map { $_ => $row->[ $i++ ] } @col_names;

            if ( $args{include_lat_long} && $pc{Eastings} && $pc{Northings} ) {
                my ( $lat, $lon ) = grid_to_ll( $pc{Eastings}, $pc{Northings} );

                $pc{$lat_col} = sprintf( "%.5f", $lat );
                $pc{$lon_col} = sprintf( "%.5f", $lon );
            }

            if ( $args{split_postcode} || $match ) {

                $pc{Postcode} =~ s/\s+/ /;

                my ( $area, $district, $sector, $unit )
                    = eval { $pc{Postcode} =~ $self->pc_re };

                if ( $@ || !$unit ) {
                    die "Unable to parse '"
                        . $pc{Postcode}
                        . "' : Please report via "
                        . "https://github.com/mjemmeson/Geo-UK-Postcode-Regex/issues\n";

                } else {

                    next if $match && ( $area . $district ) !~ $match;

                    if ( $args{split_postcode} ) {
                        $pc{$out_col} = $area . $district;
                        $pc{$in_col}  = $sector . $unit;
                    }
                }
            }

            last;
        }

        return \%pc;
    };

    return $iterator;
}

sub batch_iterator {
    my ( $self, %args ) = @_;

    my $batch_size = $args{batch_size} || 100;

    my $read_iterator = $self->read_iterator(%args);

    return sub {

        my $i = 1;
        my @postcodes;

        while ( my $pc = $read_iterator->() ) {
            push @postcodes, $pc;
            last if ++$i > $batch_size;
        }

        return @postcodes;
    };
}

1;

__END__