File Coverage

blib/lib/WebService/FogBugz/Config.pm

Criterion	Covered	Total	%
statement	43	43	100.0
branch	21	26	80.7
condition	13	21	61.9
subroutine	6	6	100.0
pod	2	2	100.0
total	85	98	86.7

package WebService::FogBugz::Config;

use strict;
use warnings;

our $VERSION = '0.1.2';

#----------------------------------------------------------------------------
# Library Modules

use base qw(Class::Accessor::Fast);

use IO::File;

#----------------------------------------------------------------------------
# Variables

my %NAMES = (
    'URL'       => 'base_url',
    'TOKEN'     => 'token',
    'EMAIL'     => 'email',
    'PASSWORD'  => 'password'
);

#----------------------------------------------------------------------------
# Accessors

__PACKAGE__->mk_accessors($_) for qw(base_url token email password file);

#----------------------------------------------------------------------------
# Public API

sub new {
    my $class = shift;
    my ($params) = {@_};
    my $atts = {};

    my $self = bless $atts, $class;

    my $fbrc = $params->{config};
    $fbrc ||= $ENV{FBRC};
    $fbrc = '.fbrc'             unless($fbrc && -f $fbrc);
    $fbrc = "$ENV{HOME}/.fbrc"  unless($fbrc && -f $fbrc);
    $fbrc = ''                  unless($fbrc && -f $fbrc);

    $self->readConfig($fbrc)    if($fbrc);

    my %config;
    for my $key (qw(token email password base_url)) {
        $config{$key} = $params->{$key} || $self->{$key};
    }

    $self->base_url($config{base_url}) if($config{base_url});
    $self->token(   $config{token})    if($config{token});
    $self->email(   $config{email})    if($config{email});
    $self->password($config{password}) if($config{password});
    $self->file(    $fbrc)             if($fbrc);

    return $self;
}

sub readConfig {
    my ($self, $fbrc) = @_;
    return  unless(-f $fbrc && -r $fbrc);

    my $fh = IO::File->new($fbrc,'r');
    return  unless($fh);

    my $line;
    while( defined($line = <$fh>) ) {
        $line =~ s!\s+$!!;
        next    unless($line && $line !~ /^#/);
        $line =~ s/^\s*//;
        if($line =~ /^(URL|TOKEN|EMAIL|PASSWORD)\s*=\s*(.*)/) {
            $self->{ $NAMES{$1} } = $2;
        }
    }

    $fh->close;
}

1;

__END__