File Coverage

blib/lib/WWW/Search/ValentinskaCZ.pm

Criterion	Covered	Total	%
statement	59	65	90.7
branch	2	6	33.3
condition			n/a
subroutine	13	13	100.0
pod			n/a
total	74	84	88.1

package WWW::Search::ValentinskaCZ;

use base qw(WWW::Search);
use strict;
use warnings;

use Encode qw(decode_utf8);
use LWP::UserAgent;
use Perl6::Slurp qw(slurp);
use Readonly;
use URI;
use Web::Scraper;

# Constants.
Readonly::Scalar our $MAINTAINER => 'Michal Josef Spacek ';
Readonly::Scalar my $VALENTINSKA_CZ => 'http://www.valentinska.cz/';
Readonly::Scalar my $VALENTINSKA_CZ_ACTION1 => 'index.php?route=product/search&search=';

our $VERSION = 0.06;

# Setup.
sub _native_setup_search {
	my ($self, $query) = @_;

	$self->{'_def'} = scraper {

		# Get list of books.
		process '//div[@class="product-inner clearfix"]',
			'books[]' => scraper {

			process '//div[@class="wrap-infor"]/div[@class="name"]/a',
				'title' => 'TEXT';
			process '//div[@class="wrap-infor"]/div[@class="name"]/a',
				'url' => ['@href', sub {
					my $url = shift;
					my $uri = URI->new($url);
					my %query = $uri->query_form;
					if (exists $query{'search'}) {
						delete $query{'search'};
					}
					$uri->query_form(\%query);
					return $uri->as_string;
				}];
			process '//div[@class="image"]/a/img',
				'image' => '@src';
			process '//div[@class="wrap-infor"]/div[@class="author"]',
				'author' => 'TEXT';
			process '//div[@class="wrap-infor"]/div[@class="price"]/br/preceding-sibling::text()',
				'price' => ['TEXT', sub { s/^\s*(.*?)\s*$/$1/; }];
			return;
		};
		return;
	};
	$self->{'_query'} = $query;

	return 1;
}

# Get data.
sub _native_retrieve_some {
	my $self = shift;

	if (defined $self->{search_from_file}) {
		my $content = slurp($self->{search_from_file});
		$self->_process_content($content);
	} else {
		# Query.
		my $query = decode_utf8($self->{'_query'});

		# Get content.
		my $ua = LWP::UserAgent->new(
			'agent' => "WWW::Search::ValentinskaCZ/$VERSION",
		);
		my $query_url = $VALENTINSKA_CZ.$VALENTINSKA_CZ_ACTION1.$query;
		my $response = $ua->get($query_url);

		# Process.
		if ($response->is_success) {
			$self->_process_content($response->content);
		}
	}

	return;
}

sub _process_content {
	my ($self, $content) = @_;

	# Get books structure.
	my $books_hr = $self->{'_def'}->scrape($content);

	# Process each book.
	foreach my $book_hr (@{$books_hr->{'books'}}) {
		push @{$self->{'cache'}}, $book_hr;
	}

	return;
}

1;

__END__