File Coverage

blib/lib/Date/Language.pm

Criterion	Covered	Total	%
statement	65	66	98.4
branch	9	18	50.0
condition	8	12	66.6
subroutine	10	11	90.9
pod	1	2	50.0
total	93	109	85.3

package Date::Language;

use     strict;
use     Time::Local;
use     Carp;

require Date::Format;

our $VERSION = '2.34'; # VERSION: generated
# ABSTRACT: Language specific date formatting and parsing

use base qw(Date::Format::Generic);

sub _build_lookups
{
 my $pkg = caller;
 no strict 'refs';
 @{"${pkg}::MoY"}{@{"${pkg}::MoY"}}  = (0 .. scalar(@{"${pkg}::MoY"}));
 @{"${pkg}::MoY"}{@{"${pkg}::MoYs"}} = (0 .. scalar(@{"${pkg}::MoYs"}));
 @{"${pkg}::DoW"}{@{"${pkg}::DoW"}}  = (0 .. scalar(@{"${pkg}::DoW"}));
 @{"${pkg}::DoW"}{@{"${pkg}::DoWs"}} = (0 .. scalar(@{"${pkg}::DoWs"}));
}

sub new
{
 my $self = shift;
 my $type = shift || $self;

 $type =~ s/^(\w+)$/Date::Language::$1/;

 croak "Bad language"
    unless $type =~ /^[\w:]+$/;

 eval "require $type"
    or croak $@;

 bless [], $type;
}

# Stop AUTOLOAD being called ;-)
sub DESTROY {}

sub AUTOLOAD
{
 our $AUTOLOAD;
 if($AUTOLOAD =~ /::strptime\Z/o)
  {
   my $self = $_[0];
   my $type = ref($self) || $self;
   require Date::Parse;

   no strict 'refs';
   *{"${type}::strptime"} = Date::Parse::gen_parser(
    \%{"${type}::DoW"},
    \%{"${type}::MoY"},
    \@{"${type}::Dsuf"},
    1);

   goto &{"${type}::strptime"};
  }

 croak "Undefined method &$AUTOLOAD called";
}

sub str2time
{
 my $me = shift;
 my @t = $me->strptime(@_);

 return undef
    unless @t;

 my($ss,$mm,$hh,$day,$month,$year,$zone) = @t;
 my @lt  = localtime(time);

 $hh    ||= 0;
 $mm    ||= 0;
 $ss    ||= 0;

 $month = $lt[4]
    unless(defined $month);

 $day  = $lt[3]
    unless(defined $day);

 $year = ($month > $lt[4]) ? ($lt[5] - 1) : $lt[5]
    unless(defined $year);

 return defined $zone ? timegm($ss,$mm,$hh,$day,$month,$year) - $zone
                      : timelocal($ss,$mm,$hh,$day,$month,$year);
}

1;

__END__