File Coverage

blib/lib/Text/ANSI/Tabs.pm

Criterion	Covered	Total	%
statement	53	58	91.3
branch	14	22	63.6
condition	1	3	33.3
subroutine	11	12	91.6
pod	3	4	75.0
total	82	99	82.8

package Text::ANSI::Tabs;
our $VERSION = "1.06";

=encoding utf-8

=head1 NAME

Text::ANSI::Tabs - Tab expand and unexpand with ANSI sequence

=head1 SYNOPSIS

    use Text::ANSI::Tabs qw(:all);
    use Text::ANSI::Tabs qw(ansi_expand ansi_unexpand);
    ansi_expand($text);
    ansi_unexpand($text);

    use Text::ANSI::Tabs;
    Text::ANSI::Tabs::expand($text);
    Text::ANSI::Tabs::unexpand($text);

=head1 VERSION

Version 1.06

=cut

use v5.14;
use utf8;
use warnings;
use Data::Dumper;

BEGIN {
    *ansi_expand   = \&expand;
    *ansi_unexpand = \&unexpand;
}

use Exporter qw(import);
our @EXPORT_OK = qw(
    &ansi_expand &ansi_unexpand $tabstop
    &configure
    );
our %EXPORT_TAGS = ( all => [ @EXPORT_OK ] );

use Text::ANSI::Fold qw(
    $csi_re
    $reset_re
    $erase_re
    );
my  $end_re = qr{ $reset_re | $erase_re }x;

my $fold = Text::ANSI::Fold->new;

our $tabstop = 8;
our $min_space = 2;
our $REMOVE_REDUNDANT = 1;

sub configure {
    my $class = shift;
    @_ % 2 and die "invalid parameter.\n";
    my @fold_opt;
    while (my($k, $v) = splice(@_, 0, 2)) {
	if ($k eq 'tabstop') {
	    $tabstop = $v;
	}
	elsif ($k eq 'minimum') {
	    $v =~ /^\d+$/ and $v > 0
		or die "$v: invalid value for minimum space.\n";
	    $min_space = $v;
	} else {
	    push @fold_opt, $k => $v;
	}
    }
    $fold->configure(@fold_opt) if @fold_opt;
    return $fold;
}

sub IsEOL {
    <<"END";
0000\t0000
000A\t000D
2028\t2029
END
}

sub expand {
    $fold->configure(width => -1, expand => 1, tabstop => $tabstop,
		     ref $_[0] eq 'ARRAY' ? @{+shift} : ());
    my @l = map {
	s{^ (?>.*\t) (?: [^\e\n]* $end_re+ )? }{
	    join '', $fold->text(${^MATCH})->chops();
	}xmgepr;
    } @_;
    wantarray ? @l : $l[0];
}

sub unexpand {
    my @opt = ref $_[0] eq 'ARRAY' ? @{+shift} : ();
    my @l = map {
	s{ ^(.*[ ].*) }{ _unexpand($1) }xmger
    } @_;
    if ($REMOVE_REDUNDANT) {
	for (@l) {
	    1 while s/ (?$csi_re+) [^\e\n]* \K $end_re+ \g{c} //xg;
	}
    }
    wantarray ? @l : $l[0];
}

sub _unexpand {
    local $_ = shift;
    my $ret = '';
    my $margin = 0;
    while (/ /) {
	my $width = $tabstop + $margin;
	my($a, $b, $w) = $fold->fold($_, width => $width);
	if ($w == $width) {
	    $a =~ s/([ ]{$min_space,})(?= $end_re* $)/\t/x;
	}
	$margin = $width - $w;
	$ret .= $a;
	$_ = $b;
    }
    $ret . $_;
}

1;

__END__