| 1 | #!/usr/bin/perl | ||
| 2 | # made by: KorG | ||
| 3 | # vim: cc=119 et sw=4 ts=4 : | ||
| 4 | package X11::korgwm::Panel::Clock; | ||
| 5 | use strict; | ||
| 6 | use warnings; | ||
| 7 | use feature 'signatures'; | ||
| 8 | |||
| 9 | use AnyEvent; | ||
| 10 | use POSIX qw( strftime ); | ||
| 11 | use X11::korgwm::Common; | ||
| 12 | use X11::korgwm::Panel; | ||
| 13 | |||
| 14 | # Add panel element | ||
| 15 | &X11::korgwm::Panel::add_element("clock", sub($el, %params) { | ||
| 16 | my $ebox = $params{ebox} or croak "Clock EventBox undefined"; | ||
| 17 | my $panel = $params{panel} or croak "Clock Panel undefined"; | ||
| 18 | |||
| 19 | # Handle separate calendar for each panel | ||
| 20 | my $calendar; | ||
| 21 | my $calendar_x_base = $panel->{x} + $panel->{width}; | ||
| 22 | my $calendar_y_base = $panel->{y} + $panel->{height}; | ||
| 23 | |||
| 24 | # Allocate a destructor | ||
| 25 | my $calendar_destroy = sub { | ||
| 26 | return unless $calendar; | ||
| 27 | pinned_remove(X11::korgwm::Window->mock($calendar->get_window()->get_xid())); | ||
| 28 | $calendar->destroy(); | ||
| 29 | undef $calendar; | ||
| 30 | }; | ||
| 31 | |||
| 32 | # Create new GtkCalendar window | ||
| 33 | $ebox->signal_connect('button-press-event', sub ($obj, $e) { | ||
| 34 | return $calendar_destroy->() if $calendar; | ||
| 35 | |||
| 36 | # Create and show the calendar | ||
| 37 | $calendar = Gtk3::Window->new('popup'); | ||
| 38 | my $widget = Gtk3::Calendar->new(); | ||
| 39 | $widget->signal_connect("month-changed" => sub { | ||
| 40 | my ($d, $m, $y) = (localtime)[3, 4, 5]; | ||
| 41 | $y += 1900; | ||
| 42 | if ($widget->get_property('month') == $m and $widget->get_property('year') == $y) { | ||
| 43 | $widget->select_day($d) | ||
| 44 | } else { | ||
| 45 | $widget->select_day(0); | ||
| 46 | } | ||
| 47 | }); | ||
| 48 | $calendar->add($widget); | ||
| 49 | $calendar->show_all; | ||
| 50 | pinned_add(X11::korgwm::Window->mock($calendar->get_window()->get_xid())); | ||
| 51 | |||
| 52 | # Move it to the right side of the relevant screen | ||
| 53 | $calendar->move($calendar_x_base - ($calendar->get_size())[0], $calendar_y_base); | ||
| 54 | }); | ||
| 55 | |||
| 56 | # Return watcher | ||
| 57 | AE::timer 0, 1, sub { $el->set_text(strftime($cfg->{clock_format}, localtime) =~ s/ +/ /gr) }; | ||
| 58 | }); | ||
| 59 | |||
| 60 | 1; |