File Coverage

blib/lib/Wikibase/Cache/Backend/Basic.pm

Criterion	Covered	Total	%
statement	43	44	97.7
branch	3	4	75.0
condition			n/a
subroutine	11	11	100.0
pod	1	1	100.0
total	58	60	96.6

package Wikibase::Cache::Backend::Basic;

use base qw(Wikibase::Cache::Backend);
use strict;
use warnings;

use Class::Utils qw(set_params);
use Data::Handle;
use Error::Pure qw(err);
use Text::DSV;

our $VERSION = 0.05;

sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# Data handler.
	$self->{'data_fh'} = Data::Handle->new(__PACKAGE__);

	# Process parameters.
	set_params($self, @params);

	$self->_load_data;

	return $self;
}

sub _get {
	my ($self, $type, $key) = @_;

	if (exists $self->{static}->{$key}) {
		if (exists $self->{static}->{$key}->{$type}) {
			return $self->{static}->{$key}->{$type};
		} else {
			return;
		}
	} else {
		return;
	}
}

sub _load_data {
	my $self = shift;

	# Read data.
	my $dsv = Text::DSV->new;
	my $fh = $self->{'data_fh'};
	while (my $data = <$fh>) {
		chomp $data;
		my ($qid, $label, $description) = $dsv->parse_line($data);
		$self->{'static'}->{$qid}->{'label'} = $label;
		$self->{'static'}->{$qid}->{'description'} = $description;
	}

	return;
}

sub _save {
	my ($self, $type, $key, $value) = @_;

	err __PACKAGE__." doesn't implement save() method.";
}

1;

=pod

=encoding utf8

=head1 NAME

Wikibase::Cache::Backend::Basic - Wikibase cache backend to local static basic ids (units, common properties)

=head1 SYNOPSIS

 use Wikibase::Cache::Backend::Basic;

 my $obj = Wikibase::Cache::Backend::Basic->new;
 my $value = $obj->get($type, $key);
 $obj->save($type, $key, $value);

=head1 METHODS

=head2 C

 my $obj = Wikibase::Cache::Backend::Basic->new;

Constructor.

=over 8

=item * C

Data file handler from which is mapping fetched.
Data file is in format parsed by L.

Default value is mapping in this file on the end.

=back

Returns instance of object.

=head2 C

 my $value = $obj->get($type, $key);

Get cache value for C<$type> and C<$key>.
Possible types are 'description' and 'label'.

Returns string.

=head2 C

 $obj->save($type, $key, $value);

Save method is not implemented in this implementation of backend.
Goes to error.

=head1 ERROR

 new():
         From Class::Utils::set_params():
                 Unknown parameter '%s'.

 get():
         Type '%s' isn't supported.
         Type must be defined.';

 save():
         Type '%s' isn't supported.
         Type must be defined.';
         Wikibase::Cache::Backend::Basic doesn't implement save() method.


=head1 EXAMPLE

=for comment filename=p31_label_and_description.pl

 use strict;
 use warnings;

 use Wikibase::Cache::Backend::Basic;

 my $obj = Wikibase::Cache::Backend::Basic->new;

 # Print out.
 print 'P31 label: '.$obj->get('label', 'P31')."\n";
 print 'P31 description: '.$obj->get('description', 'P31')."\n";

 # Output:
 # P31 label: instance of
 # P31 description: that class of which this subject is a particular example and member

=head1 DEPENDENCIES

L,
L,
L,
L,
L.

=head1 REPOSITORY

L

=head1 AUTHOR

Michal Josef Špaček L

L

=head1 LICENSE AND COPYRIGHT

© 2021-2025 Michal Josef Špaček

BSD 2-Clause License

=head1 VERSION

0.05

=cut

__DATA__