File Coverage

blib/lib/WWW/Search/Torrentz.pm

Criterion	Covered	Total	%
statement	28	63	44.4
branch	0	12	0.0
condition	2	7	28.5
subroutine	8	12	66.6
pod	1	3	33.3
total	39	97	40.2

package WWW::Search::Torrentz;

use 5.014000;
use strict;
use warnings;
no if $] >= 5.018, warnings => 'experimental::smartmatch';
use parent qw/WWW::Search/;
use re '/s';

our $VERSION = '0.001003';
our $MAINTAINER = 'Marius Gavrilescu ';

use WWW::Search::Torrentz::Result;

sub debug { say STDERR @_ } ## no critic (RequireCheckedSyscalls)

sub gui_query{ shift->native_query(@_) }

sub _native_setup_search{ ## no critic (ProhibitUnusedPrivateSubroutines)
	my ($self, $native_query, $options) = @_;
	$self->agent_email('[e-mail]');
	$options //= {};
	my $base_url = $options->{search_url} // 'https://torrentz.eu/search';
	$self->{search_debug} = $options->{search_debug};
	$self->{_next_url} = "$base_url?f=$native_query";
	$self->user_agent->delay(2/60);
}

sub fullint ($) { int (shift =~ y/0-9//cdr) } ## no critic (ProhibitSubroutinePrototypes)

sub _parse_tree{ ## no critic (ProhibitUnusedPrivateSubroutines)
	my ($self, $tree) = @_;
	my $found = 0;

	my @potential_results = $tree->find('dl');
	my $result_count = $tree->find('h2')->as_text;
	if (defined $result_count && $result_count ne 'No Torrents Found') {
		$result_count =~ s/orrents.*//;
		$self->approximate_result_count(fullint $result_count);
	}

	for my $node (@potential_results) {
		my $a = $node->find('a');
		next unless defined $a;

		my $infohash = substr $a->attr('href'), 1;
		next unless $infohash =~ /^[a-f0-9]{40}$/;
		my $title = $a->as_text;
		my ($verified, $age, $size, $seeders, $leechers);
		$verified = 0;
		for my $span ($node->find('span')) {
			given($span->attr('class')){
				$verified = int ($span->as_text =~ /^\d+/) when 'v';
				$age = $span->as_text when 'a';
				$size = $span->as_text when 's';
				$seeders = fullint $span->as_text when 'u';
				$leechers = fullint $span->as_text when 'd';
			}
		}

		push @{$self->{cache}}, WWW::Search::Torrentz::Result->new(infohash => $infohash, title => $title, verified => $verified, age => $age, size => $size, seeders => $seeders, leechers => $leechers, ua => $self->user_agent);
		debug "infohash => $infohash, title => $title, verified => $verified, age => $age, size => $size, seeders => $seeders, leechers => $leechers" if $self->{search_debug};
		$found++;
	}

	my $url = $tree->look_down(rel => 'next');
	if (defined $url) {
		my $prev = $self->{_prev_url} =~ s{/[^/]+$}{}r;
		$self->{_next_url} = $prev . $url->attr('href')
	}
	debug "Found: $found" if $self->{search_debug};
	return $found;
}

1;
__END__