File Coverage

blib/lib/WWW/Live/Auth/ConsentToken.pm

Criterion	Covered	Total	%
statement	12	68	17.6
branch	0	16	0.0
condition	0	24	0.0
subroutine	4	14	28.5
pod	0	9	0.0
total	16	131	12.2

package WWW::Live::Auth::ConsentToken;

use strict;
use warnings;

use WWW::Live::Auth::Utils;
use Carp;

require WWW::Live::Auth::SecretKey;
require WWW::Live::Auth::Offer;
require Math::BigInt;

sub new {
  my ( $proto, %args ) = @_;
  my $class = ref $proto || $proto;

  my $self = bless {
    'string' => $args{'consent_token'},
  }, $class;

  $self->_process( $args{'secret_key'} );

  return $self;
}

sub as_string {
  my $self = shift;
  return $self->{'string'};
}

sub delegation_token {
  my $self = shift;
  return $self->{'delegation_token'};
}

sub refresh_token {
  my $self = shift;
  return $self->{'refresh_token'};
}

sub session_key {
  my $self = shift;
  return $self->{'session_key'};
}

sub location_id {
  my $self = shift;
  return $self->{'location_id'};
}

sub int_location_id {
  my $self = shift;
  my $num = Math::BigInt->new('0x'.$self->{'location_id'});
  my ($base2)  = $num->as_bin() =~ /^0b(\d+)/;
  warn "BASE2: $base2";

  if ( length($base2) == 64 && substr($base2, 0, 1) eq '1' ) {
    $base2 =~ tr/01/10/;
    my @chars = split //, $base2;
    for (my $i=63; $i>0; $i--) {
      $chars[$i] =~ tr/01/10/;
      if ($chars[$i] eq '1') {
        last;
      }
    }
    $base2 = join '', @chars;
    return '-' . Math::BigInt->new("0b$base2")->bstr;
  } else {
    return $num->bstr;
  }
}

sub offers {
  my $self = shift;
  return wantarray ? @{ $self->{'offers'} || [] } : $self->{'offers'};
}

sub expires {
  my $self = shift;
  return $self->{'expires'};
}

sub _process {
  my ( $self, $secret_key ) = @_;

  $secret_key || croak('Secret key is required');
  my $consent_token = $self->{'string'} || croak('Consent token is required');

  if ( !ref $secret_key ) {
    $secret_key = WWW::Live::Auth::SecretKey->new( $secret_key );
  }

  $consent_token = _unescape( $consent_token );
  $consent_token = _split( $consent_token );

  if ( $consent_token->{'eact'} ) {
    $consent_token = _unescape( $consent_token->{'eact'} );
    $consent_token = _decode  ( $consent_token );
    $consent_token = _decrypt ( $consent_token, $secret_key->encryption_key );
    $consent_token = _validate( $consent_token, $secret_key->signature_key  );
    $consent_token = _split   ( $consent_token );
  }

  my @offers = map {
    WWW::Live::Auth::Offer->new( 'offer' => $_ )
  } split /;/, $consent_token->{'offer'};

  scalar @offers || croak('Consent token contains no offers');

  $self->{'delegation_token'} = $consent_token->{'delt'}  || croak('Consent token contains no delegation token');
  $self->{'refresh_token'}    = $consent_token->{'reft'}  || croak('Consent token contains no refresh token');
  $self->{'session_key'}      = $consent_token->{'skey'}  || croak('Consent token contains no session key');
  $self->{'expires'}          = $consent_token->{'exp'}   || croak('Consent token contains no expiry time');
  $self->{'location_id'}      = $consent_token->{'lid'}   || croak('Consent token contains no location ID');
  $self->{'offers'}           = \@offers;
}

1;
__END__