File Coverage

blib/lib/Text/ECSV.pm

Criterion	Covered	Total	%
statement	30	32	93.7
branch	3	6	50.0
condition	2	3	66.6
subroutine	6	6	100.0
pod	3	3	100.0
total	44	50	88.0

package Text::ECSV;

use warnings;
use strict;

our $VERSION = '0.02';

use base 'Text::CSV_XS', 'Class::Accessor::Fast';

__PACKAGE__->mk_accessors(qw{
        fields_hash
        dup_keys_strategy
        }
);

sub field_named {
    my $self = shift;
    my $name = shift;

    return $self->fields_hash->{$name};
}

sub parse {
    my $self = shift;

    # reset fields hash
    $self->fields_hash({});

    # run Text::CSV_XS parse
    my $status = $self->SUPER::parse(@_);

    # if the CSV parsing failed then just return
    return $status
        if not $status;

    # decode the fileds
    foreach my $field ($self->fields) {

        # if we have key value pair
        if ($field =~ m/^([^=]+)=(.*)$/) {
            my $name  = $1;
            my $value = $2;

            # if it the second occurence of the same key and we have a strategy use it
            #    to construct the new value
            if (    exists $self->{'fields_hash'}->{$name}
                and exists $self->{'dup_keys_strategy'}) {
                $value = $self->{'dup_keys_strategy'}
                    ->($name, $self->{'fields_hash'}->{$name}, $value);
            }

            # store value
            $self->{'fields_hash'}->{$name} = $value;
        }

        # else fail
        else {
            $status = 0;

            # TODO fill error messages

            last;
        }
    }

    return $status;
}

sub combine {
    my $self       = shift;
    my @key_values = @_;
    my @fields;

    while (@key_values) {
        push @fields, (shift(@key_values) . '=' . shift(@key_values));
    }

    return $self->SUPER::combine(@fields);
}

1;

__END__