File Coverage

lib/WWW/Mixpanel.pm

Criterion	Covered	Total	%
statement	16	106	15.0
branch	0	56	0.0
condition	0	12	0.0
subroutine	6	16	37.5
pod	6	7	85.7
total	28	197	14.2

package WWW::Mixpanel;

use strict;
use warnings;
use LWP::UserAgent;
use MIME::Base64;
use JSON;

BEGIN {
  $WWW::Mixpanel::VERSION = '0.07';
}

sub new {
  my ( $class, $token, $use_ssl, $api_key, $api_secret ) = @_;
  die "You must provide your API token." unless $token;

  my $ua = LWP::UserAgent->new;
  $ua->timeout(180);
  $ua->env_proxy;

  my $json = JSON->new->allow_blessed(1)->convert_blessed(1);

  bless { token                           => $token,
          use_ssl                         => $use_ssl,
          api_key                         => $api_key,
          api_secret                      => $api_secret,
          data_api_default_expire_seconds => 180,
          track_api                       => 'api.mixpanel.com/track/', # trailing slash required
          data_api                        => 'mixpanel.com/api/2.0/',
          people_api                      => 'api.mixpanel.com/engage/',
          json                            => $json,
          ua                              => $ua, }, $class;
}

sub people_set{
  my ( $self, $distinct_id, %params ) = @_;

  die "Distinct User Id required" unless $distinct_id;

  my $data = { '$set'  => \%params,
               '$distinct_id' => $distinct_id,
               '$ip' => 0,
               '$token' => $self->{token}
  };

  my $res =
    $self->{ua}->post( $self->{use_ssl}
      ? "https://$self->{people_api}"
      : "http://$self->{people_api}",
      { 'data' => encode_base64( $self->{json}->encode($data), '' ) } );

  if ( $res->is_success ) {
    if ( $res->content == 1 ) {
      return 1;
    }
    else {
      die "Failure from api: " . $res->content;
    }
  }
  else {
    die "Failed sending event: " . $self->_res($res);
  }
}

sub people_increment{
  my ( $self, $distinct_id, %params ) = @_;

  die "Distinct User Id required" unless $distinct_id;

  my $data = { '$add'  => \%params,
               '$distinct_id' => $distinct_id,
               '$ip' => 0,
               '$token' => $self->{token}
             };

  my $res =
    $self->{ua}->post( $self->{use_ssl}
                        ? "https://$self->{people_api}"
                        : "http://$self->{people_api}",
                        { 'data' => encode_base64( $self->{json}->encode($data), '' ) } );

  if ( $res->is_success ) {
    if ( $res->content == 1 ) {
      return 1;
    }
    else {
      die "Failure from api: " . $res->content;
    }
  }
  else {
    die "Failed sending event: " . $self->_res($res);
  }
}

sub people_append_transactions{
  my ( $self, $distinct_id, %params ) = @_;

  die "Distinct User Id required" unless $distinct_id;

  my $data = { '$append'  => {'$transactions' => \%params},
               '$distinct_id' => $distinct_id,
               '$ip' => 0,
               '$token' => $self->{token}
             };

  my $res =
    $self->{ua}->post( $self->{use_ssl}
                       ? "https://$self->{people_api}"
                       : "http://$self->{people_api}",
                       { 'data' => encode_base64( $self->{json}->encode($data), '' ) } );


}

sub people_track_charge{
  my ( $self, $distinct_id, $amount ) = @_;

  die "Distinct User Id required" unless $distinct_id;

  return $self->people_append_transactions( $distinct_id, '$time' => time(), '$amount' => $amount);
}


sub track {
  my ( $self, $event, %params ) = @_;

  die "You must provide an event name" unless $event;

  $params{time} ||= time();
  $params{token} = $self->{token};

  my $data = { event      => $event,
               properties => \%params, };

  my $res =
    $self->{ua}->post( $self->{use_ssl}
                       ? "https://$self->{track_api}"
                       : "http://$self->{track_api}",
                       { 'data' => encode_base64( $self->{json}->encode($data), '' ) } );

  if ( $res->is_success ) {
    if ( $res->content == 1 ) {
      return 1;
    }
    else {
      die "Failure from api: " . $res->content;
    }
  }
  else {
    die "Failed sending event: " . $self->_res($res);
  }
} # end track

sub data {
  my $self    = shift;
  my $methods = shift;
  my %params  = @_;

  $methods = [$methods] if !ref($methods);
  my $api_methods = join( '/', @$methods );

  $self->_data_params_to_json( $api_methods, \%params );

  $params{format} ||= 'json';
  $params{expire} = time() + $self->{data_api_default_expire_seconds}
    if !defined( $params{expire} );
  $params{api_key} = $self->{api_key} || die 'API Key must be specified for data requests';
  my $api_secret = $self->{api_secret} || die 'API Secret must be specified for data requests';

  my $sig = $self->_create_sig( $api_secret, \%params );
  $params{sig} = $sig;

  my $url =
    $self->{use_ssl}
    ? "https://$self->{data_api}"
    : "http://$self->{data_api}";
  $url .= $api_methods;

  # We have to hand-build the url because HTTP::REQUEST/HEADER was
  # changing underscores and capitalization, and Mixpanel is sensitive
  # about such things.
  my $ps = join( '&', map {"$_=$params{$_}"} sort keys %params );
  my $res = $self->{ua}->get( $url . '/?' . $ps );

  if ( $res->is_success ) {
    my $reso = $res->content;
    $reso = $self->{json}->decode($reso) if $params{format} eq 'json';
    return $reso;
  }
  else {
    die "Failed sending event: " . $self->_res($res);
  }
} # end data

# Calculate data request signature according to spec.
sub _create_sig {
  my $self       = shift;
  my $api_secret = shift;
  my $params     = shift;

  require Digest::MD5;
  my $pstr = join( '', map { $_ . '=' . $params->{$_} } sort keys %$params ) . $api_secret;
  return Digest::MD5::md5_hex($pstr);
}

sub _data_params_to_json {
  my $self   = shift;
  my $api    = shift;
  my $params = shift;

  # A few API calls require json encoded arrays, so transform those here.
  my $toj;
  if ( $api eq 'events' ) {
    $toj = 'event';
  }
  if ( $api eq 'events/properties' ) {
    $toj = 'values';
  }
  if ( $api eq 'arb_funnels' ) {
    $toj = 'events';
  }

  if ( $toj && defined( $params->{$toj} ) ) {
    $params->{$toj} = [ $params->{$toj} ] if !ref( $params->{$toj} );
    $params->{$toj} = $self->{json}->encode( $params->{$toj} );
  }

} # end _data_params_to_json

sub _res {
  my ( $self, $res ) = @_;

  if ( $res->code == 500 ) {
    return "Mixpanel service error. The service might be down.";
  }
  elsif ( $res->code == 400 ) {
    return "Bad Request Elements: " . $res->content;
  }
  else {
    return "Unknown error. " . $res->message;
  }
}

1;

__END__