File Coverage

lib/Unexpected/TraitFor/ErrorLeader.pm

Criterion	Covered	Total	%
statement	31	31	100.0
branch	4	4	100.0
condition	5	6	100.0
subroutine	7	7	100.0
pod	2	2	100.0
total	49	50	100.0

package Unexpected::TraitFor::ErrorLeader;

use namespace::autoclean;

use List::Util        qw( first );
use Unexpected::Types qw( NonZeroPositiveInt SimpleStr );
use Moo::Role;

requires qw( as_string clone frames );

my $Ignore = [ 'Try::Tiny' ];

# Private functions
my $_is_member = sub {
   my $wanted = shift; return (first { $_ eq $wanted } @{ $_[ 0 ] }) ? 1 : 0;
};

my $_build_leader = sub {
   my $self = shift; my $level = $self->level; my $leader = q();

   my @frames = $self->frames; my ($line, $package);

   $level >= scalar @frames and $level = scalar @frames - 1;

   do {
      # uncoverable condition right
      if ($frames[ $level ] and $package = $frames[ $level ]->package) {
         $line    = $frames[ $level ]->line;
         $leader  = $package; $leader =~ s{ :: }{-}gmx;
         $leader .= "[${line}/${level}]: "; $level++;
      }
      else { $leader = $package = q() }
   }
   while ($package and $_is_member->( $package, $self->ignore ));

   return $leader;
};

# Object attributes (public)
has 'leader' => is => 'lazy', isa => SimpleStr, builder => $_build_leader;

has 'level'  => is => 'ro',   isa => NonZeroPositiveInt, default => 1;

# Construction
around 'as_string' => sub {
   my ($orig, $self, @args) = @_; my $str = $orig->( $self, @args );

   return $str ? $self->leader.$str : $str;
};

before 'clone' => sub {
   my $self = shift; $self->leader; return;
};

# Public methods
sub ignore {
   return $Ignore;
}

sub ignore_class {
   shift; return push @{ $Ignore }, @_;
}

1;

__END__