File Coverage

blib/lib/Time/Elapse.pm

Criterion	Covered	Total	%
statement	39	43	90.7
branch	10	20	50.0
condition			n/a
subroutine	9	9	100.0
pod	0	1	0.0
total	58	73	79.4

package Time::Elapse;

require 5.006;
use strict;
use warnings;
use autouse 'Carp' => qw(confess);
use POSIX qw/ strftime /;
use Time::HiRes qw/ gettimeofday /;

# localtime and gmtime seem to be reversed
# across different OS's (MacPerl, Darwin Perl, linux Perl)
# perhaps my install of Perl is broken? setting local TZ to
# UTC seems to resolve this but it *should not be necessary!*

our $VERSION = 1.24_02;
our $_DEBUG = 0;

sub TIESCALAR
{
	local $ENV{TZ} = 'UTC';# ridiculous! shouldn't be necessary.
	my( $class, $val ) = @_;
	$val = "" unless defined($val);

	confess "Elapse->lapse() unable to use referenced values"
	  if ref($val);

	bless { now => [gettimeofday()], val => $val }, $class;
}

sub FETCH
{
	local $ENV{TZ} = 'UTC';# ridiculous! shouldn't be necessary.
	my ( $impl, $val ) = @_;
	my ($time, $ms) =  gettimeofday();

	print "(\$time = $time, \$ms = $ms)\n"
		if $_DEBUG;

	if ( $ms < $impl->{now}[1] )
	{
		$time--;
		$ms += 1000000;
	}

	print "changed? (\$time = $time, \$ms = $ms) [ $impl->{now}[1] ]\n"
		if $_DEBUG;

	my $float = sprintf("%06d", $ms - $impl->{now}[1]);
	print "Float = $float\n"
		if $_DEBUG;

	my $int = strftime( "%H:%M:%S", localtime( $time - $impl->{now}[0] ) );

	print <<"EOF" if $_DEBUG;
	# int = $int
	# Time = $time
	# IMPL = $impl->{now}[0]
	# Time - IMPL = @{[ $time - $impl->{now}[0] ]}
	# localtime = @{[ localtime($time - $impl->{now}[0]) ]}
EOF

	$val =  $impl->{val} eq "" ? "" : " [$impl->{val}]";

	return "$int.$float" . $val;
}

sub STORE
{
	local $ENV{TZ} = 'UTC';# ridiculous! shouldn't be necessary.
	my($impl, $val) = @_;
	$val = "" unless defined($val);

	confess "Elapse->lapse() unable to use referenced values"
	  if ref($val);

	$impl->{now} = [gettimeofday()];
	$impl->{val} = $val;
}


sub lapse
{
	tie $_[1], $_[0], $_[1];
}

1;

__END__