File Coverage

blib/lib/Wasm/Wasmtime/Global.pm

Criterion	Covered	Total	%
statement	34	34	100.0
branch			n/a
condition			n/a
subroutine	12	12	100.0
pod	1	1	100.0
total	47	47	100.0

package Wasm::Wasmtime::Global;

use strict;
use warnings;
use 5.008004;
use base qw( Wasm::Wasmtime::Extern );
use Ref::Util qw( is_ref );
use Wasm::Wasmtime::FFI;
use Wasm::Wasmtime::Store;
use Wasm::Wasmtime::GlobalType;
use constant is_global => 1;
use constant kind => 'global';

# ABSTRACT: Wasmtime global class
our $VERSION = '0.22'; # VERSION


$ffi_prefix = 'wasm_global_';
$ffi->load_custom_type('::PtrObject' => 'wasm_global_t' => __PACKAGE__);


$ffi->attach( new => ['wasm_store_t', 'wasm_globaltype_t', 'wasm_val_t'] => 'wasm_global_t' => sub {
  my $xsub = shift;
  my $class = shift;
  if(is_ref $_[0])
  {
    my($store, $globaltype, $value) = @_;
    $value = Wasm::Wasmtime::Val->new({
      kind => $globaltype->content->kind_num,
      of => { $globaltype->content->kind => $value },
    });
    my $self = $xsub->($store, $globaltype, $value);
    $self->{store} = $store;
    return $self;
  }
  else
  {
    my($ptr, $owner) = @_;
    bless {
      ptr   => $ptr,
      owner => $owner,
    }, $class;
  }
});


$ffi->attach( type => ['wasm_global_t'] => 'wasm_globaltype_t' => sub {
  my($xsub, $self) = @_;
  my $type = $xsub->($self);
  $type->{owner} = $self->{owner} || $self;
  $type;
});


$ffi->attach( get => ['wasm_global_t', 'wasm_val_t'] => sub {
  my($xsub, $self) = @_;
  my $value = Wasm::Wasmtime::Val->new;
  $xsub->($self, $value);
  $value->to_perl;
});


$ffi->attach( set => ['wasm_global_t','wasm_val_t'] => sub {
  my($xsub, $self, $value) = @_;
    $value = Wasm::Wasmtime::Val->new({
      kind => $self->type->content->kind_num,
      of => { $self->type->content->kind => $value },
    });
  $xsub->($self, $value);
});


sub tie
{
  my $self = shift;
  my $ref;
  tie $ref, __PACKAGE__, $self;
  \$ref;
}

sub TIESCALAR { $_[1] }
*FETCH = \&get;
*STORE = \&set;

__PACKAGE__->_cast(1);
_generate_destroy();

1;

__END__