File Coverage

blib/lib/WebService/CRUST/Result.pm

Criterion	Covered	Total	%
statement	3	3	100.0
branch			n/a
condition			n/a
subroutine	1	1	100.0
pod			n/a
total	4	4	100.0

package WebService::CRUST::Result;
use base qw(Class::Accessor);

use strict;

our $VERSION = '0.7';


__PACKAGE__->mk_accessors(qw(
    result
    crust
));


sub new {
    my ($class, $h, $crust) = @_;

    my $self = bless {}, $class;
    $self->result($h);
    $self->crust($crust);

    return $self;
}



sub string {
    my $self = shift;

    return scalar $self->result;
}

# Stringify
use overload
	'""'     => sub { shift->string },
	fallback => 1;



sub AUTOLOAD {
    my $self = shift;
    our $AUTOLOAD;

    # Don't override DESTROY
    return if $AUTOLOAD =~ /::DESTROY$/;

    ( my $method = $AUTOLOAD ) =~ s/.*:://s;

    return unless $self->result and defined $self->result->{$method};

    my $result = $self->result->{$method};

    $self->{_cache}->{$method} and return $self->{_cache}->{$method};

    if (ref $result eq 'HASH') {
        $self->{_cache}->{$method} = $self->follow_result($result);
    }
    elsif (ref $result eq 'ARRAY') {
        my @results = @$result;

        my @response;
        foreach my $r (@results) {
            push @response, $self->follow_result($r);
        }

        wantarray and return @response;
        $self->{_cache}->{$method} = \@response;
    }
    else {
        $self->{_cache}->{$method} = $result;
    }

    return $self->{_cache}->{$method};
}


sub follow_result {
    my ($self, $result) = @_;

    if (exists $result->{'xlink:href'}) {
        my $href   = new URI($result->{'xlink:href'});

        my $action = exists $result->{action}
            ? $result->{action}
            : 'GET';

        my $full_href = $self->crust->response
            ? $href->abs($self->crust->response->base)
            : $href;

        my %args = exists $result->{args}
            ? %{$result->{args}}
            : ();

        my $r = $self->crust->request(
            $action,
            $full_href,
            %args
        );

        return $r;
    }
    else {
        return new WebService::CRUST::Result($result, $self->crust);
    }
}



1;

__END__