File Coverage

blib/lib/Zeal/Feed.pm

Criterion	Covered	Total	%
statement	34	36	94.4
branch			n/a
condition			n/a
subroutine	12	12	100.0
pod			n/a
total	46	48	95.8

package Zeal::Feed;

use 5.014000;
use strict;
use warnings;
use re '/s';

our $VERSION = '0.001001';

use parent qw/Class::Accessor::Fast/;
__PACKAGE__->mk_ro_accessors(qw/version/);

use Cwd qw/getcwd/;
use File::Spec::Functions qw/catfile rel2abs/;
use HTTP::Tiny;

use Archive::Tar;
use File::Slurp qw/read_file/;
use File::Which;
use XML::Rules;

sub new {
	my ($class, $url) = @_;
	$class->new_from_content(HTTP::Tiny->new->get($url)->{content});
}

sub new_from_file {
	my ($class, $file) = @_;
	$class->new_from_content(scalar read_file $file);
}

sub new_from_content {
	my ($class, $xml) = @_;
	my ($version, @urls) = @_;

	my $self = XML::Rules->parse(
		rules => {
			_default         => 'content',
			entry            => 'pass',
			url              => 'content array',
			'other-versions' => undef,
		},
		stripspaces => 3|4,
	)->($xml);
	bless $self, $class
}

sub urls {
	my ($self) = @_;
	@{$self->{url}}
}

sub url {
	my ($self) = @_;
	my @urls = $self->urls;
	$urls[int rand @urls]
}

sub _unpack_tar_to_dir {
	my ($file, $dir) = @_;
	$file = rel2abs $file;
	my $oldwd = getcwd;
	chdir $dir;
	my $tar = which 'tar' or which 'gtar';

	# uncoverable branch true
	# uncoverable condition false
	local $ENV{ZEAL_USE_INTERNAL_TAR} = 1 if $file =~ /gz$|bz2$/ && $^O eq 'solaris';

	if ($tar && !$ENV{ZEAL_USE_INTERNAL_TAR}) {
		my $arg = '-xf';
		$arg = '-xzf' if $file =~ /[.]t?gz$/;
		$arg = '-xjf' if $file =~ /[.]bz2$/;
		system $tar, $arg => $file
	} else {
		Archive::Tar->extract_archive($file);
	}
	chdir $oldwd;
}

sub download {
	my ($self, $path) = @_;
	my ($name) = $self->url =~ /([^\/])+$/;
	my $file = catfile $path, $name;
	HTTP::Tiny->new->mirror($self->url, $file);
	_unpack_tar_to_dir $file, $path;
	unlink $file;
}

1;
__END__