File Coverage

blib/lib/autobox/Closure/Attributes.pm

Criterion	Covered	Total	%
statement	29	29	100.0
branch	12	12	100.0
condition	3	3	100.0
subroutine	6	6	100.0
pod			n/a
total	50	50	100.0

package autobox::Closure::Attributes;
use strict;
use warnings;
use base 'autobox';
our $VERSION = '0.04';

sub import {
    shift->SUPER::import(CODE => 'autobox::Closure::Attributes::Methods');
}

package autobox::Closure::Attributes::Methods;
use PadWalker;

sub AUTOLOAD {
    my $code = shift;
    (my $attr = our $AUTOLOAD) =~ s/.*:://;

    # we want the scalar unless the method name already a sigil
    $attr = "\$$attr" unless $attr =~ /^[\$\@\%\&\*]/;

    my $closed_over = PadWalker::closed_over($code);
    exists $closed_over->{$attr}
        or Carp::croak "$code does not close over $attr";

    my $ref = ref $closed_over->{$attr};

    if (@_) {
        return @{ $closed_over->{$attr} } = @_ if $ref eq 'ARRAY';
        return %{ $closed_over->{$attr} } = @_ if $ref eq 'HASH';
        return ${ $closed_over->{$attr} } = shift;
    }

    return $closed_over->{$attr} if $ref eq 'HASH' || $ref eq 'ARRAY';
    return ${ $closed_over->{$attr} };
}

1;

__END__