File Coverage

blib/lib/Tags/HTML/Tree.pm

Criterion	Covered	Total	%
statement	82	82	100.0
branch	6	6	100.0
condition	6	6	100.0
subroutine	18	18	100.0
pod	1	1	100.0
total	113	113	100.0

package Tags::HTML::Tree;

use base qw(Tags::HTML);
use strict;
use warnings;

use Class::Utils qw(set_params split_params);
use English;
use Error::Pure qw(err);
use Mo::utils 0.12 qw(check_code check_required);
use Mo::utils::CSS 0.07 qw(check_css_class check_css_unit);
use Scalar::Util qw(blessed);
use Unicode::UTF8 qw(decode_utf8);

our $VERSION = 0.07;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my ($object_params_ar, $other_params_ar) = split_params(
		['cb_value', 'css_class', 'indent'], @params);
	my $self = $class->SUPER::new(@{$other_params_ar});

	# Callback for tree value.
	$self->{'cb_value'} = sub {
		my ($self, $tree) = @_;

		$self->{'tags'}->put(
			['d', $tree->value],
		);

		return;
	};

	# CSS class.
	$self->{'css_class'} = 'tree';

	# Tree indent.
	$self->{'indent'} = '2em';

	# Process params.
	set_params($self, @{$object_params_ar});

	check_code($self, 'cb_value');

	check_required($self, 'css_class');
	check_css_class($self, 'css_class');

	check_css_unit($self, 'indent');

	# Object.
	return $self;
}

sub _cleanup {
	my $self = shift;

	delete $self->{'_tree'};

	return;
}

sub _init {
	my ($self, $tree) = @_;

	if (! defined $tree
		|| ! blessed($tree)
		|| ! $tree->isa('Tree')) {

		err "Data object must be a 'Tree' instance.";
	}

	$self->{'_tree'} = $tree;

	return;
}

sub _prepare {
	my $self = shift;

	$self->script_js([<<"END"]);
window.addEventListener('load', (event) => {
    let toggler = document.getElementsByClassName("caret");
    for (let i = 0; i < toggler.length; i++) {
        toggler[i].addEventListener("click", function() {
            this.parentElement.querySelector(".nested").classList.toggle("active");
            this.classList.toggle("caret-down");
        });
    }
});
END

	return;
}

# Process 'Tags'.
sub _process {
	my $self = shift;

	if (! exists $self->{'_tree'}) {
		return;
	}

	$self->{'tags'}->put(
		['b', 'ul'],
		['a', 'class', $self->{'css_class'}],
	);
	$self->_li($self->{'_tree'});
	$self->{'tags'}->put(
		['e', 'ul'],
	);

	return;
}

sub _process_css {
	my $self = shift;

	$self->{'css'}->put(
		['s', 'ul, .'.$self->{'css_class'}],
		['d', 'list-style-type', 'none'],
		['d', 'padding-left', $self->{'indent'}],
		['e'],

		['s', '.caret'],
		['d', 'cursor', 'pointer'],
		['d', '-webkit-user-select', 'none'],
		['d', '-moz-user-select', 'none'],
		['d', '-ms-user-select', 'none'],
		['d', 'user-select', 'none'],
		['e'],

		['s', '.caret::before'],
		['d', 'content', decode_utf8('"⯈"')],
		['d', 'color', 'black'],
		['d', 'display', 'inline-block'],
		['d', 'margin-right', '6px'],
		['e'],

		['s', '.caret-down::before'],
		['d', 'transform', 'rotate(90deg)'],
		['e'],

		['s', '.nested'],
		['d', 'display', 'none'],
		['e'],

		['s', '.active'],
		['d', 'display', 'block'],
		['e'],
	);

	return;
}

sub _li {
	my ($self, $tree) = @_;

	my $meta_hr = $tree->meta;
	$self->{'tags'}->put(
		['b', 'li'],
	);
	my @children = $tree->children;
	if (@children) {
		$self->{'tags'}->put(
			['b', 'span'],
			['a', 'class', 'caret'],
		);
		$self->{'cb_value'}->($self, $tree);
		$self->{'tags'}->put(
			['e', 'span'],

			['b', 'ul'],
			['a', 'class', 'nested'],
		);
		foreach my $child (@children) {
			$self->_li($child);
		}
		$self->{'tags'}->put(
			['e', 'ul'],
		);
	} else {
		$self->{'cb_value'}->($self, $tree);
	}
	$self->{'tags'}->put(
		['e', 'li'],
	);

	return;
}

1;

__END__