File Coverage

blib/lib/VAPID.pm

Criterion	Covered	Total	%
statement	158	191	82.7
branch	38	60	63.3
condition	10	22	45.4
subroutine	25	26	96.1
pod	11	11	100.0
total	242	310	78.0

package VAPID;
use 5.006; use strict; use warnings; our $VERSION = '1.05';
use Crypt::JWT qw(encode_jwt); use Crypt::PK::ECC; use URI; use MIME::Base64 qw/encode_base64url decode_base64url/;
use Crypt::AuthEnc::GCM qw(gcm_encrypt_authenticate); use Crypt::KeyDerivation qw(hkdf); use Crypt::PRNG qw(random_bytes);
use HTTP::Request; use LWP::UserAgent; use JSON qw(decode_json);
use base 'Import::Export';

our (%EX, $DEFAULT_SECONDS, $MAX_DEFAULT_SECONDS);

BEGIN {
	$DEFAULT_SECONDS = 12 * 60 * 60; # 12 hours
	$MAX_DEFAULT_SECONDS = 24 * 60 * 60; # 24 hours
	%EX = (
		generate_vapid_keys => [qw/all generate/],
		generate_future_expiration_timestamp => [qw/all generate/],
		generate_vapid_header => [qw/all generate/],
		validate_subject => [qw/all validate/],
		validate_public_key => [qw/all validate/],
		validate_private_key => [qw/all validate/],
		validate_expiration_key => [qw/all validate/],
		validate_expiration => [qw/all validate/],
		validate_subscription => [qw/all validate/],
		encrypt_payload => [qw/all encrypt/],
		build_push_request => [qw/all push/],
		send_push_notification => [qw/all push/],
	);
}

sub generate_vapid_keys {
	my $curve = Crypt::PK::ECC->new();
	$curve->generate_key('prime256v1');
	my $priv = $curve->export_key_raw('private');
	my $pub = $curve->export_key_raw('public');

	if (length($priv) < 32) {
		my $padding = 32 - length $priv;
		$priv = (0 x $padding) . $priv;
	}

	if (length($pub) < 65) {
		my $padding = 65 - length $pub;
		$pub = (0 x $padding) . $pub;
	}

	return (
		encode_base64url($pub),
		encode_base64url($priv)
	);
}

sub generate_vapid_header {
	my ($aud, $subject, $pub, $priv, $expiration, $enc) = @_;

	if (!$aud) {
		die "No audience could be generated for VAPID.";
	}

	if (ref $aud) {
		die "The audience value must be a string containing the origin of a push service";
	}

	my $aud_uri = URI->new($aud);

	if (!$aud_uri->host) {
		die "VAPID audience is not a url.";
	}

	validate_subject($subject);
	validate_public_key($pub);
	$priv = validate_private_key($priv);

	if ($expiration) {
		validate_expiration($expiration);
	} else {
		$expiration = generate_future_expiration_timestamp();
	}

	my $payload = {
		aud => $aud,
    		exp => $expiration,
   		sub => $subject
	};

	my $key = Crypt::PK::ECC->new
		->import_key_raw($priv, 'prime256v1')
		->export_key_pem('private');


	my $jwt_token = encode_jwt(
		payload=>$payload,
		extra_headers => { typ => 'JWT' },
		alg=>'ES256',
		key => \$key
	);

	return $enc
		? {
			Authorization => "vapit t=${jwt_token}, k=${pub}"
		}
		: {
			Authorization => 'WebPush ' . $jwt_token,
      			'Crypto-Key' => 'p256ecdsa=' . $pub
		};
}

sub generate_future_expiration_timestamp {
	my ($add) = shift;
	return time + ($add || $DEFAULT_SECONDS);
}

sub validate_subject {
	my ($subject) = shift;

	if (!$subject) {
		die "No subject passed to validate_subject";
	}

	if (ref $subject) {
		die "The subject value must be a string containing a URL or 'mailto: address.'";
	}

	unless ($subject =~ m/^mailto\:/) {
		my $uri = URI->new($subject);
		if (!$uri->host) {
			die "VAPID subject is not a url or mailto: address";
		}
	}

	return $subject;
}

sub validate_public_key {
	my ($pub) = shift;

	if (!$pub) {
		die "No public key passed to validate_public_key";
	}

	if (ref $pub) {
		die "Vapid public key is must be a URL safe Base 64 encoded string";
	}

	$pub = decode_base64url($pub);

	if (length $pub != 65) {
		die "VAPID public key should be 65 bytes long when decoded.";
	}

	return $pub;
}

sub validate_private_key {
	my ($priv) = shift;

	if (!$priv) {
		die "No private key passed to validate_private_key";
	}

	if (ref $priv) {
		die "VAPID private key is must be a URL safe Base 64 encoded string";
	}

	$priv = decode_base64url($priv);

	if (length $priv != 32) {
		die "VAPID private key should be 32 bytes long when decoded.";
	}

	return $priv;
}

sub validate_expiration {
	my $expiration = shift;

	if (!$expiration || $expiration !~ m/^\d+$/) {
		die "expiration value must be a number";
	}

	my $max = generate_future_expiration_timestamp($MAX_DEFAULT_SECONDS);

	if ($expiration >= $max) {
    		die "expiration value is greater than maximum of 24 hours";
  	}

	return $expiration;
}

sub validate_subscription {
	my ($subscription) = @_;

	if (!$subscription) {
		die "No subscription passed to validate_subscription";
	}

	if (!ref $subscription || ref $subscription ne 'HASH') {
		die "Subscription must be a hash reference";
	}

	if (!$subscription->{endpoint}) {
		die "Subscription must have an endpoint";
	}

	my $uri = URI->new($subscription->{endpoint});
	if (!$uri->host) {
		die "Subscription endpoint is not a valid URL";
	}

	if (!$subscription->{keys}) {
		die "Subscription must have keys";
	}

	if (!$subscription->{keys}{p256dh}) {
		die "Subscription must have a p256dh key";
	}

	if (!$subscription->{keys}{auth}) {
		die "Subscription must have an auth key";
	}

	return $subscription;
}

sub encrypt_payload {
	my ($payload, $subscription) = @_;

	if (!defined $payload) {
		die "No payload passed to encrypt_payload";
	}

	validate_subscription($subscription);

	my $user_public_key = decode_base64url($subscription->{keys}{p256dh});
	my $user_auth = decode_base64url($subscription->{keys}{auth});

	my $salt = random_bytes(16);

	my $local_key = Crypt::PK::ECC->new();
	$local_key->generate_key('prime256v1');
	my $local_public_key = $local_key->export_key_raw('public');

	my $user_key = Crypt::PK::ECC->new();
	$user_key->import_key_raw($user_public_key, 'prime256v1');
	my $shared_secret = $local_key->shared_secret($user_key);

	my $auth_info = "Content-Encoding: auth\x00";
	my $prk = hkdf($shared_secret, $user_auth, 'SHA256', 32, $auth_info);

	my $context = "P-256\x00"
		. pack('n', length($user_public_key)) . $user_public_key
		. pack('n', length($local_public_key)) . $local_public_key;

	my $cek_info = "Content-Encoding: aesgcm\x00" . $context;
	my $content_encryption_key = hkdf($prk, $salt, 'SHA256', 16, $cek_info);

	my $nonce_info = "Content-Encoding: nonce\x00" . $context;
	my $nonce = hkdf($prk, $salt, 'SHA256', 12, $nonce_info);

	my $padded_payload = pack('n', 0) . $payload;

	my ($ciphertext, $tag) = gcm_encrypt_authenticate(
		'AES',
		$content_encryption_key,
		$nonce,
		'',
		$padded_payload
	);

	return {
		ciphertext => $ciphertext . $tag,
		salt => $salt,
		local_public_key => $local_public_key
	};
}

sub build_push_request {
	my (%args) = @_;

	my $subscription = $args{subscription};
	my $payload = $args{payload};
	my $vapid_public = $args{vapid_public};
	my $vapid_private = $args{vapid_private};
	my $subject = $args{subject};
	my $ttl = $args{ttl} // 60;
	my $expiration = $args{expiration};
	my $enc = $args{enc};

	validate_subscription($subscription);

	my $endpoint = $subscription->{endpoint};
	my $uri = URI->new($endpoint);
	my $audience = $uri->scheme . '://' . $uri->host;

	my $vapid_headers = generate_vapid_header(
		$audience,
		$subject,
		$vapid_public,
		$vapid_private,
		$expiration,
		$enc
	);

	my $req = HTTP::Request->new(POST => $endpoint);
	$req->header(TTL => $ttl);
	$req->header(Authorization => $vapid_headers->{Authorization});

	if ($vapid_headers->{'Crypto-Key'}) {
		my $crypto_key = $vapid_headers->{'Crypto-Key'};

		if (defined $payload && length $payload) {
			my $encrypted = encrypt_payload($payload, $subscription);

			$crypto_key .= ';dh=' . encode_base64url($encrypted->{local_public_key});
			$req->header(Encryption => 'salt=' . encode_base64url($encrypted->{salt}));
			$req->header('Content-Encoding' => 'aesgcm');
			$req->header('Content-Type' => 'application/octet-stream');
			$req->content($encrypted->{ciphertext});
		}

		$req->header('Crypto-Key' => $crypto_key);
	} else {
		if (defined $payload && length $payload) {
			my $encrypted = encrypt_payload($payload, $subscription);

			$req->header('Crypto-Key' => 'dh=' . encode_base64url($encrypted->{local_public_key}));
			$req->header(Encryption => 'salt=' . encode_base64url($encrypted->{salt}));
			$req->header('Content-Encoding' => 'aesgcm');
			$req->header('Content-Type' => 'application/octet-stream');
			$req->content($encrypted->{ciphertext});
		}
	}

	$req->header('Content-Length' => length($req->content // ''));

	return $req;
}

sub send_push_notification {
	my (%args) = @_;

	my $ua = $args{ua} // LWP::UserAgent->new(timeout => 30);

	my $req = build_push_request(%args);
	my $resp = $ua->request($req);

	return {
		success => $resp->is_success,
		status => $resp->code,
		message => $resp->message,
		response => $resp
	};
}

1;

__END__