File Coverage

blib/lib/WWW/Ohloh/API/Account.pm

Criterion	Covered	Total	%
statement	77	84	91.6
branch	4	10	40.0
condition	4	12	33.3
subroutine	21	22	95.4
pod	3	9	33.3
total	109	137	79.5

package WWW::Ohloh::API::Account;
our $AUTHORITY = 'cpan:YANICK';

use strict;
use warnings;

use Carp;
use Object::InsideOut qw/
  WWW::Ohloh::API::Role::Fetchable
  WWW::Ohloh::API::Role::LoadXML /;
use XML::LibXML;
use WWW::Ohloh::API::KudoScore;
use Time::Piece;
use Date::Parse;

use Params::Validate qw/ validate validate_with /;

use Digest::MD5 qw/ md5_hex /;

our $VERSION = '1.0_1';

use overload '""' => sub { $_[0]->name };

#<<<
my @id_of               : Field
                        : Set(_set_id)
                        : Get(id)
                        ;
my @name_of             : Field
                        : Set(_set_name)
                        : Get(name)
                        ;
my @creation_date_of    : Field
                        : Set(_set_created_at)
                        : Get(created_at)
                        : Type(Time::Piece)
                        ;
my @update_date_of      : Field
                        : Set(_set_updated_at)
                        : Get(updated_at)
                        : Type(Time::Piece)
                        ;
my @homepage_url_of     : Field
                        : Set(_set_homepage_url)
                        : Get(homepage_url)
                        ;
my @avatar_url_of       : Field
                        : Set(_set_avatar_url)
                        : Get(avatar_url)
                        ;
my @posts_count_of      : Field
                        : Set(_set_posts_count)
                        : Get(posts_count)
                        ;
my @location_of         : Field
                        : Set(_set_location)
                        : Get(location)
                        ;
my @latitude_of         : Field
                        : Set(_set_latitude)
                        : Get(latitude)
                        ;
my @longitude_of        : Field
                        : Set(_set_longitude)
                        : Get(longitude)
                        ;
my @country_code_of     : Field
                        : Set(_set_country_code)
                        : Get(country_code)
                        ;
my @kudo_of             : Field
                        : Set(_set_kudo)
                        : Get(kudo_score)
                        ;
#>>>
my @kudos_of : Field : Arg(kudos);

my @stack : Field;

sub element_name { return 'account' }

sub generate_query_url : Chained(bottom up) {
    my ( $self, @args ) = @_;

    my %param = validate_with(
        params      => \@args,
        spec        => { id => 1 },
        allow_extra => 1
    );
    my $id = $param{id};
    delete $param{id};

    if ( index( $id, '@' ) > -1 ) {
        $id = md5_hex($id);
    }

    return ( "accounts/$id.xml", ohloh => $param{ohloh} );
}

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub load_xml {
    my ( $self, $dom ) = @_;

    $self->_set_id( $dom->findvalue('id/text()') );
    $self->_set_name( $dom->findvalue('name/text()') );
    $self->_set_created_at(
        scalar Time::Piece::gmtime(
            str2time( $dom->findvalue('created_at/text()') ) ) );
    $self->_set_updated_at(
        scalar Time::Piece::gmtime(
            str2time( $dom->findvalue('updated_at/text()') ) ) );
    $self->_set_homepage_url( $dom->findvalue('homepage_url/text()') );
    $self->_set_avatar_url( $dom->findvalue('avatar_url/text()') );
    $self->_set_posts_count( $dom->findvalue('posts_count/text()') );
    $self->_set_location( $dom->findvalue('location/text()') );
    $self->_set_country_code( $dom->findvalue('country_code/text()') );
    $self->_set_latitude( $dom->findvalue('latitude/text()') );
    $self->_set_longitude( $dom->findvalue('longitude/text()') );

    if ( my ($node) = $dom->findnodes('kudo_score[1]') ) {
        $kudo_of[$$self] = WWW::Ohloh::API::KudoScore->new( xml => $node );
    }
}

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub as_xml {
    my $self = shift;
    my $xml;
    my $w = XML::Writer->new( OUTPUT => \$xml );

    $w->startTag('account');

    $w->dataElement( $_ => $self->$_ ) for qw/
      id name created_at updated_at homepage_url
      avatar_url posts_count
      location
      country_code
      latitude
      longitude
      /;

    $xml .= $self->kudo->as_xml if $self->kudo;

    $w->endTag;

    return $xml;
}

sub kudoScore {
    my $self = shift;
    return $kudo_of[$$self];
}

# aliases
*kudo = *kudoScore;

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub stack {
    my $self = shift;

    my $retrieve = shift;
    $retrieve = 1 unless defined $retrieve;

    if ( $retrieve and not $stack[$$self] ) {
        $stack[$$self] = $self->ohloh->fetch_account_stack( $self->id );
        $stack[$$self]->set_account($self);
    }

    return $stack[$$self];
}

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub sent_kudos {
    my $self = shift;

    $kudos_of[$$self] ||= $self->ohloh->get_kudos( id => $self->id );

    return $kudos_of[$$self]->sent;
}

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub received_kudos {
    my $self = shift;

    $kudos_of[$$self] ||= $self->ohloh->get_kudos( id => $self->id );

    return $kudos_of[$$self]->received;
}

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub kudos {
    my $self = shift;

    return $kudos_of[$$self] ||= $self->ohloh->fetch_kudos( $self->id );
}

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

'end of WWW::Ohloh::API::Account';

__END__