File Coverage

blib/lib/WordNet/Similarity/random.pm

Criterion	Covered	Total	%
statement	4	6	66.6
branch			n/a
condition			n/a
subroutine	2	2	100.0
pod			n/a
total	6	8	75.0

# WordNet::Similarity::random.pm version 2.04
# (Last updated $Id: random.pm,v 1.15 2008/03/27 06:21:17 sidz1979 Exp $)
#
# Random semantic distance generator module.
#
# Copyright (c) 2005,
#
# Ted Pedersen, University of Minnesota Duluth
# tpederse at d.umn.edu
#
# Siddharth Patwardhan, University of Utah, Salt Lake City
# sidd at cs.utah.edu
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to
#
# The Free Software Foundation, Inc.,
# 59 Temple Place - Suite 330,
# Boston, MA  02111-1307, USA.
#
# ------------------------------------------------------------------

package WordNet::Similarity::random;

=head1 NAME

WordNet::Similarity::random - Perl module for computing semantic relatedness
of word senses using a random measure.

=head1 SYNOPSIS

  use WordNet::Similarity::random;

  use WordNet::QueryData;

  my $wn = WordNet::QueryData->new();

  my $random = WordNet::Similarity::random->new($wn);

  my $value = $random->getRelatedness("car#n#1", "bus#n#2");

  ($error, $errorString) = $random->getError();

  die "$errorString\n" if($error);

  print "car (sense 1) <-> bus (sense 2) = $value\n";

=head1 DESCRIPTION

This module generates random numbers as a measure of semantic relatedness
of word senses. It is possible to assign a random value for a word sense
pair and return the same value if the same word sense pair is passed as
input. It is also possible to generate a new random value for the same
word sense pair every time.

=head2 Methods

=over

=cut

use strict;

use WordNet::Similarity;

use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);

@ISA = qw(WordNet::Similarity);

%EXPORT_TAGS = ();

@EXPORT_OK = ();

@EXPORT = ();

$VERSION = '2.04';

WordNet::Similarity::addConfigOption ('maxrand', 1, 'f', 1.0);

=item $random->setPosList()

This method is internally called to determine the parts of speech
this measure is capable of dealing with.

Parameters: none.

Returns: none.

=cut

sub setPosList
{
  my $self = shift;
  $self->{n} = 1;
  $self->{v} = 1;
  $self->{a} = 1;
  $self->{r} = 1;
}

=item $random->initialize($file)

Overrides the initialize method in the parent class. This method
essentially initializes the measure for use.

Parameters: $file -- configuration file.

Returns: none.

=cut

# Initialization of the WordNet::Similarity::random object... parses the config file and sets up
# global variables, or sets them to default values.
# INPUT PARAMS  : $paramFile .. File containing the module specific params.
# RETURN VALUES : (none)
sub initialize
{
  my $self = shift;
  $self->SUPER::initialize (@_);
  $self->{maxCacheSize} = WordNet::Similarity::UNLIMITED_CACHE;
}

=item $random->getRelatedness ($synset1, $synset2)

Returns a value for the relatedness of the two synsets.  This value is
a random number greater-than or equal-to zero and less-than 'maxrand'.

If the synsets are not properly formed word#pos#sense strings, or if they
are not found in WordNet, then the error level will be set to non-zero and
an error string will be generated.

=cut

sub getRelatedness
{
  my $self = shift;
  my $wps1 = shift;
  my $wps2 = shift;
  my $wn = $self->{wn};
  my $class = ref $self || $self;

  # check if the synsets are well-formed and are found in WordNet
  my $ref = $self->parseWps ($wps1, $wps2);
  ref $ref or return $ref;

  # Initialize traces.
  $self->{traceString} = "";

  # Now check if the similarity value for these two synsets is in
  # fact in the cache... if so return the cached value.
  my $relatedness =
    $self->{doCache} ? $self->fetchFromCache ($wps1, $wps2) : undef;
  defined $relatedness and return $relatedness;

  # Now get down to really finding the relatedness of these two.

  my $score = rand ($self->{maxrand});
  $score = sprintf ("%.3f", $score);

  $self->{doCache} and $self->storeToCache ($wps1, $wps2, $score);
  return $score;
}

=item $random->traceOptions()

This method is internally called to determine the extra options
specified by this measure (apart from the default options specified
in the WordNet::Similarity base class).

Parameters: none.

Returns: none.

=cut

# 12/5/03 JM (#1)
# show all config options specific to this module
sub traceOptions {
  my $self = shift;
  $self->{traceString} .= "maxrand :: $self->{maxrand}\n";
  $self->SUPER::traceOptions();
}

1;

__END__