File Coverage

blib/lib/UserAgent/Any/JSON.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	6	6	100.0
condition			n/a
subroutine	9	9	100.0
pod			n/a
total	52	52	100.0

package UserAgent::Any::JSON;

use 5.036;

use Carp;
use Moo;
use UserAgent::Any::JSON::Response;
use UserAgent::Any::Wrapper 'wrap_get_like_methods', 'wrap_post_like_methods';

use namespace::clean;

our $VERSION = 0.05;

extends 'UserAgent::Any';

has _converter => (
  init_arg => 'json',
  is => 'ro',
  default => sub { require JSON; JSON->new },
);

# This is not specific to GET and can actually handle any verb that does not
# take a request body.
sub _generate_get_request ($self, $url, @headers) {
  croak 'Invalid number of arguments, expected an even sized list after the url' if @headers % 2;
  return _generate_post_request($self, $url, @headers);
}

# The only difference with the 'get' version is that this handles the request
# body.
sub _generate_post_request ($self, $url, @args) {
  my $body;
  $body = pop @args if @args % 2;
  return (
    $url,
    'Accept' => 'application/json',
    'Content-Type' => 'application/json',
    @args,
    defined $body ? ($self->_converter->encode($body)) : ());
}

sub _process_response ($self, $res, @) {
  return UserAgent::Any::JSON::Response->new(res => $res, converter => $self->_converter);
}

wrap_get_like_methods('UserAgent::Any', \&_generate_get_request, \&_process_response);
wrap_post_like_methods('UserAgent::Any', \&_generate_post_request, \&_process_response);

1;

__END__