File Coverage

blib/lib/WebService/OpenStates.pm

Criterion	Covered	Total	%
statement	38	70	54.2
branch	0	16	0.0
condition	0	27	0.0
subroutine	14	15	93.3
pod	1	1	100.0
total	53	129	41.0

package WebService::OpenStates;

our $VERSION = '1.03';

use strict;
use warnings;
use v5.14;

use Carp 'croak';
use HTTP::Tiny;
use Function::Parameters;
use Types::Common::String 'NonEmptyStr';
use Types::Common::Numeric 'NumRange';
use JSON::MaybeXS;
use URI;
use Moo;
use namespace::clean;

##
has api_key => (
    is       => 'ro',
    isa      => NonEmptyStr,
    required => 1,
    default  => sub { $ENV{OPENSTATES_API_KEY} },
);

##
has _api_url => (
    is       => 'lazy',
    init_arg => undef,
    builder  => sub { 'https://v3.openstates.org/people.geo' },
);

##
has _client => (
    is       => 'lazy',
    init_arg => undef,
    builder  => sub {
        state $ua = HTTP::Tiny->new;
        return $ua;
    },
);

##
method legislators_for_location ((NumRange[-90,90]) :$lat, (NumRange[-180,180]) :$lon) {
    my $uri = URI->new( $self->_api_url );
    $uri->query_form(
        apikey  => $self->api_key,
        lat     => $lat,
        lng     => $lon,
        include => ['links', 'offices'],
    );

    my $call = $self->_client->get( $uri );

    my $response = try {
        if ( ! $call->{success} ) {
            my $resp = { status => 'error', content => decode_json( $call->{content} ) };
            return $resp;
        }
        else {
            my $data = decode_json( $call->{content} );

            my @result;

            my @legislators = @{ $data->{results} };

            for my $legislator (sort { $a->{family_name} cmp $b->{family_name} } @legislators) {
                my $result = {
                    name    => $legislator->{name},
                    title   => join(' ', $legislator->{jurisdiction}{name}, $legislator->{current_role}{title}),
                    party   => $legislator->{party},
                    email   => $legislator->{email},
                    links   => [map {$_->{url}} @{$legislator->{links}}],
                    offices => [ map {+{name => $_->{name}, phone => $_->{voice}, address => $_->{address} }} @{$legislator->{offices}}],
                };

                push(@result, $result);
            }

            return { status => 'success', legislators => \@result };
        }
    }
    catch {
        return { status => 'error', content => "Caught fatal error trying to call Open States API: $_" };
    };

    return $response;
}

1; # return true

__END__