File Coverage

blib/lib/WWW/PayPal/Order.pm

Criterion	Covered	Total	%
statement	45	57	78.9
branch	10	18	55.5
condition	8	16	50.0
subroutine	15	19	78.9
pod	14	14	100.0
total	92	124	74.1

package WWW::PayPal::Order;

# ABSTRACT: PayPal Orders v2 order entity

use Moo;
use Carp qw(croak);
use namespace::clean;

our $VERSION = '0.001';


has _client => (
    is       => 'ro',
    required => 1,
    weak_ref => 1,
    init_arg => 'client',
);

has data => (
    is       => 'rw',
    required => 1,
);


sub id     { $_[0]->data->{id} }
sub status { $_[0]->data->{status} }
sub intent { $_[0]->data->{intent} }


sub _links {
    my ($self) = @_;
    return $self->data->{links} || [];
}

sub link_for {
    my ($self, $rel) = @_;
    for my $l (@{ $self->_links }) {
        return $l->{href} if $l->{rel} && $l->{rel} eq $rel;
    }
    return;
}


sub approve_url {
    my ($self) = @_;
    # Modern flows return 'payer-action'; legacy returned 'approve'.
    return $self->link_for('payer-action') // $self->link_for('approve');
}


sub _capture_node {
    my ($self) = @_;
    my $pu = $self->data->{purchase_units} || [];
    return unless @$pu;
    my $captures = $pu->[0]{payments}{captures} || [];
    return $captures->[0];
}

sub capture_id {
    my ($self) = @_;
    my $c = $self->_capture_node or return;
    return $c->{id};
}


sub fee_in_cent {
    my ($self) = @_;
    my $c = $self->_capture_node or return;
    my $fee = $c->{seller_receivable_breakdown}{paypal_fee}{value} or return;
    # PayPal returns decimal strings like "1.23"
    return int($fee * 100 + 0.5);
}


sub total {
    my ($self) = @_;
    my $pu = $self->data->{purchase_units} || [];
    return unless @$pu;
    return $pu->[0]{amount}{value};
}

sub currency {
    my ($self) = @_;
    my $pu = $self->data->{purchase_units} || [];
    return unless @$pu;
    return $pu->[0]{amount}{currency_code};
}


sub payer_email {
    my ($self) = @_;
    return $self->data->{payer}{email_address};
}

sub payer_name {
    my ($self) = @_;
    my $n = $self->data->{payer}{name} or return;
    return join(' ', grep { defined && length } $n->{given_name}, $n->{surname});
}

sub payer_id {
    my ($self) = @_;
    return $self->data->{payer}{payer_id};
}


sub refresh {
    my ($self) = @_;
    my $fresh = $self->_client->orders->get($self->id);
    $self->data($fresh->data);
    return $self;
}


sub capture {
    my ($self) = @_;
    my $captured = $self->_client->orders->capture($self->id);
    $self->data($captured->data);
    return $self;
}


1;

__END__