File Coverage

blib/lib/Types/JSONSchema/PrimativeTypes.pm

Criterion	Covered	Total	%
statement	20	20	100.0
branch			n/a
condition			n/a
subroutine	7	7	100.0
pod			n/a
total	27	27	100.0

use 5.036;
use strict;
use warnings;
use experimental 'builtin';

package Types::JSONSchema::PrimativeTypes;

our $AUTHORITY = 'cpan:TOBYINK';
our $VERSION   = '0.001000';

use Type::Library
	-base,
	-declare => qw/
		JNull
		JBoolean
		JObject
		JArray
		JNumber
		JString

		JTrue
		JFalse
		JInteger
		JAny

		JSPrimativeName
		JSPrimativeType
	/;
use Types::Common -all;
use Type::Utils;

declare JNull,
	as Undef;

declare JBoolean,
	as InstanceOf[ 'boolean', 'JSON::PP::Boolean', 'JSON::XS::Boolean' ]
	| ScalarRef[ Enum[ 0, 1 ] ]
	| Value->create_child_type(
		name       => 'PerlNativeBoolean',
		constraint => sub { builtin::is_bool($_) },
		inlined    => sub { my $var = pop; qq{do{ use experimental 'builtin'; builtin::is_bool($var) }} },
	);

declare JTrue,
	as JBoolean,
	where { ( 'SCALAR' eq ( ref $_ or '' ) ) ? $$_ : $_ },
	inline_as {
		my $var = $_;
		my $parent = $_[0]->parent->inline_check( $var );
		qq{$parent and ( 'SCALAR' eq ( ref $var or '' ) ) ? \${$var} : $var}
	};

declare JFalse,
	as JBoolean,
	where { ( 'SCALAR' eq ( ref $_ or '' ) ) ? !$$_ : !$_ },
	inline_as {
		my $var = $_;
		my $parent = $_[0]->parent->inline_check( $var );
		qq{$parent and ( 'SCALAR' eq ( ref $var or '' ) ) ? !\${$var} : !$var}
	};

declare JObject,
	as HashRef;

declare JArray,
	as ArrayRef;

declare JNumber,
	as Num,
	where { builtin::created_as_number( $_ ) },
	inline_as { ( Value->inline_check($_), qq{do{ use experimental 'builtin'; builtin::created_as_number( $_ ) }} ) };

declare JInteger,
	as JNumber,
	where { int($_) == $_ },
	inline_as { ( undef, qq{int($_) == $_} ) };

declare JString,
	as Str,
	where { builtin::created_as_string( $_ ) },
	inline_as { ( Value->inline_check($_), qq{do{ use experimental 'builtin'; builtin::created_as_string( $_ ) }} ) };

declare JAny,
	as JNull | JBoolean | JObject | JArray | JNumber | JString;

my %primative_name_to_type = (
	null     => JNull,
	boolean  => JBoolean,
	object   => JObject,
	array    => JArray,
	number   => JNumber,
	string   => JString,
);

declare JSPrimativeName,
	as Enum[ sort keys %primative_name_to_type ];

declare JSPrimativeType,
	as InstanceOf->of('Type::Tiny')->with_attribute_values(
		library => Enum[ 'Types::JSONSchema::PrimativeTypes' ],
		name    => Enum[ sort map $_->name, values %primative_name_to_type ],
	);

coerce JSPrimativeType,
	from JSPrimativeName, via { $primative_name_to_type{$_} },
	from Enum['integer'], via { JInteger };

1;

__END__