File Coverage

blib/lib/WWW/Speakerdeck/Download.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	14	14	100.0
condition	3	3	100.0
subroutine	6	6	100.0
pod	1	1	100.0
total	61	61	100.0

package WWW::Speakerdeck::Download;
$WWW::Speakerdeck::Download::VERSION = '0.01';
# ABSTRACT: Download a deck from speakerdeck.com

use Mojo::Base -base, -signatures;

use Carp;
use Mojo::UserAgent;
use Mojo::File qw(path);
use Scalar::Util qw(blessed);

has ua => sub {
    Mojo::UserAgent->new
};

has base_url => 'https://speakerdeck.com';

sub download ($self, $user, $name, $to = '' ) {

    croak 'need plain path to target or Mojo::File object' if !blessed( $to ) && ref $to;

    my $url  = join '/', $self->base_url, $user, $name;
    my $tx   = $self->ua->get( $url );

    croak 'cannot get deck ' . $url . ': ' . $tx->res->message if $tx->res->is_error;

    my $icon = $tx->res->dom->find("svg.icon-download")->first;

    croak 'cannot download ' . $name . ' deck: download link not found' if !$icon;

    my $link = $icon->parent->attr('href');

    my $basename = path( $link )->basename;

    $to = path( '.', $basename ) if !$to;
    $to = path($to)              if !blessed( $to );

    croak 'need plain path to target or Mojo::File object' if !$to->isa('Mojo::File');

    my $download_tx = $self->ua->get( $link );
    my $res         = $download_tx->res;

    croak 'cannot download deck: ' . $res->message if $res->is_error;

    $to->spurt( $res->body );

    return 1;
}

1;

__END__