File Coverage

blib/lib/WebService/SmartyStreets.pm

Criterion	Covered	Total	%
statement	15	15	100.0
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod			n/a
total	20	20	100.0

package WebService::SmartyStreets;
$WebService::SmartyStreets::VERSION = '0.0102';
use Moo;
with 'WebService::BaseClientRole';

# VERSION

use aliased 'WebService::SmartyStreets::Exception::AddressNotFound';
use aliased 'WebService::SmartyStreets::Exception::AddressMissingInformation';

use Function::Parameters ':strict';
use URI;

has auth_id    => ( is => 'ro', required => 1 );
has auth_token => ( is => 'ro', required => 1 );

has '+base_url' => (
    default => sub {
        my $self = shift;
        my $uri = URI->new('https://api.smartystreets.com/street-address');
        $uri->query_form(
            'auth-id'    => $self->auth_id,
            'auth-token' => $self->auth_token,
        );
        return $uri->as_string;
    },
);

method verify_address(
    Str :$street,
    Str :$street2 = '',
    Str :$city,
    Str :$state,
    Str :$zipcode = '',
    Int :$candidates = 2
) {
    my $results = $self->post($self->base_url, [{
        street     => $street,
        street2    => $street2,
        city       => $city,
        state      => $state,
        zipcode    => $zipcode,
        candidates => $candidates,
    }]);

    AddressNotFound->throw unless $results and @$results;
    AddressMissingInformation->throw if @$results == 1
        and $results->[0]{analysis}{dpv_match_code} eq 'D';

    return [
        map {{
            street  => $_->{delivery_line_1},
            (street2 => $_->{delivery_line_2}) x!! $_->{delivery_line_2},
            city    => $_->{components}{city_name},
            state   => $_->{components}{state_abbreviation},
            zipcode => $_->{components}{zipcode} . '-' . $_->{components}{plus4_code},
        }} @$results
    ];
}


1;

__END__