File Coverage

blib/lib/WWW/PayPal/API/Subscriptions.pm

Criterion	Covered	Total	%
statement	13	56	23.2
branch	0	38	0.0
condition	0	8	0.0
subroutine	5	14	35.7
pod	7	7	100.0
total	25	123	20.3

package WWW::PayPal::API::Subscriptions;

# ABSTRACT: PayPal Billing Subscriptions API (v1)

use Moo;
use Carp qw(croak);
use WWW::PayPal::Subscription;
use namespace::clean;

our $VERSION = '0.002';


has client => (
    is       => 'ro',
    required => 1,
    weak_ref => 1,
);

has openapi_operations => (
    is      => 'lazy',
    builder => sub {
        return {
            'billing.subscriptions.create'       => { method => 'POST',  path => '/v1/billing/subscriptions' },
            'billing.subscriptions.get'          => { method => 'GET',   path => '/v1/billing/subscriptions/{id}' },
            'billing.subscriptions.patch'        => { method => 'PATCH', path => '/v1/billing/subscriptions/{id}' },
            'billing.subscriptions.revise'       => { method => 'POST',  path => '/v1/billing/subscriptions/{id}/revise' },
            'billing.subscriptions.suspend'      => { method => 'POST',  path => '/v1/billing/subscriptions/{id}/suspend' },
            'billing.subscriptions.activate'     => { method => 'POST',  path => '/v1/billing/subscriptions/{id}/activate' },
            'billing.subscriptions.cancel'       => { method => 'POST',  path => '/v1/billing/subscriptions/{id}/cancel' },
            'billing.subscriptions.capture'      => { method => 'POST',  path => '/v1/billing/subscriptions/{id}/capture' },
            'billing.subscriptions.transactions' => { method => 'GET',   path => '/v1/billing/subscriptions/{id}/transactions' },
        };
    },
);

with 'WWW::PayPal::Role::OpenAPI';

sub _wrap {
    my ($self, $data) = @_;
    return WWW::PayPal::Subscription->new(client => $self->client, data => $data);
}

sub create {
    my ($self, %args) = @_;
    croak 'plan_id required' unless $args{plan_id};

    my %body = ( plan_id => $args{plan_id} );
    $body{subscriber}    = $args{subscriber}    if $args{subscriber};
    $body{quantity}      = $args{quantity}      if defined $args{quantity};
    $body{custom_id}     = $args{custom_id}     if defined $args{custom_id};
    $body{start_time}    = $args{start_time}    if defined $args{start_time};
    $body{shipping_amount} = $args{shipping_amount} if $args{shipping_amount};

    my %ctx;
    $ctx{return_url}  = $args{return_url}  if $args{return_url};
    $ctx{cancel_url}  = $args{cancel_url}  if $args{cancel_url};
    $ctx{brand_name}  = $args{brand_name}  if $args{brand_name};
    $ctx{locale}      = $args{locale}      if $args{locale};
    $ctx{user_action} = $args{user_action} // 'SUBSCRIBE_NOW';
    $ctx{shipping_preference} = $args{shipping_preference}
        if $args{shipping_preference};
    $body{application_context} = \%ctx if %ctx;

    my $data = $self->call_operation('billing.subscriptions.create', body => \%body);
    return $self->_wrap($data);
}


sub get {
    my ($self, $id) = @_;
    croak 'subscription id required' unless $id;
    return $self->_wrap($self->call_operation('billing.subscriptions.get', path => { id => $id }));
}


sub _action_with_reason {
    my ($self, $op, $id, %args) = @_;
    croak 'subscription id required' unless $id;
    my $reason = $args{reason} // 'not specified';
    return $self->call_operation($op,
        path => { id => $id },
        body => { reason => $reason },
    );
}

sub suspend  { my $s = shift; $s->_action_with_reason('billing.subscriptions.suspend',  @_) }
sub activate { my $s = shift; $s->_action_with_reason('billing.subscriptions.activate', @_) }
sub cancel   { my $s = shift; $s->_action_with_reason('billing.subscriptions.cancel',   @_) }


sub capture {
    my ($self, $id, %args) = @_;
    croak 'subscription id required' unless $id;
    croak 'amount required'          unless $args{amount};
    my $body = {
        note        => $args{note} // 'Outstanding balance',
        capture_type => $args{capture_type} // 'OUTSTANDING_BALANCE',
        amount      => $args{amount},
    };
    return $self->call_operation('billing.subscriptions.capture',
        path => { id => $id },
        body => $body,
    );
}


sub transactions {
    my ($self, $id, %args) = @_;
    croak 'subscription id required' unless $id;
    croak 'start_time required'      unless $args{start_time};
    croak 'end_time required'        unless $args{end_time};
    return $self->call_operation('billing.subscriptions.transactions',
        path  => { id => $id },
        query => {
            start_time => $args{start_time},
            end_time   => $args{end_time},
        },
    );
}


1;

__END__