File Coverage

blib/lib/Time/Tiny.pm

Criterion	Covered	Total	%
statement	30	39	76.9
branch	5	10	50.0
condition	1	3	33.3
subroutine	13	16	81.2
pod	8	8	100.0
total	57	76	75.0

use strict;
use warnings;
package Time::Tiny;
# ABSTRACT: A time object, with as little code as possible

our $VERSION = '1.08';

use overload 'bool' => sub () { 1 };
use overload '""'   => 'as_string';
use overload 'eq'   => sub { "$_[0]" eq "$_[1]" };
use overload 'ne'   => sub { "$_[0]" ne "$_[1]" };





#####################################################################
# Constructor and Accessors

#pod =pod
#pod
#pod =method new
#pod
#pod   # Create a Time::Tiny object for midnight
#pod   my $midnight = Time::Tiny->new(
#pod       hour   => 0,
#pod       minute => 0,
#pod       second => 0,
#pod   );
#pod
#pod The C constructor creates a new B object.
#pod
#pod It takes three named parameters. C should be the hour of the day (0-23),
#pod C should be the minute of the hour (0-59), and C should be
#pod the second of the minute (0-59).
#pod
#pod These are the only parameters accepted.
#pod
#pod Returns a new B object.
#pod
#pod =cut

sub new {
	my $class = shift;
	bless { @_ }, $class;
}

#pod =pod
#pod
#pod =method now
#pod
#pod   my $current_time = Time::Tiny->now;
#pod
#pod The C method creates a new date object for the current time.
#pod
#pod The time created will be based on localtime, despite the fact that
#pod the time is created in the floating time zone.
#pod
#pod This means that the time created by C is somewhat lossy, but
#pod since the primary purpose of B is for small transient
#pod time objects, and B for use in calculations and comparisons,
#pod this is considered acceptable for now.
#pod
#pod Returns a new B object.
#pod
#pod =cut

sub now {
	my @t = localtime time;
	$_[0]->new(
		hour   => $t[2],
		minute => $t[1],
		second => $t[0],
	);
}

#pod =pod
#pod
#pod =method hour
#pod
#pod The C accessor returns the hour component of the time as
#pod an integer from zero to twenty-three (0-23) in line with 24-hour
#pod time.
#pod
#pod =cut

sub hour {
	$_[0]->{hour} || 0;
}

#pod =pod
#pod
#pod =method minute
#pod
#pod The C accessor returns the minute component of the time
#pod as an integer from zero to fifty-nine (0-59).
#pod
#pod =cut

sub minute {
	$_[0]->{minute} || 0;
}

#pod =pod
#pod
#pod =method second
#pod
#pod The C accessor returns the second component of the time
#pod as an integer from zero to fifty-nine (0-59).
#pod
#pod =cut

sub second {
	$_[0]->{second} || 0;
}





#####################################################################
# Type Conversion

#pod =pod
#pod
#pod =method from_string
#pod
#pod The C method creates a new B object from a string.
#pod
#pod The string is expected to be an "hh:mm:ss" type ISO 8601 time string.
#pod
#pod   my $almost_midnight = Time::Tiny->from_string( '23:59:59' );
#pod
#pod Returns a new B object, or throws an exception on error.
#pod
#pod =cut

sub from_string {
	my $string = $_[1];
	unless ( defined $string and ! ref $string ) {
		require Carp;
		Carp::croak("Did not provide a string to from_string");
	}
	unless ( $string =~ /^(\d\d):(\d\d):(\d\d)$/ ) {
		require Carp;
		Carp::croak("Invalid time format (does not match ISO 8601 hh:mm:ss)");
	}
	$_[0]->new(
		hour   => $1 + 0,
		minute => $2 + 0,
		second => $3 + 0,
	);
}

#pod =pod
#pod
#pod =method as_string
#pod
#pod The C method converts the time object to an ISO 8601
#pod time string, with separators (see example in C).
#pod
#pod Returns a string.
#pod
#pod =cut

sub as_string {
	sprintf( "%02u:%02u:%02u",
		$_[0]->hour,
		$_[0]->minute,
		$_[0]->second,
	);
}

#pod =pod
#pod
#pod =method DateTime
#pod
#pod The C method is used to create a L object
#pod that is equivalent to the B object, for use in
#pod conversions and calculations.
#pod
#pod As mentioned earlier, the object will be set to the 'C' locate,
#pod and the 'floating' time zone.
#pod
#pod If installed, the L module will be loaded automatically.
#pod
#pod Returns a L object, or throws an exception if L
#pod is not installed on the current host.
#pod
#pod =cut

sub DateTime {
	require DateTime;
	my $self = shift;
	DateTime->new(
		year      => 1970,
		month     => 1,
		day       => 1,
		hour      => $self->hour,
		minute    => $self->minute,
		second    => $self->second,
		locale    => 'C',
		time_zone => 'floating',
		@_,
	);
}

1;

__END__