AppWindow/Ext/MDI.pm untested

filter: Statementstmt 0.0% 0 / 610 Branchbran 0.0% 0 / 268 Conditioncond 0.0% 0 / 15 MC/DCmcdc 0.0% 0 / 10 Subroutinesub 0.0% 0 / 82 Podpod 0.0% 0 / 69 totaltotal 0.0% 0 / 1054 CC 134 SCAR 32.8
CC
134
Cov
0%
CmdDocOpen
90.0
CmdDocSave
90.0
CmdDocClose
72.0
CRAP 26.5
1 package Tk::AppWindow::Ext::MDI;
2  
3 =head1 NAME
4  
5 Tk::AppWindow::Ext::MDI - multiple document interface
6  
7 =cut
8  
9 use strict;
10 use warnings;
11 use Carp;
12  
13 use vars qw($VERSION);
14 $VERSION="0.17";
15  
16 use base qw( Tk::AppWindow::BaseClasses::Extension );
17  
18 use File::Basename;
19 use File::Spec;
20 use File::stat;
21 use Time::localtime;
22 require Tk::LabFrame;
23 require Tk::YAMessage;
24 require Tk::YANoteBook;
25  
26 use Config;
27 my $mswin = 0;
28 $mswin = 1 if $Config{'osname'} eq 'MSWin32';
29  
30 =head1 SYNOPSIS
31  
32 my $app = new Tk::AppWindow(@options,
33 -extensions => ['MDI'],
34 );
35 $app->MainLoop;
36  
37 =head1 DESCRIPTION
38  
39 Provides a multi document interface to your application.
40  
41 When L<Tk::AppWindow::Ext::MenuBar> is loaded it creates menu
42 entries for creating, opening, saving and closing files. It also
43 maintains a history of recently closed files.
44  
45 When L<Tk::AppWindow::Ext::ToolBar> is loaded it creates toolbuttons
46 for creating, opening, saving and closing files.
47  
48 It features deferred loading. If you open a document it will not load the document
49 until there is a need to access it. This comes in handy when you want
50 to open multiple documents at one time.
51  
52 You should define a content handler based on the abstract
53 baseclass L<Tk::AppWindow::BaseClasses::ContentManager>. See also there.
54  
55 This extension will also load the extensions B<ConfigFolder> and B<Daemons>.
56  
57 =head1 CONFIG VARIABLES
58  
59 =over 4
60  
61 =item Switch: B<-contentmanagerclass>
62  
63 This one should always be specified and you should always define a
64 content manager class inheriting L<Tk::AppWindow::BaseClasses::ContentManager>.
65 This base class is a valid Tk widget.
66  
67 =item Switch: B<-contentmanageroptions>
68  
69 The possible options to pass on to the contentmanager.
70 These will also become options to the main application.
71  
72 =item Switch: B<-diskmonitorinterval>
73  
74 Default value 100. This means every 100 cycles of the B<Daemons> extension. Specifies the interval for
75 monitoring the disk status of documents.
76  
77 =item Switch: B<-filetypes>
78  
79 Default value is "All files|*"
80  
81 =item Switch: B<-historymenupath>
82  
83 Specifies the default location in the main menu of the history menu.
84 Default value is File::Open recent. See also L<Tk::AppWindow::Ext::MenuBar>.
85  
86 =item Switch: B<-maxhistory>
87  
88 Default value is 12.
89  
90 =item Switch: B<-maxtablength>
91  
92 Default value 16
93  
94 Maximum size of the document tab in the document bar.
95  
96 =item Switch: B<-modifiedmonitorinterval>
97  
98 Default value 25. This means every 25 cycles of the B<Daemons> extension. Specifies the interval for
99 monitoring the modified status of documents.
100  
101 =item Switch: B<-readonly>
102  
103 Default value 0. If set to 1 MDI will operate in read only mode.
104  
105 =back
106  
107 =head1 COMMANDS
108  
109 The following commands are defined.
110  
111 =over 4
112  
113 =item B<deferred_open>
114  
115 Takes a document name that is in deferred state as parameter and creates a new content handler for it.
116 Returns a boolean indicating the succesfull load of its content.
117  
118 =item B<doc_close>
119  
120 Takes a document name as parameter and closes it.
121 If no parameter is specified closes the current selected document.
122 Returns a boolean for succes or failure.
123  
124 =item B<doc_new>
125  
126 Takes a document name as parameter and creates a new document.
127 If no parameter is specified an Untitled document is created.
128 Returns a boolean for succes or failure.
129  
130 =item B<doc_open>
131  
132 Takes a filename as parameter and opens it in deferred state.
133 If no parameter is specified a file dialog is issued.
134 Returns a boolean for succes or failure.
135  
136 =item B<doc_rename>
137  
138 Takes two document names as parameters and renames the first one to
139 the second one in the interface.
140  
141 =item B<doc_save>
142  
143 Takes a document name as parameter and saves it if it is modified.
144 If no parameter is specified the current selected document is saved.
145 Returns a boolean for succes or failure.
146  
147 =item B<doc_save_as>
148  
149 Takes a document name as parameter and issues a file dialog to rename it.
150 If no parameter is specified the current selected document is initiated in the dialog.
151 Returns a boolean for succes or failure.
152  
153 =item B<doc_save_all>
154  
155 Saves all open and modified documents.
156 Returns a boolean for succes or failure.
157  
158 =item B<doc_select>
159  
160 Select an opened document.
161  
162 =item B<pop_hist_menu>
163  
164 Is called when the file menu is opened in the menubar. It populates the
165 'Open recent' menu with the current history.
166  
167 =item B<set_title>
168  
169 Takes a document name as parameter and sets the main window title accordingly.
170  
171 =back
172  
173 =cut
174  
175 sub new {
176 my $class = shift;
177 my $self = $class->SUPER::new(@_);
178  
179 $self->Require( qw[ConfigFolder Daemons] );
180  
181 $self->{CMOPTIONS} = {};
182 $self->{DEFERRED} = {};
183 $self->{DOCS} = {};
184 $self->{FORCECLOSE} = 0;
185 $self->{HISTORY} = [];
186 $self->{HISTORYDISABLED} = 0;
187 $self->{INTERFACE} = undef;
188 $self->{MONITOR} = {};
189 $self->{SELECTDISABLED} = 0;
190 $self->{SELECTED} = undef;
191 $self->{SILENTMODE} = 0;
192  
193 my $args = $self->GetArgsRef;
194 my $cmo = delete $args->{'-contentmanageroptions'};
195 $cmo = [] unless defined $cmo;
196 my @preconfig = ();
197 for (@$cmo) {
198 push @preconfig, $_ => ['PASSIVE', undef, undef, ''];
199 }
200  
201 $self->addPreConfig(@preconfig,
202 -contentmanagerclass => ['PASSIVE', undef, undef, 'Wx::Perl::FrameWorks::BaseClasses::ContentManager'],
203 -contentmanageroptions => ['PASSIVE', undef, undef, $cmo],
204 -diskmonitorinterval => ['PASSIVE', undef, undef, 100], #times 10 ms
205 -maxhistory => ['PASSIVE', undef, undef, 12],
206 -filetypes => ['PASSIVE', undef, undef, "All files|*"],
207 -historymenupath => ['PASSIVE', undef, undef, 'File::Open recent'],
208 -maxtablength => ['PASSIVE', undef, undef, 16],
209 -modifiedmonitorinterval => ['PASSIVE', undef, undef, 25], #times 10 ms
210 -readonly => ['PASSIVE', undef, undef, 0],
211 );
212 $self->cmdConfig(
213 deferred_open => ['deferredOpen', $self],
214 doc_close => ['CmdDocClose', $self],
215 doc_new => ['CmdDocNew', $self],
216 doc_open => ['CmdDocOpen', $self],
217 doc_rename => ['docRename', $self],
218 doc_save => ['CmdDocSave', $self],
219 doc_save_as => ['CmdDocSaveAs', $self],
220 $self->CommandDocSaveAll,
221 doc_select => ['docSelect', $self],
222 set_title => ['setTitle', $self],
223 pop_hist_menu => ['CmdPopulateHistoryMenu', $self],
224 pop_hist_tool => ['CmdPopulateHistoryTool', $self],
225 );
226  
227 $self->addPostConfig('DoPostConfig', $self);
228 $self->historyLoad;
229 return $self;
230 }
231  
232 =head1 METHODS
233  
234 =over 4
235  
236 =cut
237  
238 sub CanQuit {
239 my $self = shift;
240 if ($self->docConfirmSaveAll) {
241 $self->docForceClose(1);
242 return 1
243 }
244 return 0
245 }
246  
247 sub CmdDocClose {
248 my ($self, $name) = @_;
249 $name = $self->docSelected unless defined $name;
250 return 1 unless defined $name;
251 my $close = 1;
252 my $fc = $self->docForceClose;
253 if ($self->docForceClose or $self->docConfirmSave($name)) {
254 my $geosave = $self->geometry;
255 $close = $self->docClose($name);
256 $self->interfaceRemove($name) if $close;
257 $self->geometry($geosave);
258 }
259 $self->log("Closed '$name'") if $close;
260 $self->logWarning("Failed closing '$name'") unless $close;
261 $close = $name if $close;
262 return $close
263 }
264  
265  
266 sub CmdDocNew {
267 my ($self, $name) = @_;
268 $name = $self->docUntitled unless defined $name;
269 $self->deferredAssign($name);
270 $self->interfaceAdd($name);
271  
272 $self->cmdExecute('doc_select', $name);
273 return $name;
274 }
275  
276 sub CmdDocOpen {
277 my $self = shift;
278 my @files = @_;
279 unless (@files) {
280 my @op = ();
281 my $sel = $self->docSelected;
282 push @op, -initialdir => dirname($sel) if defined $sel;
283 @files = $self->docOpenDialog(@op);
284 }
285 my @o = ();
286 my $silentmode = $self->silentMode;
287 $self->silentMode(1) if @files > 1;
288 for (@files) {
289 my $file = $_;
290 $file = File::Spec->rel2abs($file);
291 next if -d $file;
292 if ($self->docExists($file)) {
293 # push @o, $file;
294 } elsif ($self->cmdExecute('doc_new', $file)) {
295 $self->historyRemove($file);
296 $self->log("Opened '$file'");
297 push @o, $file;
298 }
299 }
300 $self->silentMode($silentmode) if @files > 1;
301 $self->cmdExecute('doc_select', $o[0]) if @o;
302 return @o
303 }
304  
305 sub CmdDocSave {
306 my ($self, $name) = @_;
307 return 1 if $self->configGet('-readonly');
308 $name = $self->docSelected unless defined $name;
309 return 1 unless defined $name;
310 return 1 unless $self->docModified($name);
311
312 my $doc = $self->docGet($name);
313  
314 if (defined $doc) {
315 unless ($name =~ /^Untitled/) {
316 if ($doc->Save($name)) {
317 $self->monitorUpdate($name);
318 $self->log("Saved '$name'");
319 $self->Interface->indicator($name, 0);
320 my $nav = $self->navigator;
321 $nav->EntrySaved($name) if defined $nav;
322 return $name
323 } else {
324 $self->logWarning("Failed saving '$name'");
325 return 0
326 }
327
328 } else {
329 return $self->CmdDocSaveAs($name);
330 }
331 }
332 return 0
333 }
334  
335 sub CmdDocSaveAs {
336 my ($self, $name) = @_;
337 return 0 if $self->configGet('-readonly');
338 $name = $self->docSelected unless defined $name;
339 return 0 unless defined $name;
340  
341 my $doc = $self->docGet($name);
342 if (defined $doc) {
343 my @op = (
344 -initialdir => dirname($name),
345 -initialfile => basename($name),
346 );
347 # push @op, -popover => 'mainwindow' unless $mswin;
348 my ($file) = $self->pickFileSave(@op,);
349 if (defined $file) {
350 $file = File::Spec->rel2abs($file);
351 if ($doc->Save($file)) {
352 $self->log("Saved '$file'");
353 $self->cmdExecute('doc_rename', $name, $file);
354 return $file
355 } else {
356 $self->logWarning("Failed saving '$file'");
357 return ''
358 }
359 }
360 }
361 return ''
362 }
363  
364 sub CmdDocSaveAll {
365 my $self = shift;
366 my @list = $self->docList;
367 my $succes = 1;
368 for (@list) {
369 $succes = '' unless $self->cmdExecute('doc_save', $_)
370 }
371 return $succes
372 }
373  
374 sub CmdPopulateHistoryMenu {
375 my $self = shift;
376 my $mnu = $self->extGet('MenuBar');
377 if (defined $mnu) {
378 my $path = $self->configGet('-historymenupath');
379 my ($menu, $index) = $mnu->FindMenuEntry($path);
380 if (defined($menu)) {
381 my $submenu = $menu->entrycget($index, '-menu');
382 $submenu->delete(1, 'last');
383 my $h = $self->{HISTORY};
384 for (@$h) {
385 my $f = $_;
386 $submenu->add('command',
387 -label => $f,
388 -command => sub { $self->cmdExecute('doc_open', $f) }
389 );
390 }
391 $submenu->add('separator');
392 $submenu->add('command',
393 -label => 'Clear list',
394 -command => sub { @$h = () },
395 );
396 }
397 }
398 }
399  
400 sub CmdPopulateHistoryTool {
401 my $self = shift;
402 my $tb = $self->extGet('ToolBar');
403 my $hist = $tb->GetItem('history');
404 for ($hist->children) { $_->destroy }
405 my $lf = $hist->LabFrame(
406 -label => 'Recent files',
407 -labelside => 'acrosstop',
408 )->pack(-fill => 'both');
409 my $f = $lf->Subwidget('frame');
410 my $h = $self->{HISTORY};
411 for (@$h) {
412 my $file = $_;
413 my $l = $f->Label(
414 -anchor => 'w',
415 -borderwidth => 1,
416 -text => $file,
417 )->pack(-fill => 'x');
418 $l->bind('<Enter>', sub { $l->configure(-relief => 'raised') });
419 $l->bind('<Leave>', sub { $l->configure(-relief => 'flat') });
420 $l->bind('<Button-1>', sub { $l->configure(-relief => 'sunken') });
421 $l->bind('<ButtonRelease-1>', sub {
422 $l->configure(-relief => 'flat');
423 $self->update;
424 $tb->PopDown;
425 $self->cmdExecute('doc_open', $file);
426 });
427 }
428 $f->Frame(-borderwidth => 1, -relief => 'sunken', -height => 2)->pack(-fill => 'x', -pady => 2);
429 my $l = $f->Label(
430 -anchor => 'w',
431 -borderwidth => 1,
432 -text => 'Clear list',
433 )->pack(-fill => 'x');
434 $l->bind('<Enter>', sub { $l->configure(-relief => 'raised') });
435 $l->bind('<Leave>', sub { $l->configure(-relief => 'flat') });
436 $l->bind('<Button-1>', sub { $l->configure(-relief => 'sunken') });
437 $l->bind('<ButtonRelease-1>', sub {
438 $l->configure(-relief => 'flat');
439 $self->update;
440 $tb->PopDown;
441 @$h = ();
442 });
443 my $width = 0;
444 my $height = 0;
445 for ($f->children) {
446 my $w = $_->reqwidth;
447 my $h = $_->reqheight;
448 $width = $w if $w >$width;
449 $height = $height + $h;
450 }
451 $hist->configure(-height => $height + 32, -width => $width + 12);
452 }
453  
454 sub CommandDocSaveAll {
455 my $self = shift;
456 return doc_save_all => ['CmdDocSaveAll', $self],
457 }
458  
459 =item B<ConfirmSaveDialog>I<($name)>
460  
461 Pops a dialog with a warning that $name is unsaved.
462 Asks for your action. Does not check if $name is modified or not.
463 Returns the key you press, 'Yes', 'No', or cancel.
464 Does not do any saving or checking whether a file has been modified.
465  
466 =cut
467  
468 sub ConfirmSaveDialog {
469 my ($self, $name) = @_;
470 croak 'Name not defined' unless defined $name;
471 my $title = 'Warning, file modified';
472 my $text = "Closing " . basename($name) .
473 ".\nDocument has been modified. Save it?";
474 my $icon = 'dialog-warning';
475 return $self->popDialog($title, $text, $icon, qw/Yes No Cancel/);
476 }
477  
478 =item B<ContentSpace>I<($name)>
479  
480 Returns the page frame widget in the notebook belonging to $name.
481  
482 =cut
483  
484 sub ContentSpace {
485 my ($self, $name) = @_;
486 croak 'Name not defined' unless defined $name;
487 return $self->Interface->getPage($name);
488 }
489  
490 =item B<CreateContentHandler>I($name);
491  
492 Initiates a new content handler for $name.
493  
494 =cut
495  
496 sub CreateContentHandler {
497 my ($self, $name) = @_;
498 croak 'Name not defined' unless defined $name;
499 my $page = $self->ContentSpace($name);
500 my $cmclass = $self->configGet('-contentmanagerclass');
501 my $h = $page->$cmclass(-extension => $self)->pack(-expand => 1, -fill => 'both');
502 $self->{DOCS}->{$name} = $h;
503 return $h;
504 }
505  
506 =item B<CreateInterface>
507  
508 Creates a Tk::YANoteBook multiple document interface.
509  
510 =cut
511  
512 sub CreateInterface {
513 my $self = shift;
514 $self->{INTERFACE} = $self->WorkSpace->YANoteBook(
515 -image => $self->getArt('document-multiple', 16),
516 -indicatorimage => $self->getArt('document-save', 16),
517 -selecttabcall => ['cmdExecute', $self, 'doc_select'],
518 -closetabcall => ['cmdExecute', $self, 'doc_close'],
519 )->pack(-expand => 1, -fill => 'both');
520 }
521  
522 =item B<deferredAssign>I<($name, ?$options?)>
523  
524 This method is called when you open a document.
525 It adds document $name to the interface and stores $options
526 in the deferred hash. $options is a reference to a hash. It's keys can
527 be any option accepted by your content manager.
528  
529 =cut
530  
531 sub deferredAssign {
532 my ($self, $name, $options) = @_;
533 croak 'Name not defined' unless defined $name;
534 $options = {} unless defined $options;
535 $self->{DEFERRED}->{$name} = $options;
536 }
537  
538 =item B<deferredExists>I<($name)>
539  
540 Returns true if deferred entry $name exists.
541  
542 =cut
543  
544 sub deferredExists {
545 my ($self, $name) = @_;
546 croak 'Name not defined' unless defined $name;
547 return exists $self->{DEFERRED}->{$name}
548 }
549  
550 =item B<deferredList>
551  
552 Returns a list of deferred documents.
553  
554 =cut
555  
556 sub deferredList {
557 my $self = shift;
558 my $d = $self->{DEFERRED};
559 return keys %$d
560 }
561  
562 =item B<deferredOpen>I<($name)>
563  
564 This method is called when you access the document for the first time.
565 It creates the content manager with the deferred options and loads the file.
566  
567 =cut
568  
569 sub deferredOpen {
570 my ($self, $name) = @_;
571 croak 'Name not defined' unless defined $name;
572 my $doc = $self->CreateContentHandler($name);
573 my $flag = 1;
574 $flag = '' unless (-e $name) and ($doc->Load($name));
575 my $options = $self->deferredOptions($name);
576 $self->after(20, sub {
577 for (keys %$options) {
578 $doc->configure($_, $options->{$_})
579 }
580 $self->monitorAdd($name);
581 });
582 $self->deferredRemove($name);
583 if ($flag) {
584 $self->log("Loaded $name");
585 } else {
586 $self->logWarning("Failed loading $name");
587 }
588 $flag = $name if $flag;
589 return $flag
590 }
591  
592 =item B<deferredOptions>I<($name, ?$options?)>
593  
594 Sets and returns a reference to the hash containing the
595 options for $name.
596  
597 =cut
598  
599 sub deferredOptions {
600 my ($self, $name, $options) = @_;
601 croak 'Name not defined' unless defined $name;
602 my $def = $self->{DEFERRED};
603 $def->{$name} = $options if defined $options;
604 return $def->{$name}
605 }
606  
607 =item B<deferredRemove>I<($name)>
608  
609 Removes $name from the deferred hash.
610  
611 =cut
612  
613 sub deferredRemove {
614 my ($self, $name) = @_;
615 croak 'Name not defined' unless defined $name;
616 delete $self->{DEFERRED}->{$name}
617 }
618  
619 =item B<docClose>I<($name)>
620  
621 Removes $name from the interface and destroys the content manager.
622 Also adds $name to the history list.
623  
624 =cut
625  
626 sub docClose {
627 my ($self, $name) = @_;
628 croak 'Name not defined' unless defined $name;
629 if ($self->deferredExists($name)) {
630 $self->historyAdd($name);
631 $self->deferredRemove($name);
632 return $name
633 }
634 my $doc = $self->docGet($name);
635 if ($doc->Close) {
636 #Add to history
637 $self->historyAdd($name);
638  
639 #delete from document hash
640 delete $self->{DOCS}->{$name};
641 $self->monitorRemove($name);
642  
643 if ((defined $self->docSelected) and ($self->docSelected eq $name)) {
644 $self->docSelected(undef);
645 }
646 $doc->destroy;
647 return $name
648 }
649 return 0
650 }
651  
652 =item B<docConfirmSave>I<($name)>
653  
654 Checks if $name is modified and asks confirmation
655 for save. Saves the document if you press 'Yes'.
656 Returns 1 unless you cancel the dialog, then it returns 0.
657
658 =cut
659  
660 sub docConfirmSave {
661 my ($self, $name) = @_;
662 croak 'Name not defined' unless defined $name;
663 if ($self->docModified($name)) {
664 #confirm save dialog comes here
665 my $answer = $self->ConfirmSaveDialog($name);
666 if ($answer eq 'Yes') {
667 return 0 unless $self->cmdExecute('doc_save', $name);
668 } elsif ($answer eq 'No') {
669 return 1
670 } else {
671 return 0
672 }
673 } else {
674 return 1
675 }
676 }
677  
678 =item B<docConfirmSaveAll>
679  
680 Calls docConfirmSave for all loaded documents.
681 returns 0 if a 'Cancel' is detected.
682  
683 =cut
684  
685 sub docConfirmSaveAll {
686 my $self = shift;
687 my $close = 1;
688 my @docs = $self->docList;
689 for (@docs) {
690 my $name = $_;
691 $close = $self->docConfirmSave($name);
692 last if $close eq 0;
693 }
694 return $close;
695 }
696  
697 =item B<docExists>I<($name)>
698  
699 Returns true if $name exists in either loaded or deferred state.
700  
701 =cut
702  
703 sub docExists {
704 my ($self, $name) = @_;
705 croak 'Name not defined' unless defined $name;
706 return 1 if exists $self->{DOCS}->{$name};
707 return 1 if $self->deferredExists($name);
708 return 0
709 }
710  
711 =item B<docForceClose>I<(?$flag?)>
712  
713 If $flag is set ConfirmSave dialogs will be skipped,
714 documents will be closed ruthlessly. Use with care
715 and always reset it back to 0 when you're done.
716  
717 =cut
718  
719 sub docForceClose {
720 my $self = shift;
721 $self->{FORCECLOSE} = shift if @_;
722 return $self->{FORCECLOSE}
723 }
724  
725  
726 =item B<docFullList>
727  
728 Returns a list of all documents, loaded and deferred.
729  
730 =cut
731  
732 sub docFullList {
733 my $self = shift;
734 return $self->docList, $self->deferredList;
735 }
736  
737 =item B<docGet>I<($name)>
738  
739 Returns the content manager object for $name.
740  
741 =cut
742  
743 sub docGet {
744 my ($self, $name) = @_;
745 croak 'Name not defined' unless defined $name;
746 $self->cmdExecute('deferred_open', $name) if $self->deferredExists($name);
747 return $self->{DOCS}->{$name}
748 }
749  
750 =item B<docList>
751  
752 Returns a list of all loaded documents.
753  
754 =cut
755  
756 sub docList {
757 my $self = shift;
758 my $dochash = $self->{DOCS};
759 return keys %$dochash;
760 }
761  
762 =item B<docListDisplayed>
763  
764 Returns a list of documents currently visible in the tabs bar.
765  
766 =cut
767  
768 sub docListDisplayed {
769 my $self = shift;
770 my $interface = $self->extGet('CoditMDI')->Interface;
771 my $disp = $interface->{DISPLAYED};
772 return @$disp
773 }
774  
775 =item B<docListUnDisplayed>
776  
777 Returns a list of documents currently not visible in the tabs bar.
778  
779 =cut
780  
781 sub docListUnDisplayed {
782 my $self = shift;
783 my $interface = $self->extGet('CoditMDI')->Interface;
784 my $undisp = $interface->{UNDISPLAYED};
785 return @$undisp
786 }
787  
788 =item B<docModified>I<($name)>
789  
790 Returns true if $name is modified.
791  
792 =cut
793  
794 sub docModified {
795 my ($self, $name) = @_;
796 croak 'Name not defined' unless defined $name;
797 return 0 if $self->deferredExists($name);
798 return $self->docGet($name)->IsModified;
799 }
800  
801 sub docOpenDialog {
802 my $self = shift;
803 return $self->pickFileOpenMulti(@_);
804 }
805  
806 =item B<docRename>I<($old, $new)>
807  
808 Renames a loaded document.
809  
810 =cut
811  
812 sub docRename {
813 my ($self, $old, $new) = @_;
814 croak 'Old not defined' unless defined $old;
815 croak 'New not defined' unless defined $new;
816  
817 unless ($old eq $new) {
818 my $doc = delete $self->{DOCS}->{$old};
819 $self->{DOCS}->{$new} = $doc;
820  
821 $self->interfaceRename($old, $new);
822 $self->monitorRemove($old);
823 $self->monitorAdd($new);
824  
825 if ($self->docSelected eq $old) {
826 $self->cmdExecute('doc_select', $new)
827 }
828 }
829 }
830  
831 =item B<docSelect>I<($name)>
832  
833 Selects $name.
834  
835 =cut
836  
837 sub docSelect {
838 my ($self, $name) = @_;
839 croak 'Name not defined' unless defined $name;
840 return if $self->selectDisabled;
841 $self->cmdExecute('deferred_open', $name) if $self->deferredExists($name);
842 $self->docSelected($name);
843 $self->interfaceSelect($name);
844 $self->docGet($name)->doSelect;
845 $self->cmdExecute('set_title', $name);
846 }
847  
848 =item B<docSelected>
849  
850 Returns the name of the currently selected document.
851 Returns undef if no document is selected.
852  
853 =cut
854  
855 sub docSelected {
856 my $self = shift;
857 $self->{SELECTED} = shift if @_;
858 return $self->{SELECTED}
859 }
860  
861 =item B<docTitle>I<($name)>
862  
863 Strips the path from $name for the title bar.
864  
865 =cut
866  
867 sub docTitle {
868 my ($self, $name) = @_;
869 return basename($name, '');
870 }
871  
872 =item B<docUntitled>>
873  
874 Returns 'Untitled' plus a digit '(d)'.
875 It checks how many untitled documents exists
876 and adjusts the number.
877  
878 =cut
879  
880 sub docUntitled {
881 my $self = shift;
882 my $name = 'Untitled';
883 if ($self->docExists($name)) {
884 my $num = 2;
885 while ($self->docExists("$name ($num)")) { $num ++ }
886 $name = "$name ($num)";
887 }
888 return $name
889 }
890  
891 sub DoPostConfig {
892 my $self = shift;
893 $self->CreateInterface;
894 }
895  
896 =item B<historyAdd>I<($name)>
897  
898 =cut
899  
900 sub historyAdd {
901 my ($self, $filename) = @_;
902 croak 'Name not defined' unless defined $filename;
903 return if $self->historyDisabled;
904 if (defined($filename) and (-e $filename)) {
905 my $hist = $self->{HISTORY};
906 unshift @$hist, $filename;
907  
908 #Keep history size at or below maximum
909 my $siz = @$hist;
910 pop @$hist if ($siz > $self->configGet('-maxhistory'));
911 }
912 }
913  
914 =item B<historyDisabled>I<($name)>
915  
916 =cut
917  
918 sub historyDisabled {
919 my $self = shift;
920 $self->{HISTORYDISABLED} = shift if @_;
921 return $self->{HISTORYDISABLED}
922 }
923
924  
925 =item B<historyLoad>
926  
927 Loads the history file in the config folder.
928  
929 =cut
930  
931 sub historyLoad {
932 my $self = shift;
933 my $folder = $self->configGet('-configfolder');
934 if (-e "$folder/history") {
935 if (open(OFILE, "<", "$folder/history")) {
936 my @history = ();
937 while (<OFILE>) {
938 my $line = $_;
939 chomp $line;
940 push @history, $line;
941 }
942 close OFILE;
943 $self->{HISTORY} = \@history;
944 }
945 }
946 }
947  
948 =item B<historyRemove>I<($name)>
949  
950 Removes $name from the history list. Called when a document is
951 opened.
952  
953 =cut
954  
955 sub historyRemove {
956 my ($self, $file) = @_;
957 croak 'Name not defined' unless defined $file;
958 return if $self->historyDisabled;
959 my $h = $self->{HISTORY};
960 my ($index) = grep { $h->[$_] eq $file } (0 .. @$h-1);
961 splice @$h, $index, 1 if defined $index;
962 }
963  
964 =item B<historySave>
965  
966 Saves the history list to the history file in the config folder.
967  
968 =cut
969  
970 sub historySave {
971 my $self = shift;
972 my $hist = $self->{HISTORY};
973 if (@$hist) {
974 my $folder = $self->configGet('-configfolder');
975 if (open(OFILE, ">", "$folder/history")) {
976 for (@$hist) {
977 print OFILE "$_\n";
978 }
979 close OFILE
980 } else {
981 warn "Cannot save document history"
982 }
983 }
984 }
985  
986 =item B<Interface>
987  
988 Returns a reference to the multiple document interface.
989  
990 =cut
991  
992 sub Interface {
993 return $_[0]->{INTERFACE}
994 }
995  
996 =item B<interfaceAdd>I<($name)>
997  
998 Adds $name to the multiple document interface and to the
999 Selector if the Selector extension is loaded.
1000  
1001 =cut
1002  
1003 sub interfaceAdd {
1004 my ($self, $name) = @_;
1005 croak 'Name not defined' unless defined $name;
1006  
1007 #add to document notebook
1008 my $if = $self->Interface;
1009 if (defined $if) {
1010 my @op = ();
1011 my $cti = $self->getArt('tab-close', 16);
1012 push @op, -closeimage => $cti if defined $cti;
1013 my $page = $if->addPage($name, @op,
1014 -title => $self->docTitle($name),
1015 -closebutton => 1,
1016 );
1017 }
1018  
1019 #add to navigator
1020 my $navigator = $self->navigator;
1021 if (defined $navigator) {
1022 $navigator->Add($name) if defined $navigator;
1023 # $self->interfaceCollapse;
1024 }
1025 }
1026  
1027 =item B<interfaceCollapse>
1028  
1029 Collapses all folder trees in the document tree except the path of the selected entry, if extension Selector is loaded.
1030  
1031 =cut
1032  
1033 sub interfaceCollapse {
1034 my $self = shift;
1035 my $t = $self->Subwidget('NAVTREE');
1036 $t->collapseAll if defined $t;
1037 }
1038  
1039 =item B<interfaceExpand>
1040  
1041 Opens all folder trees in the document tree, if extension Selector is loaded.
1042  
1043 =cut
1044  
1045 sub interfaceExpand {
1046 my $self = shift;
1047 my $t = $self->Subwidget('NAVTREE');
1048 $t->expandAll if defined $t;
1049 }
1050  
1051 sub interfaceGet {
1052 my $self = shift;
1053 my $navigator = $self->navigator;
1054 return $navigator
1055 }
1056  
1057 =item B<interfaceRemove>I<($name, ?$flag?)>
1058  
1059 Removes $name from the multiple document interface and from the
1060 Selector if the Selector extension is loaded.
1061  
1062 =cut
1063  
1064 sub interfaceRemove {
1065 my ($self, $name, $flag) = @_;
1066 croak 'Name not defined' unless defined $name;
1067 $flag = 1 unless defined $flag;
1068 #remove from document notebook
1069 my $if = $self->Interface;
1070 $if->deletePage($name) if (defined $if) and $flag;
1071  
1072 #remove from navigator
1073 my $navigator = $self->interfaceGet;
1074 $navigator->Delete($name) if defined $navigator;
1075 }
1076  
1077 =item B<interfaceRename>I<($old, $new)>
1078  
1079 Renames the $old entry in the multiple document interface and the navigator.
1080  
1081 =cut
1082  
1083 sub interfaceRename {
1084 my ($self, $old, $new) = @_;
1085 croak 'Old not defined' unless defined $old;
1086 croak 'New not defined' unless defined $new;
1087  
1088 #rename in document notebook
1089 my $if = $self->Interface;
1090 if (defined $if) {
1091 $if->renamePage($old, $new);
1092 my $tab = $if->getTab($new);
1093 $tab->configure(
1094 -name => $new,
1095 -title => $self->docTitle($new),
1096 );
1097 }
1098  
1099 #rename in navigator
1100 my $navigator = $self->interfaceGet;
1101 if (defined $navigator) {
1102 $navigator->Delete($old);
1103 $navigator->Add($new);
1104 }
1105 }
1106  
1107 =item B<interfaceSelect>I<($name)>
1108  
1109 Is called when something else than the user selects a document.
1110  
1111 =cut
1112  
1113 sub interfaceSelect {
1114 my ($self, $name) = @_;
1115 croak 'Name not defined' unless defined $name;
1116  
1117 #select on document notebook
1118 my $if = $self->Interface;
1119 $if->selectPage($name) if defined $if;
1120  
1121 #select on navigator
1122 my $navigator = $self->interfaceGet;
1123 $navigator->SelectEntry($name) if defined $navigator;
1124 }
1125  
1126 =item B<interfaceShow>I<($name)>
1127  
1128 Makes I<$name> visible in the Selector.
1129  
1130 =cut
1131  
1132 sub interfaceShow {
1133 my ($self, $name) = @_;
1134 croak 'Name not defined' unless defined $name;
1135  
1136 my $t = $self->Subwidget('NAVTREE');
1137 $t->entryShow($name) if defined $t;
1138 }
1139  
1140 =item B<MenuItems>
1141  
1142 Returns the menu items for MDI. Called by extension B<MenuBar>.
1143  
1144 =cut
1145  
1146 sub MenuSaveAll {
1147 my $self = shift;
1148 return [ 'menu_normal', 'File::', "Save ~all", 'doc_save_all', 'document-save', 'CTRL+L'],
1149 }
1150  
1151 sub MenuItems {
1152 my $self = shift;
1153 my $readonly = $self->configGet('-readonly');
1154  
1155 my @items = (
1156 # type menupath label cmd icon keyb
1157 [ 'menu', undef, "~File" ],
1158 );
1159 push @items,
1160 [ 'menu_normal', 'File::', "~New", 'doc_new', 'document-new', 'CTRL+N' ],
1161 [ 'menu_separator', 'File::', 'f1'],
1162 unless $readonly;
1163 push @items,
1164 [ 'menu_normal', 'File::', "~Open", 'doc_open', 'document-open', 'CTRL+O' ],
1165 [ 'menu', 'File::', "Open ~recent", 'pop_hist_menu', ],
1166 ;
1167 push @items,
1168 [ 'menu_separator', 'File::', 'f2' ],
1169 [ 'menu_normal', 'File::', "~Save", 'doc_save', 'document-save', 'CTRL+S' ],
1170 [ 'menu_normal', 'File::', "S~ave as", 'doc_save_as', 'document-save-as',],
1171 $self->MenuSaveAll,
1172 unless $readonly;
1173 push @items,
1174 [ 'menu_separator', 'File::', 'f3' ],
1175 [ 'menu_normal', 'File::', "~Close", 'doc_close', 'document-close', 'CTRL+SHIFT+O' ],
1176 ;
1177 return @items
1178 }
1179  
1180 =item B<monitorAdd>I<($name)>
1181  
1182 Adds $name to the hash of monitored documents.
1183 It will check it's modified status. It willcollect its time stamp,
1184 if $name is an existing file.
1185  
1186 =cut
1187  
1188 sub monitorAdd {
1189 my ($self, $name) = @_;
1190 croak 'Name not defined' unless defined $name;
1191  
1192 my $dem = $self->extGet('Daemons');
1193 my $di = $self->configGet('-diskmonitorinterval');
1194 my $mi = $self->configGet('-modifiedmonitorinterval');
1195  
1196 $dem->jobAdd("$name-disk", $di, 'monitorDisk', $self, $name);
1197 $dem->jobAdd("$name-modified", $mi, 'monitorModified', $self, $name);
1198 my $hash = $self->{MONITOR};
1199 my $modified = $self->docModified($name);
1200 my $stamp;
1201 $stamp = ctime(stat($name)->mtime) if -e $name;
1202 $hash->{$name} = {
1203 modified => $modified,
1204 timestamp => $stamp,
1205 }
1206 }
1207  
1208  
1209 =item B<monitorDisk>I<($name)>
1210  
1211 Checks if $name is modified on disk after it was loaded.
1212 Launches a dialog for reload or ignore if so.
1213  
1214 =cut
1215  
1216 sub monitorDisk {
1217 my ($self, $name) = @_;
1218 croak 'Name not defined' unless defined $name;
1219 # print "monitorDisk $name\n";
1220 return unless -e $name;
1221 my $stamp = $self->{MONITOR}->{$name}->{'timestamp'};
1222 my $docstamp = ctime(stat($name)->mtime);
1223 if ($stamp ne $docstamp) {
1224 my $title = 'Warning, file modified on disk';
1225 my $text = "$name\nHas been modified on disk.";
1226 my $icon = 'dialog-warning';
1227 my $answer = $self->popDialog($title, $text, $icon, qw/Reload Ignore/);
1228 if ($answer eq 'Reload') {
1229 $self->docGet($name)->Load($name);
1230 }
1231 $self->{MONITOR}->{$name}->{'timestamp'} = $docstamp;
1232 }
1233 }
1234  
1235 =item B<monitorList>I<($name)>
1236  
1237 returns a list of monitored documents.
1238  
1239 =cut
1240  
1241 sub monitorList {
1242 my $self = shift;
1243 my $hash = $self->{MONITOR};
1244 return sort keys %$hash;
1245 }
1246  
1247 =item B<monitorModified>I<($name)>
1248  
1249 Checks if the modified status of the document has changed
1250 and updates the navigator.
1251  
1252 =cut
1253  
1254 sub monitorModified {
1255 my ($self, $name) = @_;
1256 croak 'Name not defined' unless defined $name;
1257 my $mod = $self->{MONITOR}->{$name}->{'modified'};
1258 my $docmod = $self->docModified($name);
1259 my $nav = $self->navigator;
1260 if ($mod ne $docmod) {
1261 if ($docmod) {
1262 $self->Interface->indicator($name, 1);
1263 $nav->EntryModified($name) if defined $nav;
1264 } else {
1265 $self->Interface->indicator($name, 0);
1266 $nav->EntrySaved($name) if defined $nav;
1267 }
1268 $self->{MONITOR}->{$name}->{'modified'} = $docmod;
1269 }
1270 }
1271  
1272 =item B<monitorRemove>I<($name)>
1273  
1274 Removes $name from the hash of monitored documents.
1275  
1276 =cut
1277  
1278 sub monitorRemove {
1279 my ($self, $name) = @_;
1280 croak 'Name not defined' unless defined $name;
1281 my $dem = $self->extGet('Daemons');
1282 $dem->jobRemove("$name-disk");
1283 $dem->jobRemove("$name-modified");
1284 delete $self->{MONITOR}->{$name};
1285 }
1286  
1287 =item B<monitorUpdate>I<($name)>
1288  
1289 Assigns a fresh time stamp to $name. Called when a document is saved.
1290  
1291 =cut
1292  
1293 sub monitorUpdate {
1294 my ($self, $name) = @_;
1295 croak 'Name not defined' unless defined $name;
1296 $self->{MONITOR}->{$name}->{'timestamp'} = ctime(stat($name)->mtime);
1297 }
1298  
1299 sub navigator {
1300 my $self = shift;
1301 my $nav = $self->extGet('Selector');
1302 return $nav
1303 }
1304  
1305 sub ReConfigure {
1306 my $self = shift;
1307 my @docs = $self->docList;
1308 for (@docs) {
1309 $self->docGet($_)->ConfigureCM;
1310 }
1311 }
1312  
1313 sub Quit {
1314 my $self = shift;
1315 my @docs = $self->docList;
1316 # $self->docForceClose(1);
1317 for (@docs) {
1318 $self->CmdDocClose($_);
1319 }
1320 $self->historySave;
1321 }
1322  
1323 =item B<selectDisabled>I<?$flag?)>
1324  
1325 Sets and returns the selectdisabled flag. If this flag is set,
1326 no document can be selected. Use with care.
1327  
1328 =cut
1329  
1330 sub selectDisabled {
1331 my $self = shift;
1332 $self->{SELECTDISABLED} = shift if @_;
1333 return $self->{SELECTDISABLED}
1334 }
1335  
1336 sub setTitle {
1337 my ($self, $name) = @_;
1338 my $appname = $self->configGet('-appname');
1339 $self->configPut(-title => "$name - $appname") if defined $name;
1340 $self->configPut(-title => $appname) unless defined $name;
1341 }
1342  
1343  
1344 =item B<silentMode>I<($flag)>
1345  
1346 Takes a boolean as parameter. When silentMode is on the document bar will not update,
1347 document history and select are disabled. This will speed up things when you open
1348 multiple documents at once.
1349  
1350 =cut
1351  
1352 sub silentMode {
1353 my ($self, $flag) = @_;
1354 unless (defined $flag) {
1355 return $self->{SILENTMODE};
1356 }
1357 $self->{SILENTMODE} = $flag;
1358 my $if = $self->Interface;
1359 if ($flag) {
1360 $self->{'autoupdate'} = $if->autoupdate;
1361 $if->autoupdate(0);
1362  
1363 $self->{'historydisabled'} = $self->historyDisabled;
1364 $self->historyDisabled(1);
1365  
1366 $self->{'selectdisabled'} = $self->selectDisabled;
1367 $self->selectDisabled(1);
1368  
1369 } else {
1370 my $a = $self->{'autoupdate'};
1371 $if->autoupdate($a) if defined $a;
1372 delete $self->{'autoupdate'};
1373 # $if->UpdateTabs;
1374  
1375 my $h = $self->{'historydisabled'};
1376 $self->historyDisabled($h) if defined $h;
1377 delete $self->{'historydisabled'};
1378  
1379 my $d = $self->{'selectdisabled'};
1380 $self->selectDisabled($d) if defined $d;
1381 delete $self->{'selectdisabled'};
1382 }
1383 }
1384  
1385 sub ToolSaveAll {
1386 my $self = shift;
1387 return [ 'tool_button', 'Save all', 'doc_save_all', 'document-save', 'Save all open documents'],
1388 }
1389  
1390 =item B<ToolItems>
1391  
1392 Returns the tool items for MDI. Called by extension B<ToolBar>.
1393  
1394 =cut
1395  
1396 sub ToolItems {
1397 my $self = shift;
1398 my $readonly = $self->configGet('-readonly');
1399 my @items = ();
1400  
1401 push @items,
1402 # type label cmd icon help
1403 [ 'tool_button', 'New', 'doc_new', 'document-new', 'Create a new document'],
1404 unless $readonly;
1405  
1406 push @items,
1407 [ 'tool_list', 'history', 'pop_hist_tool' ],
1408 [ 'tool_button', 'Open', 'doc_open', 'document-open', 'Open a document'],
1409 [ 'tool_list_end' ],
1410
1411 ;
1412  
1413 push @items,
1414
1415 [ 'tool_list' ],
1416 [ 'tool_button', 'Save', 'doc_save', 'document-save', 'Save current document'],
1417 [ 'tool_button', 'Save as ', 'doc_save_as', 'document-save-as', 'Rename and save current document'],
1418 $self->ToolSaveAll,
1419 [ 'tool_list_end' ],
1420 unless $readonly;
1421  
1422 push @items,
1423 [ 'tool_button', 'Close', 'doc_close', 'document-close', 'Close current document'],
1424 ;
1425 return @items
1426 }
1427  
1428  
1429 =back
1430  
1431 =head1 AUTHOR
1432  
1433 Hans Jeuken (hanje at cpan dot org)
1434  
1435 =head1 BUGS
1436  
1437 Unknown. If you find any, please contact the author.
1438  
1439 =head1 SEE ALSO
1440  
1441 =over 4
1442  
1443 =item L<Tk::AppWindow>
1444  
1445 =item L<Tk::AppWindow::BaseClasses::Extension>
1446  
1447 =item L<Tk::AppWindow::BaseClasses::ContentManager>
1448  
1449 =item L<Tk::AppWindow::Ext::ConfigFolder>
1450  
1451 =item L<Tk::AppWindow::Ext::Selector>
1452  
1453 =back
1454  
1455 =cut
1456  
1457 1;