File Coverage

blib/lib/WWW/Hetzner/Cloud/API/Datacenters.pm

Criterion	Covered	Total	%
statement	30	30	100.0
branch	4	6	66.6
condition	1	2	50.0
subroutine	9	9	100.0
pod	3	3	100.0
total	47	50	94.0

package WWW::Hetzner::Cloud::API::Datacenters;
# ABSTRACT: Hetzner Cloud Datacenters API

our $VERSION = '0.100';

use Moo;
use Carp qw(croak);
use WWW::Hetzner::Cloud::Datacenter;
use namespace::clean;


has client => (
    is       => 'ro',
    required => 1,
    weak_ref => 1,
);

sub _wrap {
    my ($self, $data) = @_;
    return WWW::Hetzner::Cloud::Datacenter->new(
        client => $self->client,
        %$data,
    );
}

sub _wrap_list {
    my ($self, $list) = @_;
    return [ map { $self->_wrap($_) } @$list ];
}


sub list {
    my ($self, %params) = @_;

    my $result = $self->client->get('/datacenters', params => \%params);
    return $self->_wrap_list($result->{datacenters} // []);
}


sub get {
    my ($self, $id) = @_;
    croak "Datacenter ID required" unless $id;

    my $result = $self->client->get("/datacenters/$id");
    return $self->_wrap($result->{datacenter});
}


sub get_by_name {
    my ($self, $name) = @_;
    croak "Name required" unless $name;

    my $datacenters = $self->list;
    for my $dc (@$datacenters) {
        return $dc if $dc->name eq $name;
    }
    return;
}


1;

__END__