File Coverage

blib/lib/Wasm/Wasmtime/Instance/Exports.pm

Criterion	Covered	Total	%
statement	47	49	95.9
branch	3	4	75.0
condition	2	3	66.6
subroutine	11	14	78.5
pod	0	2	0.0
total	63	72	87.5

package Wasm::Wasmtime::Instance::Exports;

use strict;
use warnings;
use 5.008004;
use Carp ();
use Hash::Util ();
use overload
  '%{}' => sub {
    my $self   = shift;
    my $instance = $$self;
    $instance->{exports};
  },
  '@{}' => sub {
    my $self = shift;
    my $instance = $$self;
    my @exports = $instance->_exports;
    Internals::SvREADONLY @exports, 1;
    Internals::SvREADONLY $exports[$_], 1 for 0..$#exports;
    \@exports;
  },
  bool => sub { 1 },
  fallback => 1;

# ABSTRACT: Wasmtime instance exports class
our $VERSION = '0.22'; # VERSION


sub new
{
  my($class, $instance) = @_;

  $instance->{exports} ||= do {
    my @exports = $instance->_exports;
    my @module_exports   = @{ $instance->module->exports };
    my %exports;
    foreach my $i (0..$#exports)
    {
      $exports{$module_exports[$i]->name} = $exports[$i];
    }
    Hash::Util::lock_hash(%exports);
    \%exports;
  };

  bless \$instance, $class;
}

sub can
{
  my($self, $name) = @_;
  my $instance = $$self;
  exists $instance->{exports}->{$name}
    ? sub { $self->$name }
    : $self->SUPER::can($name);
}

sub AUTOLOAD
{
  our $AUTOLOAD;
  my $self = shift;

  my $name = $AUTOLOAD;
  $name=~ s/^.*:://;

  my $instance = $$self;
  Carp::croak("no export $name") unless exists $instance->{exports}->{$name};
  $instance->{exports}->{$name};
}

sub DESTROY
{
  # needed because of AUTOLOAD
}


1;

__END__