File Coverage

blib/lib/YA/CLI/ActionRole.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	10	10	100.0
condition			n/a
subroutine	13	13	100.0
pod	4	6	66.6
total	66	68	97.0

package YA::CLI::ActionRole;
our $VERSION = '0.007';
use Moo::Role;
use namespace::autoclean;

# ABSTRACT: Action handler role

use YA::CLI::Usage;
use Getopt::Long;
use List::Util qw(none any);

with 'YA::CLI::PodRole';

requires qw(
    action
    run
);

has _cli_args => (
  is        => 'ro',
  predicate => '_has_cli_args',
  writer    => '_set_cli_args',
  init_args => undef,
  default   => sub { {} },
);

sub cli_options {
    return;
}

sub BUILD {
    my ($self, $args) = @_;

    foreach (keys %$args) {
        delete $args->{$_} if $self->can($_);
    }
    $self->_set_cli_args($args) if %$args;
}

sub new_from_args {
    my ($class, $args) = @_;
    return $class->new($class->get_opts($args));
}

sub get_opts {
    my ($class, $args) = @_;

    my $p = Getopt::Long::Parser->new(
        config => [qw(no_auto_abbrev) ]
    );

    my %cli_args;
    $p->getoptionsfromarray($args, \%cli_args, $class->cli_options);
    return %cli_args;
}

sub has_action {
    my $self = shift;
    my $action  = shift;
    my $subaction = shift;

    return if none { $action eq $_ } $self->action;

    return $self->has_subaction($subaction);
}

sub has_subaction {
    my $self = shift;
    my $subaction = shift;

    return -1 unless $self->can('subaction');
    return 0 unless defined $subaction;
    return any { $subaction eq $_ } $self->subaction;
}

1;

__END__