File Coverage

blib/lib/WebService/Hexonet/Connector/ResponseTemplateManager.pm

Criterion	Covered	Total	%
statement	56	56	100.0
branch	4	4	100.0
condition	1	3	33.3
subroutine	14	14	100.0
pod	8	8	100.0
total	83	85	97.6

package WebService::Hexonet::Connector::ResponseTemplateManager;

use 5.026_000;
use strict;
use warnings;
use WebService::Hexonet::Connector::ResponseTemplate;
use WebService::Hexonet::Connector::ResponseParser;

use version 0.9917; our $VERSION = version->declare('v2.9.0');

my $instance = undef;


sub getInstance {
    if ( !defined $instance ) {
        my $self = { templates => {} };
        $instance = bless $self, shift;
        $instance->addTemplate( '404',          $instance->generateTemplate( '421', 'Page not found' ) );
        $instance->addTemplate( '500',          $instance->generateTemplate( '500', 'Internal server error' ) );
        $instance->addTemplate( 'empty',        $instance->generateTemplate( '423', 'Empty API response. Probably unreachable API end point {CONNECTION_URL}' ) );
        $instance->addTemplate( 'error',        $instance->generateTemplate( '421', 'Command failed due to server error. Client should try again' ) );
        $instance->addTemplate( 'expired',      $instance->generateTemplate( '530', 'SESSION NOT FOUND' ) );
        $instance->addTemplate( 'httperror',    $instance->generateTemplate( '421', 'Command failed due to HTTP communication error' ) );
        $instance->addTemplate( 'invalid',      $instance->generateTemplate( '423', 'Invalid API response. Contact Support' ) );
        $instance->addTemplate( 'unauthorized', $instance->generateTemplate( '530', 'Unauthorized' ) );
    }
    return $instance;
}


sub generateTemplate {
    my ( $self, $code, $description ) = @_;
    return "[RESPONSE]\r\nCODE=${code}\r\nDESCRIPTION=${description}\r\nEOF\r\n";
}


sub addTemplate {
    my ( $self, $id, $plain ) = @_;
    $self->{templates}->{$id} = $plain;
    return $instance;
}


sub getTemplate {
    my ( $self, $id ) = @_;
    my $plain;
    if ( $self->hasTemplate($id) ) {
        $plain = $self->{templates}->{$id};
    } else {
        $plain = $self->generateTemplate( '500', 'Response Template not found' );
    }
    return WebService::Hexonet::Connector::ResponseTemplate->new($plain);
}


sub getTemplates {
    my $self = shift;
    my $tmp  = {};
    my $tpls = $self->{templates};
    foreach my $key ( keys %{$tpls} ) {
        $tmp->{$key} = WebService::Hexonet::Connector::ResponseTemplate->new( $tpls->{$key} );
    }
    return $tmp;
}


sub hasTemplate {
    my ( $self, $id ) = @_;
    return defined $self->{templates}->{$id};
}


sub isTemplateMatchHash {
    my ( $self, $tpl2, $id ) = @_;
    my $tpl = $self->getTemplate($id);
    my $h   = $tpl->getHash();
    return ( $h->{CODE} eq $tpl2->{CODE} ) && ( $h->{DESCRIPTION} eq $tpl2->{DESCRIPTION} );
}


sub isTemplateMatchPlain {
    my ( $self, $plain, $id ) = @_;
    my $h = WebService::Hexonet::Connector::ResponseParser::parse($plain);
    return $self->isTemplateMatchHash( $h, $id );
}

1;

__END__