File Coverage

blib/lib/Template/Plugin/Autoformat.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	12	12	100.0
condition			n/a
subroutine	9	9	100.0
pod	1	1	100.0
total	59	59	100.0

#============================================================= -*-Perl-*-
#
# Template::Plugin::Autoformat
#
# DESCRIPTION
#   Plugin interface to Damian Conway's Text::Autoformat module.
#
# AUTHORS
#   Robert McArthur
#     - original plugin code
#
#   Andy Wardley
#     - added FILTER registration, support for forms and some additional
#       documentation
#
# COPYRIGHT
#   Copyright (C) 2000-2008 Robert McArthur, Andy Wardley.
#   All Rights Reserved.
#
#   This module is free software; you can redistribute it and/or
#   modify it under the same terms as Perl itself.
#
#============================================================================

package Template::Plugin::Autoformat;

use strict;
use warnings;
use base 'Template::Plugin';
use Text::Autoformat;

our $VERSION = '2.79';

sub new {
    my ( $class, $context, $options ) = @_;
    my $filter_factory;
    my $plugin;

    if ($options) {

        # create a closure to generate filters with additional options
        $filter_factory = sub {
            my $context = shift;
            my $filtopt = ref $_[-1] eq 'HASH' ? pop : {};
            @$filtopt{ keys %$options } = values %$options;
            return sub {
                _tt_autoformat( @_, $filtopt );
            };
        };

        # and a closure to represent the plugin
        $plugin = sub {
            my $plugopt = ref $_[-1] eq 'HASH' ? pop : {};
            @$plugopt{ keys %$options } = values %$options;
            _tt_autoformat( @_, $plugopt );
        };
    }
    else {
        # simple filter factory closure (no legacy options from constructor)
        $filter_factory = sub {
            my $context = shift;
            my $filtopt = ref $_[-1] eq 'HASH' ? pop : {};
            return sub {
                _tt_autoformat( @_, $filtopt );
            };
        };

        # plugin without options can be static
        $plugin = \&_tt_autoformat;
    }

    # now define the filter and return the plugin
    $context->define_filter( 'Autoformat', [ $filter_factory => 1 ] );
    return $plugin;
}

sub _tt_autoformat {
    my $options = ref $_[-1] eq 'HASH' ? pop : {};
    my $form = $options->{form};
    my $out
        = $form
        ? Text::Autoformat::form( $options, $form, @_ )
        : Text::Autoformat::autoformat( join( '', @_ ), $options );
    return $out;
}

1;

__END__