| 1 | package Test2::Harness::Renderer::UIDB; | ||
| 2 | use strict; | ||
| 3 | use warnings; | ||
| 4 | |||
| 5 | use Carp qw/croak/; | ||
| 6 | use Sys::Hostname qw/hostname/; | ||
| 7 | |||
| 8 | use DateTime; | ||
| 9 | |||
| 10 | use Time::HiRes qw/time/; | ||
| 11 | use Test2::Harness::UI::Config; | ||
| 12 | use Test2::Harness::UI::RunProcessor; | ||
| 13 | use Test2::Harness::Runner::State; | ||
| 14 | use Test2::Harness::UI::Util qw/config_from_settings/; | ||
| 15 | use Test2::Harness::Util::JSON qw/encode_json/; | ||
| 16 | |||
| 17 | use Test2::Harness::UI::UUID qw/gen_uuid uuid_inflate/; | ||
| 18 | |||
| 19 | use Test2::Harness::Util qw/mod2file/; | ||
| 20 | |||
| 21 | our $VERSION = '0.000150'; | ||
| 22 | |||
| 23 | use parent 'Test2::Harness::Renderer'; | ||
| 24 | use Test2::Harness::Util::HashBase qw{ | ||
| 25 | <run | ||
| 26 | <processor | ||
| 27 | <config | ||
| 28 | <dbh | ||
| 29 | <project | ||
| 30 | <user | ||
| 31 | <finished | ||
| 32 | +links | ||
| 33 | |||
| 34 | +resources +resource_interval +state +host | ||
| 35 | |||
| 36 | <last_resource_stamp | ||
| 37 | }; | ||
| 38 | |||
| 39 | sub init { | ||
| 40 | my $self = shift; | ||
| 41 | |||
| 42 | my $settings = $self->settings; | ||
| 43 | |||
| 44 | my $yath = $settings->yathui; | ||
| 45 | $self->{+PROJECT} //= $yath->project || die "The yathui-project option is required.\n"; | ||
| 46 | $self->{+USER} //= $yath->user || die "The yathui-user option is required.\n"; | ||
| 47 | |||
| 48 | my $config = $self->{+CONFIG} //= config_from_settings($settings); | ||
| 49 | |||
| 50 | my $dbh = $config->connect // die "Could not connect to the db"; | ||
| 51 | $dbh->{mysql_auto_reconnect} = 1 if $Test2::Harness::UI::Schema::LOADED =~ m/mysql/i; | ||
| 52 | |||
| 53 | STDOUT->autoflush(1); | ||
| 54 | print $self->links; | ||
| 55 | } | ||
| 56 | |||
| 57 | sub step { | ||
| 58 | my $self = shift; | ||
| 59 | |||
| 60 | $self->send_resources(); | ||
| 61 | } | ||
| 62 | |||
| 63 | sub resource_interval { | ||
| 64 | my $self = shift; | ||
| 65 | return $self->{+RESOURCE_INTERVAL} //= $self->settings->yathui->resources; | ||
| 66 | } | ||
| 67 | |||
| 68 | sub state { | ||
| 69 | my $self = shift; | ||
| 70 | |||
| 71 | return $self->{+STATE} if $self->{+STATE}; | ||
| 72 | |||
| 73 | my $settings = $self->settings; | ||
| 74 | |||
| 75 | return $self->{+STATE} = Test2::Harness::Runner::State->new( | ||
| 76 | observe => 1, | ||
| 77 | job_count => $settings->runner->job_count // 1, | ||
| 78 | workdir => $settings->workspace->workdir, | ||
| 79 | ); | ||
| 80 | } | ||
| 81 | |||
| 82 | sub resources { | ||
| 83 | my $self = shift; | ||
| 84 | return $self->{+RESOURCES} if $self->{+RESOURCES}; | ||
| 85 | |||
| 86 | my $state = $self->state; | ||
| 87 | $state->poll; | ||
| 88 | |||
| 89 | return $self->{+RESOURCES} = [grep { $_ && $_->can('status_data') } @{$state->resources}]; | ||
| 90 | } | ||
| 91 | |||
| 92 | sub send_resources { | ||
| 93 | my $self = shift; | ||
| 94 | |||
| 95 | return unless $self->{+RUN}; | ||
| 96 | |||
| 97 | my $interval = $self->resource_interval or return; | ||
| 98 | my $resources = $self->resources or return; | ||
| 99 | return unless @$resources; | ||
| 100 | |||
| 101 | my $stamp = time; | ||
| 102 | |||
| 103 | if (my $last = $self->{+LAST_RESOURCE_STAMP}) { | ||
| 104 | my $delta = $stamp - $last; | ||
| 105 | return unless $delta >= $interval; | ||
| 106 | } | ||
| 107 | |||
| 108 | unless(eval { $self->_send_resources($stamp => $resources); 1 }) { | ||
| 109 | my $err = $@; | ||
| 110 | warn "Non fatal error, could not send resource info to YathUI: $err"; | ||
| 111 | return; | ||
| 112 | } | ||
| 113 | |||
| 114 | return $self->{+LAST_RESOURCE_STAMP} = $stamp; | ||
| 115 | } | ||
| 116 | |||
| 117 | sub host { | ||
| 118 | my $self = shift; | ||
| 119 | return $self->{+HOST} //= $self->{+CONFIG}->schema->resultset('Host')->find_or_create({hostname => hostname(), host_id => gen_uuid()}); | ||
| 120 | } | ||
| 121 | |||
| 122 | sub _send_resources { | ||
| 123 | my $self = shift; | ||
| 124 | my ($stamp, $resources) = @_; | ||
| 125 | |||
| 126 | my $config = $self->{+CONFIG}; | ||
| 127 | |||
| 128 | my $run_id = $self->settings->run->run_id; | ||
| 129 | my $host_id = $self->host->host_id; | ||
| 130 | |||
| 131 | my $res_rs = $config->schema->resultset('Resource'); | ||
| 132 | my $batch_rs = $config->schema->resultset('ResourceBatch'); | ||
| 133 | |||
| 134 | $self->state->poll; | ||
| 135 | |||
| 136 | my $dt_stamp = DateTime->from_epoch(epoch => $stamp, time_zone => 'local'); | ||
| 137 | |||
| 138 | my $batch_id = gen_uuid(); | ||
| 139 | my $batch = $batch_rs->create({ | ||
| 140 | resource_batch_id => $batch_id, | ||
| 141 | run_id => uuid_inflate($run_id), | ||
| 142 | host_id => uuid_inflate($host_id), | ||
| 143 | stamp => $dt_stamp, | ||
| 144 | }); | ||
| 145 | |||
| 146 | my $ord = 0; | ||
| 147 | |||
| 148 | my @items; | ||
| 149 | for my $res (@$resources) { | ||
| 150 | my $data = $res->status_data or next; | ||
| 151 | |||
| 152 | my $item = { | ||
| 153 | resource_id => gen_uuid(), | ||
| 154 | resource_batch_id => $batch_id, | ||
| 155 | batch_ord => $ord++, | ||
| 156 | module => ref($res) || $res, | ||
| 157 | data => encode_json($data), | ||
| 158 | }; | ||
| 159 | |||
| 160 | push @items => $item; | ||
| 161 | } | ||
| 162 | |||
| 163 | $res_rs->populate(\@items); | ||
| 164 | |||
| 165 | return; | ||
| 166 | } | ||
| 167 | |||
| 168 | sub links { | ||
| 169 | my $self = shift; | ||
| 170 | return $self->{+LINKS} if defined $self->{+LINKS}; | ||
| 171 | |||
| 172 | if (my $url = $self->settings->yathui->url) { | ||
| 173 | $self->{+LINKS} = "\nThis run can be reviewed at: $url/view/" . $self->settings->run->run_id . "\n\n"; | ||
| 174 | } | ||
| 175 | |||
| 176 | return $self->{+LINKS} //= ""; | ||
| 177 | } | ||
| 178 | |||
| 179 | sub signal { | ||
| 180 | my $self = shift; | ||
| 181 | my ($sig) = @_; | ||
| 182 | |||
| 183 | $self->{+PROCESSOR}->set_signal($sig) if $self->{+PROCESSOR}; | ||
| 184 | |||
| 185 | my $run = $self->{+RUN} or return; | ||
| 186 | $run->update({status => 'canceled', error => "Canceled with signal '$sig'"}); | ||
| 187 | } | ||
| 188 | |||
| 189 | sub render_event { | ||
| 190 | my $self = shift; | ||
| 191 | my @args = @_; | ||
| 192 | |||
| 193 | my $out; | ||
| 194 | eval { $out = $self->_render_event(@args); 1 } and return $out; | ||
| 195 | my $err = $@; | ||
| 196 | warn "YathUI-DB Renderer error:\n====\n$err\n====\n"; | ||
| 197 | die $err unless $self->{+RUN}; | ||
| 198 | } | ||
| 199 | |||
| 200 | sub _render_event { | ||
| 201 | my $self = shift; | ||
| 202 | my ($event) = @_; | ||
| 203 | |||
| 204 | my $f = $event->{facet_data}; | ||
| 205 | |||
| 206 | if (my $runf = $f->{harness_run}) { | ||
| 207 | my $run_id = uuid_inflate($runf->{run_id}) or die "No run-id?"; | ||
| 208 | |||
| 209 | my $config = $self->{+CONFIG}; | ||
| 210 | |||
| 211 | my $p = $config->schema->resultset('Project')->find_or_create({name => $self->{+PROJECT}, project_id => gen_uuid()}); | ||
| 212 | my $u = $config->schema->resultset('User')->find_or_create({username => $self->{+USER}, user_id => gen_uuid(), role => 'user'}); | ||
| 213 | |||
| 214 | my $ydb = $self->settings->prefix('yathui-db') or die "No DB settings"; | ||
| 215 | my $run = $config->schema->resultset('Run')->create({ | ||
| 216 | run_id => $run_id, | ||
| 217 | mode => $self->settings->yathui->mode, | ||
| 218 | buffer => $ydb->buffering, | ||
| 219 | status => 'pending', | ||
| 220 | user_id => $u->user_id, | ||
| 221 | project_id => $p->project_id, | ||
| 222 | }); | ||
| 223 | |||
| 224 | $self->{+RUN} = $run; | ||
| 225 | |||
| 226 | my $processor = Test2::Harness::UI::RunProcessor->new( | ||
| 227 | config => $config, | ||
| 228 | run => $run, | ||
| 229 | interval => $ydb->flush_interval, | ||
| 230 | ); | ||
| 231 | |||
| 232 | $self->{+PROCESSOR} = $processor; | ||
| 233 | $processor->start(); | ||
| 234 | } | ||
| 235 | elsif (!$self->{+RUN}) { | ||
| 236 | die "Run was not seen!"; | ||
| 237 | } | ||
| 238 | |||
| 239 | $self->{+PROCESSOR}->process_event($event, $f); | ||
| 240 | } | ||
| 241 | |||
| 242 | sub finish { | ||
| 243 | my $self = shift; | ||
| 244 | |||
| 245 | eval { $self->{+PROCESSOR}->finish(); 1 } or warn "YathUI-DB finish error:\n====\n$@\n====\n"; | ||
| 246 | |||
| 247 | $self->{+FINISHED} = 1; | ||
| 248 | |||
| 249 | print $self->links; | ||
| 250 | } | ||
| 251 | |||
| 252 | sub DESTROY { | ||
| 253 | my $self = shift; | ||
| 254 | |||
| 255 | return if $self->{+FINISHED}; | ||
| 256 | |||
| 257 | my $run = $self->{+RUN} or return; | ||
| 258 | $run->update({status => 'broken', error => 'Run did not finish'}); | ||
| 259 | } | ||
| 260 | |||
| 261 | 1; |