File Coverage

blib/lib/Test/CheckGitStatus.pm

Criterion	Covered	Total	%
statement	15	31	48.3
branch	3	14	21.4
condition	1	3	33.3
subroutine	5	7	71.4
pod	0	1	0.0
total	24	56	42.8

# ABSTRACT: Check git status after every test
package Test::CheckGitStatus;
use strict;
use warnings;
use Config;

our $VERSION = 'v0.1.2'; # VERSION

my $CHECK_GIT_STATUS = $ENV{CHECK_GIT_STATUS};

# prevent subsequent perl processes to check the status
if ($ENV{HARNESS_ACTIVE} or $ENV{TEST_ACTIVE} or $ENV{TEST2_ACTIVE}) {
    $ENV{CHECK_GIT_STATUS} = 0;
}
else {
    $CHECK_GIT_STATUS = 0;
}

# Prevent forked processes to check the status
my $pid = $$;

my $cwd;

if ($CHECK_GIT_STATUS) {
    require Test::More;
    require Cwd;
    $cwd = Cwd::cwd();
}

sub check_status {
    my @lines = _get_status();
    if (@lines > 0) {
        Test::More::diag("Error: modified or untracked files\n" . join '', @lines);
        $? = 1;
    }
}

sub _check_git {
    require File::Which;
    my $git = File::Which::which('git');
    return unless $git;
    if ($Config{osname} eq 'MSWin32') {
        $git = qq{"$git"};
    }
    return $git;
}

sub _get_status {
    local $?;
    chdir $cwd;
    my $git = _check_git();
    return unless $git;
    my $cmd = qq{$git rev-parse --git-dir};
    my $out = qx{$cmd};
    return if $? != 0;
    $cmd = qq{$git status --porcelain=v1 2>&1};
    my @lines = qx{$cmd};
    die "Problem running '$git':\n" . join '', @lines if $? != 0;
    return @lines;
}

END {
    # Check $pid - don't run this in forked processes
    check_status() if $$ == $pid and $CHECK_GIT_STATUS;
}

1;

__END__