File Coverage

blib/lib/WebService/HIBP.pm

Criterion	Covered	Total	%
statement	132	132	100.0
branch	30	30	100.0
condition			n/a
subroutine	21	21	100.0
pod	9	9	100.0
total	192	192	100.0

package WebService::HIBP;

use strict;
use warnings;
use JSON();
use URI::Escape();
use LWP::UserAgent();
use Digest::SHA();
use Encode();
use Unicode::Normalize();
use WebService::HIBP::Breach();
use WebService::HIBP::Paste();

our $VERSION = '0.12';

sub _LENGTH_OF_PASSWORD_PREFIX { return 5; }

sub new {
    my ( $class, %params ) = @_;
    my $self = {};
    bless $self, $class;
    $self->{url}          = 'https://haveibeenpwned.com/api/v2/';
    $self->{password_url} = 'https://api.pwnedpasswords.com/range/';
    if ( $params{user_agent} ) {
        $self->{ua} = $params{user_agent};
    }
    else {
        $self->{ua} =
          LWP::UserAgent->new( agent => "WebService-HIBP/$VERSION " );
        $self->{ua}->env_proxy();
    }
    return $self;
}

sub _get {
    my ( $self, $url ) = @_;
    my $response = $self->{ua}->get($url);
    $self->{last_response} = $response;
    return $response;
}

sub last_request {
    my ($self) = @_;
    if ( defined $self->{last_response} ) {
        return $self->{last_response}->request();
    }
    return;
}

sub last_response {
    my ($self) = @_;
    if ( defined $self->{last_response} ) {
        return $self->{last_response};
    }
    return;
}

sub data_classes {
    my ($self)   = @_;
    my $url      = $self->{url} . 'dataclasses';
    my $response = $self->_get($url);
    if ( $response->is_success() ) {
        my $json = JSON::decode_json( $response->decoded_content() );
        my @classes;
        foreach my $class ( @{$json} ) {
            push @classes, $class;
        }
        return @classes;
    }
    else {
        Carp::croak( "Failed to retrieve $url:" . $response->status_line() );
    }
}

sub breach {
    my ( $self, $name ) = @_;
    my $url      = $self->{url} . 'breach/' . $name;
    my $response = $self->_get($url);
    if ( $response->is_success() ) {
        my $json = JSON::decode_json( $response->decoded_content() );
        return WebService::HIBP::Breach->new( %{$json} );
    }
    else {
        Carp::croak( "Failed to retrieve $url:" . $response->status_line() );
    }
}

sub pastes {
    my ( $self, $account ) = @_;
    my $url =
      $self->{url} . 'pasteaccount/' . URI::Escape::uri_escape($account);
    my $response = $self->_get($url);
    if ( $response->is_success() ) {
        my $json = JSON::decode_json( $response->decoded_content() );
        my @pastes;
        foreach my $paste ( @{$json} ) {
            push @pastes, WebService::HIBP::Paste->new( %{$paste} );
        }
        return @pastes;
    }
    else {
        Carp::croak( "Failed to retrieve $url:" . $response->status_line() );
    }
}

sub breaches {
    my ( $self, %parameters ) = @_;
    my $url = $self->{url} . 'breaches';
    if ( $parameters{domain} ) {
        $url .= '?domain=' . URI::Escape::uri_escape( $parameters{domain} );
    }
    my $response = $self->_get($url);
    if ( $response->is_success() ) {
        my $json = JSON::decode_json( $response->decoded_content() );
        my @breaches;
        foreach my $breach ( @{$json} ) {
            push @breaches, WebService::HIBP::Breach->new( %{$breach} );
        }
        return @breaches;
    }
    else {
        Carp::croak( "Failed to retrieve $url:" . $response->status_line() );
    }
}

sub account {
    my ( $self, $account, %parameters ) = @_;
    my $url =
      $self->{url} . 'breachedaccount/' . URI::Escape::uri_escape($account);
    my @filters;
    if ( $parameters{unverified} ) {
        push @filters, 'includeUnverified=true';
    }
    if ( $parameters{truncate} ) {
        push @filters, 'truncateResponse=true';
    }
    if ( $parameters{domain} ) {
        push @filters,
          'domain=' . URI::Escape::uri_escape( $parameters{domain} );
    }
    if (@filters) {
        $url .= q[?] . join q[&], @filters;
    }
    my $response = $self->_get($url);
    if ( $response->is_success() ) {
        my $json = JSON::decode_json( $response->decoded_content() );
        my @breaches;
        foreach my $breach ( @{$json} ) {
            push @breaches, WebService::HIBP::Breach->new( %{$breach} );
        }
        return @breaches;
    }
    else {
        Carp::croak( "Failed to retrieve $url:" . $response->status_line() );
    }
}

sub password {
    my ( $self, $password ) = @_;
    my $normalised = Unicode::Normalize::NFD($password)
      ; # No API documentation on normalisation, chose NFD based on compatibility with the front end at https://haveibeenpwned.com/Passwords.
    my $sha1 =
      uc Digest::SHA::sha1_hex( Encode::encode( 'UTF-8', $normalised, 1 ) );
    my $url = $self->{password_url} . substr $sha1, 0,
      _LENGTH_OF_PASSWORD_PREFIX();
    my $response = $self->_get($url);
    if ( $response->is_success() ) {
        my $remainder = substr $sha1, _LENGTH_OF_PASSWORD_PREFIX();
        foreach my $line ( split /\r\n/smx, $response->decoded_content() ) {
            my ( $pwned, $count ) = split /:/smx, $line;
            if ( $pwned eq $remainder ) {
                return $count;
            }
        }
        return 0;
    }
    else {
        Carp::croak( "Failed to retrieve $url:" . $response->status_line() );
    }
}

1;    # End of WebService::HIBP
__END__