File Coverage

blib/lib/WWW/Scraper/ISBN/Driver.pm

Criterion	Covered	Total	%
statement	77	77	100.0
branch	34	34	100.0
condition	16	19	84.2
subroutine	14	14	100.0
pod	10	10	100.0
total	151	154	98.0

package WWW::Scraper::ISBN::Driver;

use strict;
use warnings;

our $VERSION = '1.04';

#----------------------------------------------------------------------------
# Library Modules

use Carp;

#----------------------------------------------------------------------------
# Public API

# Preloaded methods go here.
sub new {
	my $proto = shift;
	my $class = ref($proto) || $proto;

    my $self = {
	    FOUND       => 0,
	    VERBOSITY   => 0,
	    BOOK        => undef,
	    ERROR       => ''
    };

    bless ($self, $class);
	return $self;
}

sub found       { my $self = shift; return $self->_accessor('FOUND',@_)     }
sub verbosity   { my $self = shift; return $self->_accessor('VERBOSITY',@_) }
sub book        { my $self = shift; return $self->_accessor('BOOK',@_)      }
sub error       { my $self = shift; return $self->_accessor('ERROR',@_)     }

sub _accessor {
	my $self     = shift;
	my $accessor = shift;
	if (@_) { $self->{$accessor} = shift };
	return $self->{$accessor};
}

sub search {
	croak(q{Child class must overload 'search()' method.});
}

#----------------------------------------------------------------------------
# Internal Class methods

# a generic method for storing the error & setting not found
sub handler {
	my $self = shift;
	if (@_) {
		$self->{ERROR} = shift;
		print "Error: $self->{ERROR}\n"	if $self->verbosity;
	};
	return $self->found(0);
}

sub convert_to_ean13 {
	my $self = shift;
    my $isbn = shift || return;
    my $prefix;

    return  unless(length $isbn == 10 || length $isbn == 13);

    if(length $isbn == 13) {
        return  if($isbn !~ /^(978|979)(\d{10})$/);
        ($prefix,$isbn) = ($1,$2);
    } else {
        return  if($isbn !~ /^(\d{10}|\d{9}X)$/);
        $prefix = '978';
    }

    my $isbn13 = $prefix . $isbn;
    chop($isbn13);
    my @isbn = split(//,$isbn13);
    my ($lsum,$hsum) = (0,0);
    while(@isbn) {
        $hsum += shift @isbn;
        $lsum += shift @isbn;
    }

    my $csum = ($lsum * 3) + $hsum;
    $csum %= 10;
    $csum = 10 - $csum  if($csum != 0);

    return $isbn13 . $csum;
}

sub convert_to_isbn10 {
	my $self = shift;
    my $ean  = shift || return;
    my ($isbn,$isbn10);

    return  unless(length $ean == 10 || length $ean == 13);

    if(length $ean == 13) {
        return  if($ean !~ /^(?:978|979)(\d{9})\d$/);
        ($isbn,$isbn10) = ($1,$1);
    } else {
        return  if($ean !~ /^(\d{9})[\dX]$/);
        ($isbn,$isbn10) = ($1,$1);
    }

	my ($csum, $pos, $digit) = (0, 0, 0);
    for ($pos = 9; $pos > 0; $pos--) {
        $digit = $isbn % 10;
        $isbn /= 10;             # Decimal shift ISBN for next time
        $csum += ($pos * $digit);
    }
    $csum %= 11;
    $csum = 'X'   if ($csum == 10);
    return $isbn10 . $csum;
}

sub is_valid {
	my $self = shift;
    my $isbn = shift or return 0;

    # validate and convert into EAN13 format
    my $ean = $self->convert_to_ean13($isbn);

    return 0 if(!$ean);
    return 0 if(length $isbn == 13 && $isbn ne $ean);
    return 0 if(length $isbn == 10 && $isbn ne $self->convert_to_isbn10($ean));

    return 1;
}

1;

__END__