File Coverage

blib/lib/Types/MIDI.pm

Criterion	Covered	Total	%
statement	20	20	100.0
branch			n/a
condition			n/a
subroutine	7	7	100.0
pod			n/a
total	27	27	100.0

## no critic (TestingAndDebugging::RequireUseStrict)
## no critic (TestingAndDebugging::RequireUseWarnings)
package Types::MIDI;
our $AUTHORITY = 'cpan:MJGARDNER';
## use critic (TestingAndDebugging::RequireUseStrict)
## use critic (TestingAndDebugging::RequireUseWarnings)

use 5.016;
use strict;
use warnings;

# ABSTRACT: Type library for MIDI

#<<<
our $VERSION = 'v0.601.0';
#>>>

use Type::Library 2.000000 -extends => [ qw(
    Types::Common::Numeric
    Types::Common::String
) ],
    -declare => qw(
    Channel
    Velocity
    Note
    PercussionNote
    );
use Type::Utils 2.000000 -all;
use MIDI;
use Readonly;

#pod =head1 SYNOPSIS
#pod
#pod     use Moo;
#pod     use Types::MIDI -all;
#pod
#pod     has volume => (
#pod         is      => 'ro',
#pod         isa     => Velocity,
#pod         default => 100,
#pod     );
#pod     has a440 => (
#pod         is      => 'ro',
#pod         isa     => Note,
#pod         default => 69,
#pod     );
#pod     has electric_snare => (
#pod         is      => 'ro',
#pod         isa     => PercussionNote,
#pod         coerce  => 1,
#pod         default => 'Electric Snare',
#pod     );
#pod
#pod =head1 DESCRIPTION
#pod
#pod This is a type constraint library intended to be useful for those
#pod developing music software using the MIDI (Musical Instrument Digital
#pod Interface) specification.
#pod
#pod It is a work in progress driven by real-world usage, and as such
#pod B. Once it reaches
#pod version 1.0, though, the author does not intend to introduce any
#pod breaking changes without a corresponding increase in the major version
#pod number.
#pod
#pod =head1 OVERVIEW
#pod
#pod Because this leverages L, it should be usable in a
#pod variety of Perl object systems, including L and L. By
#pod default, it exports nothing into the consumer's namespace; however, in
#pod addition to specifying individual functions in the L
#pod statement, you can also provide or combine the following tags to export
#pod groups of functions:
#pod
#pod =over
#pod
#pod =item C
#pod
#pod Exports all types by name into the namespace.
#pod
#pod =item C
#pod
#pod Exports all CI functions into the namespace.
#pod
#pod =item C
#pod
#pod Exports all CI functions into the namespace.
#pod
#pod =item C
#pod
#pod Exports all CI functions into the namespace.
#pod
#pod =item CIC<);>
#pod
#pod Exports I and all related functions into the namespace.
#pod
#pod =item C
#pod
#pod Exports everything.
#pod
#pod =back
#pod
#pod This library also inherits from L; consult
#pod L for ways to customize how functions
#pod are imported, such as renaming or omitting certain names.
#pod
#pod Also note that the tags listed above may be preceded with a C<->
#pod (hyphen) instead of a C<:> (colon); Perl's auto-quoting of barewords
#pod thus enables you to import a tag group of functions like so:
#pod
#pod     use Types::MIDI -all;
#pod
#pod =cut

## no critic (ValuesAndExpressions::ProhibitMagicNumbers)

#pod =type Channel
#pod
#pod An L 0 to 15 corresponding
#pod to a MIDI Channel.
#pod
#pod =func is_Channel
#pod
#pod Returns true if the passed value can be used as a L.
#pod
#pod =func assert_Channel
#pod
#pod Returns the passed value if and only if it can be used as a L;
#pod otherwise it throws an exception.
#pod
#pod =cut

declare Channel, as IntRange [ 0, 15 ];

#pod =type Velocity
#pod
#pod An L 0 to 127 corresponding
#pod to a MIDI velocity.
#pod
#pod =func is_Velocity
#pod
#pod Returns true if the passed value can be used as a L.
#pod
#pod =func assert_Velocity
#pod
#pod Returns the passed value if and only if it can be used as a
#pod L; otherwise it throws an exception.
#pod
#pod =cut

declare Velocity, as IntRange [ 0, 127 ];

#pod =type Note
#pod
#pod An L 0 to 127 corresponding
#pod to a MIDI note number.
#pod
#pod =func is_Note
#pod
#pod Returns true if the passed value can be used as a L.
#pod
#pod =func assert_Note
#pod
#pod Returns the passed value if and only if it can be used as a L;
#pod otherwise it throws an exception.
#pod
#pod =cut

declare Note, as IntRange [ 0, 127 ];

#pod =type PercussionNote
#pod
#pod A L from 27 through 87, corresponding to a L number in the
#pod General MIDI 2 Percussion Sound Set.
#pod
#pod This type can also coerce case-insensitive
#pod Ls of instrument names in the
#pod General MIDI 2 Percussion Sound Set, returning the corresponding
#pod L.
#pod
#pod =func is_PercussionNote
#pod
#pod Returns true if the passed value can be used as a L.
#pod
#pod =func assert_PercussionNote
#pod
#pod Returns the passed value if and only if it can be used as a
#pod L; otherwise it throws an exception.
#pod
#pod =func to_PercussionNote
#pod
#pod Coerces the passed value to a L.
#pod
#pod =cut

my %notenum2percussion = %MIDI::notenum2percussion;    ## no critic (Variables::ProhibitPackageVars)
@notenum2percussion{ 27 .. 34, 82 .. 87 } = (
    'High Q',
    'Slap',
    'Scratch Push',
    'Scratch Pull',
    'Sticks',
    'Square Click',
    'Metronome Click',
    'Metronome Bell',

    'Shaker',
    'Jingle Bell',
    'Bell Tree',
    'Castanets',
    'Mute Surdo',
    'Open Surdo',
);
Readonly my %NOTENUM2PERCUSSION_FC =>
    map { fc $notenum2percussion{$_} => $_ } keys %notenum2percussion;

declare PercussionNote, as Note,
    where { exists $notenum2percussion{$_} };
coerce PercussionNote, from NonEmptySimpleStr,
    via { $NOTENUM2PERCUSSION_FC{"\F$_"} };

#pod =head1 SEE ALSO
#pod
#pod =over
#pod
#pod =item *
#pod
#pod I,
#pod revised February 1996 by the MIDI Manufacturers Association:
#pod L
#pod
#pod =item *
#pod
#pod B in
#pod I,
#pod published February 6, 2007 by the MIDI Manufacturers Association:
#pod L
#pod
#pod =back
#pod
#pod =cut

1;

__END__