File Coverage

lib/Web/ComposableRequest/Role/Session.pm

Criterion	Covered	Total	%
statement	38	38	100.0
branch			n/a
condition			n/a
subroutine	12	12	100.0
pod	1	1	100.0
total	51	51	100.0

package Web::ComposableRequest::Role::Session;

use namespace::autoclean;

use Web::ComposableRequest::Constants qw( TRUE );
use Web::ComposableRequest::Util      qw( add_config_role compose_class );
use Unexpected::Types                 qw( LoadableClass Object );
use Moo::Role;

requires qw( loc loc_default query_params _config _env _log );

add_config_role __PACKAGE__.'::Config';

has 'session' =>
   is      => 'lazy',
   isa     => Object,
   builder => sub {
      my $self = shift;

      return $self->session_class->new(
         config  => $self->_config,
         request => $self,
         session => $self->_env->{'psgix.session'},
      );
   },
   clearer => TRUE,
   handles => [ 'authenticated', 'username' ];

has 'session_class' =>
   is      => 'lazy',
   isa     => LoadableClass,
   builder => sub {
      my $self = shift;
      my $conf = $self->_config;

      return compose_class(
         $conf->session_class, $conf->session_attr, is => 'rw'
      );
   };

sub reset_session {
   my $self       = shift;
   my $psgix_sess = $self->_env->{ 'psgix.session' };

   delete $psgix_sess->{ $_ } for (keys %{ $psgix_sess });

   $self->clear_session;
   return;
}

package Web::ComposableRequest::Role::Session::Config;

use namespace::autoclean;

use Web::ComposableRequest::Constants qw( FALSE TRUE );
use Unexpected::Types qw( ArrayRef Bool CodeRef HashRef NonEmptySimpleStr
                          NonZeroPositiveInt PositiveInt );
use Moo::Role;

has 'delete_on_collect' => is => 'ro', isa => Bool, default => TRUE;

has 'expire_session' => is => 'lazy', isa => CodeRef,
   default => sub { sub { [ 'User [_1] session expired', $_[ 0 ]->username ] }};

has 'max_messages' => is => 'ro', isa => NonZeroPositiveInt,
   default => 3;

has 'max_sess_time' => is => 'ro', isa => PositiveInt,
   default => 3_600;

has 'serialise_session_attr' => is => 'ro', isa => ArrayRef[NonEmptySimpleStr],
   default => sub { [] };

has 'session_attr' => is => 'ro', isa => HashRef[ArrayRef],
   default => sub { {} };

has 'session_class' => is => 'ro', isa => NonEmptySimpleStr,
   default => 'Web::ComposableRequest::Session';

1;

__END__