File Coverage

blib/lib/WebService/LastFM/TrackInfo.pm

Criterion	Covered	Total	%
statement	41	44	93.1
branch	8	10	80.0
condition	5	6	83.3
subroutine	11	12	91.6
pod	1	1	100.0
total	66	73	90.4

package WebService::LastFM::TrackInfo;
our $AUTHORITY = 'cpan:GENE';

# ABSTRACT: Access to the track.getInfo slice of the LastFM API

our $VERSION = '0.0204';

use Moo;
use strictures 2;
use namespace::clean;

use Carp;
use Mojo::UserAgent;
use Mojo::JSON qw(decode_json);
use Mojo::URL;
use Try::Tiny;


has api_key => (
    is       => 'ro',
    required => 1,
);


has method => (
    is      => 'ro',
    default => sub { 'track.getInfo' },
);


has format => (
    is      => 'ro',
    default => sub { 'json' },
);


has base => (
    is      => 'rw',
    default => sub { 'http://ws.audioscrobbler.com' },
);


has version => (
    is      => 'ro',
    default => sub { '2.0' },
);


has ua => (
    is      => 'rw',
    default => sub { Mojo::UserAgent->new },
);


sub fetch {
    my ( $self, %args ) = @_;

    croak 'No artist provided' unless $args{artist};
    croak 'No track provided' if $self->method eq 'track.getInfo' && !$args{track};
    croak 'No album provided' if $self->method eq 'album.getInfo' && !$args{album};

    my $url = Mojo::URL->new($self->base)
        ->path($self->version)
        ->query(
            %args,
            api_key => $self->api_key,
            method  => $self->method,
            format  => $self->format,
        );

    my $tx = $self->ua->get($url);

    my $data = $self->_handle_response($tx);

    return $data;
}

sub _handle_response {
    my ($self, $tx) = @_;

    my $data;

    my $res = $tx->result;

    if ( $res->is_success ) {
        my $body = $res->body;

        if ($self->format eq 'json') {
            try {
                $data = decode_json($body);
            }
            catch {
                croak $body, "\n";
            };
        }
        else {
            $data = $body;
        }
    }
    else {
        croak 'Connection error: ', $res->message;
    }

    return $data;
}

1;

__END__