File Coverage

blib/lib/perfSONAR_PS/DB/File.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package perfSONAR_PS::DB::File;

use fields 'FILE', 'XML', 'LOGGER';

use strict;
use warnings;

our $VERSION = 0.09;

=head1 NAME

perfSONAR_PS::DB::File - A module that provides methods for adding 'database
like' functions to files that contain XML markup.

=head1 DESCRIPTION

This purpose of this module is to ease the burden for someone who simply wishes
to use a flat file as an XML database.  It should be known that this is not
recommended as performance will no doubt suffer, but the ability to do so can
be valuable.  The module is to be treated as an object, where each instance of
the object represents a direct connection to a file.  Each method may then be
invoked on the object for the specific database.

=cut

use XML::LibXML;
use Log::Log4perl qw(get_logger :nowarn);
use Params::Validate qw(:all);

use perfSONAR_PS::Common;
use perfSONAR_PS::ParameterValidation;

=head2 new($package, { file })

The only argument is a string representing the file to be opened.

=cut

sub new {
    my ( $package, @args ) = @_;
    my $parameters = validateParams( @args, { file => 0 } );

    my $self = fields::new($package);
    $self->{LOGGER} = get_logger("perfSONAR_PS::DB::File");
    if ( defined $parameters->{file} and $parameters->{file} ) {
        $self->{FILE} = $parameters->{file};
    }
    return $self;
}

=head2 setFile($self, { file })

(Re-)Sets the name of the file to be used.

=cut

sub setFile {
    my ( $self, @args ) = @_;
    my $parameters = validateParams( @args, { file => 1 } );

    if ( $parameters->{file} =~ m/\.xml$/mx ) {
        $self->{FILE} = $parameters->{file};
        return 0;
    }
    else {
        $self->{LOGGER}->error("Cannot set filename.");
        return -1;
    }
}

=head2 openDB($self, { error })

Opens the database, will return status of operation.

=cut

sub openDB {
    my ( $self, @args ) = @_;
    my $parameters = validateParams( @args, { error => 0 } );

    if ( defined $self->{FILE} ) {
        my $parser = XML::LibXML->new();
        $self->{XML} = $parser->parse_file( $self->{FILE} );
        ${ $parameters->{error} } = q{} if ( defined $parameters->{error} );
        return 0;
    }
    else {
        my $msg = "Cannot open database, missing filename.";
        $self->{LOGGER}->error($msg);
        ${ $parameters->{error} } = $msg if ( defined $parameters->{error} );
        return -1;
    }
}

=head2 closeDB($self, { error })

Close the database, will return status of operation.

=cut

sub closeDB {
    my ( $self, @args ) = @_;
    my $parameters = validateParams( @args, { error => 0 } );

    if ( defined $self->{XML} and $self->{XML} ) {
        if ( defined open( my $FILE, ">", $self->{FILE} ) ) {
            print $FILE $self->{XML}->toString;
            my $status = close($FILE);
            if ( $status  ) {
                ${ $parameters->{error} } = q{} if ( defined $parameters->{error} );
                return 0;
            }
            else {
                my $msg = "File close failed.";
                $self->{LOGGER}->error($msg);
                ${ $parameters->{error} } = $msg if ( defined $parameters->{error} );
                return -1;
            }
        }
        else {
            my $msg = "Couldn't open output file \"" . $self->{FILE} . "\"";
            $self->{LOGGER}->error($msg);
            ${ $parameters->{error} } = $msg if ( defined $parameters->{error} );
            return -1;
        }
    }
    else {
        my $msg = "LibXML DOM structure not defined.";
        $self->{LOGGER}->error($msg);
        ${ $parameters->{error} } = $msg if ( defined $parameters->{error} );
        return -1;
    }
}

=head2 query($self, { query, error } )

Given a query, returns the results or nothing.

=cut

sub query {
    my ( $self, @args ) = @_;
    my $parameters = validateParams( @args, { query => 1, error => 0 } );

    my @results = ();
    if ( $parameters->{query} ) {
        $self->{LOGGER}->debug( "Query \"" . $parameters->{query} . "\" received." );
        if ( defined $self->{XML} and $self->{XML} ) {
            my $nodeset = $self->{XML}->find( $parameters->{query} );
            foreach my $node ( @{$nodeset} ) {
                push @results, $node->toString;
            }
            ${ $parameters->{error} } = q{} if ( defined $parameters->{error} );
            return @results;
        }
        else {
            my $msg = "LibXML DOM structure not defined.";
            $self->{LOGGER}->error($msg);
            ${ $parameters->{error} } = $msg if ( defined $parameters->{error} );
            return -1;
        }
    }
    else {
        my $msg = "Missing argument.";
        $self->{LOGGER}->error($msg);
        ${ $parameters->{error} } = $msg if ( defined $parameters->{error} );
        return -1;
    }
}

=head2 querySet($self, { query error } )

Given a query, returns the results (as a nodeset) or nothing.

=cut

sub querySet {
    my ( $self, @args ) = @_;
    my $parameters = validateParams( @args, { query => 1, error => 0 } );

    if ( $parameters->{query} ) {
        $self->{LOGGER}->debug( "Query \"" . $parameters->{query} . "\" received." );
        if ( defined $self->{XML} and $self->{XML} ) {
            ${ $parameters->{error} } = q{} if ( defined $parameters->{error} );
            return $self->{XML}->find( $parameters->{query} );
        }
        else {
            my $msg = "LibXML DOM structure not defined.";
            $self->{LOGGER}->error($msg);
            ${ $parameters->{error} } = $msg if ( defined $parameters->{error} );
            return -1;
        }
    }
    else {
        my $msg = "Missing argument.";
        $self->{LOGGER}->error($msg);
        ${ $parameters->{error} } = $msg if ( defined $parameters->{error} );
        return -1;
    }
}

=head2 count($self, { query error } )

Counts the results of a query.

=cut

sub count {
    my ( $self, @args ) = @_;
    my $parameters = validateParams( @args, { query => 1, error => 0 } );

    if ( $parameters->{query} ) {
        $self->{LOGGER}->debug( "Query \"" . $parameters->{query} . "\" received." );
        if ( defined $self->{XML} and $self->{XML} ) {
            my $nodeset = $self->{XML}->find( $parameters->{query} );
            ${ $parameters->{error} } = q{} if ( defined $parameters->{error} );
            return $nodeset->size();
        }
        else {
            my $msg = "LibXML DOM structure not defined.";
            $self->{LOGGER}->error($msg);
            ${ $parameters->{error} } = $msg if ( defined $parameters->{error} );
            return -1;
        }
    }
    else {
        my $msg = "Missing argument.";
        $self->{LOGGER}->error($msg);
        ${ $parameters->{error} } = $msg if ( defined $parameters->{error} );
        return -1;
    }
}

=head2 getDOM($self, { error } )

Returns the internal XML::LibXML DOM object. Will return "" on error.

=cut

sub getDOM {
    my ( $self, @args ) = @_;
    my $parameters = validateParams( @args, { error => 0 } );

    if ( defined $self->{XML} and $self->{XML} ) {
        ${ $parameters->{error} } = q{} if ( defined $parameters->{error} );
        return $self->{XML};
    }
    else {
        my $msg = "LibXML DOM structure not defined.";
        $self->{LOGGER}->error($msg);
        ${ $parameters->{error} } = $msg if ( defined $parameters->{error} );
        return -1;
    }
}

=head2 setDOM($self, { dom, error } )

Sets the DOM object.

=cut

sub setDOM {
    my ( $self, @args ) = @_;
    my $parameters = validateParams( @args, { dom => 1, error => 0 } );

    if ( $parameters->{dom} ) {
        $self->{XML} = $parameters->{dom};
        ${ $parameters->{error} } = q{} if ( defined $parameters->{error} );
        return 0;
    }
    else {
        my $msg = "Missing argument.";
        $self->{LOGGER}->error($msg);
        ${ $parameters->{error} } = $msg if ( defined $parameters->{error} );
        return -1;
    }
}

1;

__END__