File Coverage

blib/lib/WebService/Coincheck.pm

Criterion	Covered	Total	%
statement	44	64	68.7
branch	1	14	7.1
condition	0	2	0.0
subroutine	13	15	86.6
pod	3	3	100.0
total	61	98	62.2

package WebService::Coincheck;
use strict;
use warnings;
use Carp qw/croak/;
use HTTP::Tiny;
use Time::HiRes qw/time/;
use URI::Query;
use Digest::SHA qw/hmac_sha256_hex/;
use String::CamelCase qw/camelize/;
use Class::Load qw/load_class/;
use JSON qw//;
use Class::Accessor::Lite (
    ro  => [qw/
        api_base
        access_key
        secret_key
        ticker
        trade
        order_book
        order
        leverage
        account
        send
        deposit
        bank_account
        withdraw
        borrow
        transfer
    /],
    rw  => [qw/
        client
        signature
        nonce
        decode_json
    /],
);

our $VERSION = '0.04';

sub new {
    my $class = shift;
    my %args  = @_;

    my $self = bless {
        decode_json => 0,
        api_base    => 'https://coincheck.jp/',
        %args,
    }, $class;

    $self->_initialize($args{client_opt});

    return $self;
}

sub _initialize {
    my ($self, $client_opt) = @_;

    $self->client(
        HTTP::Tiny->new(
            agent   => __PACKAGE__ . "/$VERSION",
            default_headers => {
                'Content-Type' => 'application/json',
                'ACCESS-KEY'   => $self->access_key,
            },
            timeout => 15,
            verify_SSL => 1,
            %{$client_opt || {}},
        )
    );

    for my $api (qw/
        ticker
        trade
        order_book
        order
        leverage
        account
        send
        deposit
        bank_account
        withdraw
        borrow
        transfer
    /) {
        my $klass = 'WebService::Coincheck::' . camelize($api);
        $self->{$api} = load_class($klass)->new($self);
    }
}

sub set_signature {
    my ($self, $req_url, $body) = @_;

    $self->nonce(int(time * 10000));
    $self->signature(hmac_sha256_hex($self->nonce . $req_url . ($body || ''), $self->secret_key));
}

sub request {
    my ($self, $method, $req_path, $query) = @_;

    my $res;

    if ($method =~ m!^get$!i) {
        my $query_string = URI::Query->new($query)->stringify;
        my $req_url = join '', $self->api_base, $req_path, $query_string ? "?$query_string" : '';
        $self->set_signature($req_url);
        $res = $self->client->get(
            $req_url,
            {
                headers => {
                    'ACCESS-NONCE'     => $self->nonce,
                    'ACCESS-SIGNATURE' => $self->signature,
                },
            },
        );
    }
    elsif ($method =~ m!^(?:post|delete)$!i) {
        my $req_url = join '', $self->api_base, $req_path;
        my $content = $query ? JSON::encode_json($query) : '';
        $self->set_signature($req_url, $content);
        $res = $self->client->request(
            uc $method,
            $req_url,
            {
                content => $content,
                headers => {
                    'ACCESS-NONCE'     => $self->nonce,
                    'ACCESS-SIGNATURE' => $self->signature,
                },
            },
        );
    }

    unless ($res->{success}) {
        croak "Error:" . join "\t", map { $res->{$_} } (qw/url status reason content/);
    }

    if ($self->decode_json) {
        return JSON::decode_json($res->{content});
    }
    else {
        return $res->{content};
    }
}

1;

__END__