File Coverage

blib/lib/WebService/HashiCorp/Vault/Secret/Kvv2.pm

Criterion	Covered	Total	%
statement	6	34	17.6
branch	0	16	0.0
condition	0	3	0.0
subroutine	2	8	25.0
pod	2	3	66.6
total	10	64	15.6

#!perl
# vim: softtabstop=4 tabstop=4 shiftwidth=4 ft=perl expandtab smarttab
# ABSTRACT: Perl API for HashiCorp's Vault (Secret)

# See also https://github.com/hashicorp/vault-ruby
# And https://github.com/ianunruh/hvac
# And https://www.vaultproject.io/api/index.html

package WebService::HashiCorp::Vault::Secret::Kvv2;

use Moo;
our $VERSION = '0.01'; # VERSION
use namespace::clean;

extends 'WebService::HashiCorp::Vault::Base';

has '+mount'  => ( is => 'ro', default => 'secret' );
has 'path'  => ( is => 'ro' );
has 'auth' => ( is => 'ro' );
has '_metadata' => ( is => 'ro' );
has 'data' => ( is => 'rw',
                trigger => sub {
                    my $self = shift;
                    $self->_save(@_);
                    $self->BUILD()
                });
has 'lease_duration' => ( is => 'ro' );
has 'lease_id' => ( is => 'ro' );
has 'renewable' => ( is => 'ro' );

sub BUILD {
    my $self = shift;
    return unless $self->path;
    $self->_clear_self();
    if (my $resp = $self->get( $self->_mkuri($self->path) )) {
        $self->{auth} = $resp->{auth}
            if $resp->{auth};
        $self->{data} = $resp->{data}->{data}; # avoid triggering the trigger
        $self->{_metadata} = $resp->{data}->{_metadata}; # avoid triggering the trigger
        $self->{lease_duration} = $resp->{lease_duration}
            if $resp->{lease_duration};
        $self->{lease_id} = $resp->{lease_id}
            if $resp->{lease_id};
        $self->{renewable} = 0 + $resp->{renewable} # convert from JSON::Boolean
            if $resp->{renewable};
    }
}

sub _mkuri {
    my $self = shift;
    my @paths = @_;
    return join '/',
        $self->base_url,
        $self->version,
        $self->mount, 'data',
        @paths
}

sub _clear_self {
    my $self = shift;
    for my $k (qw/ auth data lease_duration lease_id renewable /) {
        delete $self->{$k} if $self->{$k}
    }
    return 1
}


sub delete {
    my $self = shift;
    my $result = $self->SUPER::delete( $self->_mkuri($self->path) );
    $self->_clear_self();
    return $result
}

sub _save {
    my $self = shift;
    my $data = shift;
    die sprintf( "Secret data must be hashref, not a %s\n", ref $data )
       if ref $data ne 'HASH';
    return $self->post( $self->_mkuri($self->path), { data => $data } );
}


sub list {
    my $self = shift;
    my $result = $self->SUPER::list( $self->_mkuri($self->path || ()) );
    return $result->{data}
}


1;

__END__