File Coverage

blib/lib/WordNet/Similarity/jcn.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

# WordNet::Similarity::jcn.pm version 2.04
# (Last updated $Id: jcn.pm,v 1.23 2008/03/27 06:21:17 sidz1979 Exp $)
#
# Semantic Similarity Measure package implementing the measure
# described by Jiang and Conrath (1997).
#
# Copyright (c) 2005,
#
# Ted Pedersen, University of Minnesota Duluth
# tpederse at d.umn.edu
#
# Siddharth Patwardhan, University of Utah, Salt Lake City
# sidd at cs.utah.edu
#
# Jason Michelizzi, Univeristy of Minnesota Duluth
# mich0212 at d.umn.edu
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to
#
# The Free Software Foundation, Inc.,
# 59 Temple Place - Suite 330,
# Boston, MA  02111-1307, USA.
#
# ------------------------------------------------------------------

package WordNet::Similarity::jcn;

=head1 NAME

WordNet::Similarity::jcn - Perl module for computing semantic relatedness
of word senses according to the method described by Jiang and Conrath
(1997).

=head1 SYNOPSIS

  use WordNet::Similarity::jcn;

  use WordNet::QueryData;

  my $wn = WordNet::QueryData->new();

  my $rel = WordNet::Similarity::jcn->new($wn);

  my $value = $rel->getRelatedness("car#n#1", "bus#n#2");

  ($error, $errorString) = $rel->getError();

  die "$errorString\n" if($error);

  print "car (sense 1) <-> bus (sense 2) = $value\n";

=head1 DESCRIPTION

This module computes the semantic relatedness of word senses according to
the method described by Jiang and Conrath (1997). This measure is based on
a combination of using edge counts in the WordNet 'is-a' hierarchy and
using the information content values of the WordNet concepts, as described
in the paper by Jiang and Conrath. Their measure, however, computes values
that indicate the semantic distance between words (as opposed to their
semantic relatedness). In this implementation of the measure we invert the
value so as to obtain a measure of semantic relatedness. Other issues that
arise due to this inversion (such as handling of zero values in the
denominator) have been taken care of as special cases.

=over

=cut

use strict;
use warnings;

use Exporter;
use WordNet::Similarity::ICFinder;

our (@ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);

@ISA = qw(WordNet::Similarity::ICFinder);

%EXPORT_TAGS = ();

@EXPORT_OK = ();

@EXPORT = ();

our $VERSION = '2.04';

# the 'new' method is supplied by WordNet::Similarity

=item $jcn->getRelatedness ($synset1, $synset2)

Computes the relatedness of two word senses using an information content
scheme.  See the discussion section below for detailed information on how
the jcn measure calculates relatedness.

Parameters: two word senses in "word#pos#sense" format.

Returns: Unless a problem occurs, the return value is the relatedness
score.  If no path exists between the two word senses, then a large
negative number is returned.  If an error occures, then the error level
is set to non-zero and an error string is created (see the description
of getError()).  Note: the error level will also be set to 1 and an
an error string will be created if no path exists between the words.

=cut

sub getRelatedness
{
  my $self = shift;
  my $wps1 = shift;
  my $wps2 = shift;
  my $wn = $self->{wn};
  my $class = ref $self || $self;

  # Check the existence of the WordNet::QueryData object.
  unless ($wn) {
    $self->{errorString} .= "\nError (${class}::getRelatedness()) - ";
    $self->{errorString} .= "A WordNet::QueryData object is required.";
    $self->{error} = 2;
    return undef;
  }

  # Initialize traces.
  $self->{traceString} = "";

  # JM 1-21-04
  # moved input validation code to parseInput() in a super-class
  my $ret = $self->parseWps ($wps1, $wps2);
  ref $ret or return $ret;
  my ($word1, $pos1, undef, $offset1, $word2, $pos2, undef, $offset2) = @{$ret};

  my $pos = $pos1;

  # Now check if the similarity value for these two synsets is in
  # fact in the cache... if so return the cached value.
  my $relatedness =
    $self->{doCache} ? $self->fetchFromCache ($wps1, $wps2) : undef;
  defined $relatedness and return $relatedness;

  # Now get down to really finding the relatedness of these two.
  my $mode = 'offset';
  my @LCSs = $self->getLCSbyIC ($offset1, $offset2, $pos, 'offset');

  my $ref = shift @LCSs;
  # check if $ref is a reference, if not, then return undefined
  # $ref will not be a reference if no LCS was found
  unless (ref $ref) {
    return $self->UNRELATED;
  }

  my ($lcs, $lcsic) = @{$ref};
  my $lcsfreq = $self->getFrequency ($lcs, $pos, 'offset');

  # Check for the rare possibility of the root node having 0
  # frequency count...
  # If normal (i.e. freqCount(root) > 0)... Set the minimum distance to the
  # greatest distance possible + 1... (my replacement for infinity)...
  # If zero root frequency count... return 0 relatedness, with a warning...

  my $maxScore;
  my $rootFreq = $self->getFrequency (0, $pos, 'offset');
  if($rootFreq) {
#    $minDist = (2*(-log(0.001/($self->{offsetFreq}->{$pos}->{0})))) + 1;
    $maxScore = 2 * -log (0.001 / $rootFreq) + 1;
  }
  else {
    $self->{errorString} .= "\nWarning (${class}::getRelatedness()) - ";
    $self->{errorString} .= "Root node has a zero frequency count.";
    $self->{error} = ($self->{error} < 1) ? 1 : $self->{error};
    return 0;
  }

  # Foreach lowest common subsumer...
  # Find the minimum jcn distance between the two subsuming concepts...
  # Making sure that neither of the 2 concepts have 0 infocontent
  my $ic1 = $self->IC($offset1, $pos);
  my $ic2 = $self->IC($offset2, $pos);
  if ($self->{trace}) {
    $self->{traceString} .= "Concept1: ";
    $self->printSet ($pos, $mode, $offset1);
    $self->{traceString} .= " (IC=";
    $self->{traceString} .= sprintf ("%.6f", $ic1);
    $self->{traceString} .= ")\n";
    $self->{traceString} .= "Concept2: ";
    $self->printSet ($pos, $mode, $offset2);
    $self->{traceString} .= " (IC=";
    $self->{traceString} .= sprintf ("%.6f", $ic2);
    $self->{traceString} .= ")\n";
  }

  my $distance;

  # If either of the two concepts have a zero information content...
  # return 0, for lack of data...
  if($ic1 && $ic2) {
    my $ic3 = $self->IC($lcs, $pos);

    $distance = $ic1 + $ic2 - (2 * $ic3);
  }
  else {
    return 0;
  }

  # Now if distance turns out to be 0...
  # implies ic1 == ic2 == ic3 (most probably all three represent
  # the same concept)... i.e. maximum relatedness... i.e. infinity...
  # We'll return the maximum possible value ("Our infinity").
  # Here's how we got our infinity...
  # distance = ic1 + ic2 - (2 x ic3)
  # Largest possible value for (1/distance) is infinity, when distance = 0.
  # That won't work for us... Whats the next value on the list...
  # the smallest value of distance greater than 0...
  # Consider the formula again... distance = ic1 + ic2 - (2 x ic3)
  # We want the value of distance when ic1 or ic2 have information content
  # slightly more than that of the root (ic3)... (let ic2 == ic3 == 0)
  # Assume frequency counts of 0.01 less than the frequency count of the
  # root for computing ic1...
  # sim = 1/ic1
  # sim = 1/(-log((freq(root) - 0.01)/freq(root)))

  my $score;

  if ($distance == 0) {
    if ($rootFreq > 0.01) {
      $score = 1 / -log (($rootFreq - 0.01) / $rootFreq);
    }
    else {
      # root frequency is 0
      return 0;
    }
  }
  else { # distance is non-zero
    $score = 1 / $distance
  }
  $self->{doCache} and $self->storeToCache ($wps1, $wps2, $score);
  return $score;
}

# JM 1-16-04
# moved subroutine _getLeastCommonSubsumers to Infocontent.pm

1;

__END__