| 1 | package Helm::Conf::Loader::helm; | ||
| 2 | use strict; | ||
| 3 | use warnings; | ||
| 4 | use Moose; | ||
| 5 | use namespace::autoclean; | ||
| 6 | use Try::Tiny; | ||
| 7 | use Config::ApacheFormat; | ||
| 8 | use Helm::Conf; | ||
| 9 | use Helm::Server; | ||
| 10 | |||
| 11 | BEGIN { | ||
| 12 | eval { require Config::ApacheFormat }; | ||
| 13 | die "Could not load Config::ApacheFormat. " | ||
| 14 | . "It must be installed to use Helm's built-in configuration format: $@" | ||
| 15 | if $@; | ||
| 16 | } | ||
| 17 | |||
| 18 | extends 'Helm::Conf::Loader'; | ||
| 19 | |||
| 20 | sub load { | ||
| 21 | my ($class, %args) = @_; | ||
| 22 | my $uri = $args{uri}; | ||
| 23 | my $helm = $args{helm}; | ||
| 24 | my $file = $uri->path || $uri->authority; | ||
| 25 | $helm->die("Config file $file does not exist!") unless -e $file; | ||
| 26 | $helm->die("Config file $file is not readable!") unless -r $file; | ||
| 27 | |||
| 28 | my $config = Config::ApacheFormat->new( | ||
| 29 | expand_vars => 1, | ||
| 30 | duplicate_directives => 'combine', | ||
| 31 | ); | ||
| 32 | try { | ||
| 33 | $config->read($file); | ||
| 34 | } catch { | ||
| 35 | $helm->die("Cannot process config file $file: $_"); | ||
| 36 | }; | ||
| 37 | |||
| 38 | my @server_blocks = $config->get('Server'); | ||
| 39 | $helm->die("No servers listed in config file $file") unless @server_blocks; | ||
| 40 | |||
| 41 | my @servers; | ||
| 42 | my %seen_server_names; | ||
| 43 | foreach my $server_block (@server_blocks) { | ||
| 44 | my $server_name = $server_block->[1]; | ||
| 45 | my $conf_block = $config->block(Server => $server_name); | ||
| 46 | my @roles = $conf_block->get('Role'); | ||
| 47 | my $port = $conf_block->get('Port'); | ||
| 48 | |||
| 49 | # expand server names in case they have ranges | ||
| 50 | my @names = Helm::Server->expand_server_names($server_name); | ||
| 51 | foreach my $name (@names) { | ||
| 52 | $helm->die("Already seen server $name in $file. Duplicate entries not allowed.") | ||
| 53 | if $seen_server_names{$name}; | ||
| 54 | Helm->debug("Adding server $name with roles: " | ||
| 55 | . join(', ', @roles) | ||
| 56 | . ($port ? " on port $port" : '')); | ||
| 57 | push(@servers, Helm::Server->new(name => $name, roles => \@roles, port => $port)); | ||
| 58 | $seen_server_names{$name}++; | ||
| 59 | } | ||
| 60 | } | ||
| 61 | |||
| 62 | return Helm::Conf->new(servers => \@servers); | ||
| 63 | } | ||
| 64 | |||
| 65 | __PACKAGE__->meta->make_immutable; | ||
| 66 | |||
| 67 | 1; |