File Coverage

blib/lib/WWW/Search/KacurCZ.pm

Criterion	Covered	Total	%
statement	65	71	91.5
branch	2	6	33.3
condition			n/a
subroutine	14	14	100.0
pod			n/a
total	81	91	89.0

package WWW::Search::KacurCZ;

use base qw(WWW::Search);
use strict;
use warnings;

use Encode qw(decode_utf8);
use LWP::UserAgent;
use Perl6::Slurp qw(slurp);
use Readonly;
use Text::Iconv;
use Web::Scraper;

# Constants.
Readonly::Scalar our $MAINTAINER => 'Michal Josef Spacek ';
Readonly::Scalar my $KACUR_CZ => 'http://kacur.cz/';
Readonly::Scalar my $KACUR_CZ_ACTION1 => '/search.asp?doIt=search&menu=675&'.
	'kategorie=&nazev=&rok=&dosearch=Vyhledat';

our $VERSION = 0.02;

# Setup.
sub _native_setup_search {
	my ($self, $query) = @_;

	$self->{'_def'} = scraper {
		process '//div[@class="productItemX"]', 'books[]' => scraper {
			process '//div/h3/a', 'title' => 'TEXT';
			process '//div/h3/a', 'url' => '@href';
			process '//img', 'cover_url' => '@src';
			process '//p', 'author_publisher[]' => 'TEXT';
			process '//span[@class="price"]', 'price' => 'TEXT';
			return;
		};
		return;
	};
	$self->{'_query'} = $query;

	return 1;
}

# Get data.
sub _native_retrieve_some {
	my $self = shift;

	if (defined $self->{search_from_file}) {
		my $content = slurp($self->{search_from_file});
		$self->_process_content($content);
	} else {
		# Query.
		my $i1 = Text::Iconv->new('utf-8', 'windows-1250');
		my $query = $i1->convert(decode_utf8($self->{'_query'}));

		# Get content.
		my $ua = LWP::UserAgent->new(
			'agent' => "WWW::Search::KacurCZ/$VERSION",
		);
		my $response = $ua->get($KACUR_CZ.$KACUR_CZ_ACTION1."&autor=$query");

		# Process.
		if ($response->is_success) {
			$self->_process_content($response->content);
		}
	}

	return;
}

# Fix URL to absolute path.
sub _fix_url {
	my ($book_hr, $url) = @_;

	if (exists $book_hr->{$url}) {
		$book_hr->{$url} = $KACUR_CZ.$book_hr->{$url};
	}

	return;
}

sub _process_content {
	my ($self, $content) = @_;

	my $i2 = Text::Iconv->new('windows-1250', 'utf-8');
	my $utf8_content = $i2->convert($content);

	# Get books structure.
	my $books_hr = $self->{'_def'}->scrape($utf8_content);

	# Process each book.
	foreach my $book_hr (@{$books_hr->{'books'}}) {
		_fix_url($book_hr, 'url');
		_fix_url($book_hr, 'cover_url');
		$book_hr->{'author'}
			= $book_hr->{'author_publisher'}->[0];
		$book_hr->{'author'} =~ s/\N{U+00A0}$//ms;
		$book_hr->{'publisher'}
			= $book_hr->{'author_publisher'}->[1];
		$book_hr->{'publisher'} =~ s/\N{U+00A0}$//ms;
		delete $book_hr->{'author_publisher'};
		($book_hr->{'old_price'}, $book_hr->{'price'})
			= split m/\s*\*\s*/ms, $book_hr->{'price'};
		push @{$self->{'cache'}}, $book_hr;
	}

	return;
}

1;

__END__